Flash Анимация формы по наведению мышки

[rocket-ua]

addEventListener(Event.ENTER_FRAME, onEnterFrame);
		
private function onEnterFrame(e:Event):void 
{
	if (button.currentFrame == 10)
		button.stop();
}

[glazik]

stop();
lstrelka.addEventListener(MouseEvent.MOUSE_OVER, playF);
function playF (e:MouseEvent) : void {
	play();
}


lstrelka.addEventListener(Event.ENTER_FRAME, onEnterFrame);
		
function onEnterFrame(e:Event):void 
{
	if (button.currentFrame == 10)
		buttonMode.stop();
}




lstrelka.addEventListener(MouseEvent.MOUSE_OUT, stopF);
function stopF (e:MouseEvent) : void {
	if(currentFrame == 1)
	{
		gotoAndPlay(totalFrames);
	};
	
	
}

Вот все 3 действия заданные кнопке, но не работает, что не так с синтаксисом?

[rocket-ua]

у меня такое впечатление что у тебя недостаточно знаний и нет полного представления о том как и что работает.

чему ты делаешь stop() в первой строке? всему клипу. мне кажется что это нужно делать мувику стрелки.
потом при наведении на стрелку ты делаешь не стрелке play(), а всему клипу. Так и должно быть? Мне кажется что нет.
в хендлере ентерфрейма ты проверяешь текущий кадр у button. У тебя этот самый button и если есть то при чем тут он если тебе надо проверять у стрелки? Или ты просто не вникая скопировал то, что я написал? мне кажется что второе.

if(currentFrame == 1)
{
	gotoAndPlay(totalFrames);
};

вот это мне вообще не понятно. Когда убрали мышу со стрелки проверяем какой сейчас кадр у всего мувика, и если первый кадр тогда идем на последний и пытаемся проиграть анимацию, и начинаем ее с самого начала.

Я могу тебе написать весь код, но вот надо ли оно тебе, может лучше все же почитать книги, справочники и тому подобное что бы не путаться в простейших вещах.

[rocket-ua]

вот простейший пример, может быть станет понятнее

public class Main extends Sprite 
{		
	private var _testButton:MovieClip;
	public function Main():void 
	{
		if (stage) init();
		else addEventListener(Event.ADDED_TO_STAGE, init);
	}
		
	private function init(e:Event = null):void 
	{
		removeEventListener(Event.ADDED_TO_STAGE, init);
		// entry point
			
		addEventListener(Event.ENTER_FRAME, onEnterFrame);
			
		_testButton = new button();
		_testButton.addEventListener(MouseEvent.MOUSE_OVER, onMouseOver);
		_testButton.addEventListener(MouseEvent.MOUSE_OUT, onMouseOut);
		_testButton.stop();
		_testButton.isPlaying = false;
		addChild(_testButton);
	}
		
	private function onMouseOut(e:MouseEvent):void 
	{
		playAnimation(26);
	}
		
	private function onMouseOver(e:MouseEvent):void 
	{
		playAnimation(1);
	}
		
	private function playAnimation($frame:int):void
	{
		if (_testButton.isPlaying) return;

		_testButton.gotoAndPlay($frame);
		_testButton.isPlaying = true;
	}
		
	private function onEnterFrame(e:Event):void 
	{
		if (_testButton.currentFrame == 25 || _testButton.currentFrame == _testButton.totalFrames )
		{
			_testButton.stop();
			_testButton.isPlaying = false;
		}
	}
		
}

[glazik]

На самом деле это мое первое знакомство с флешем, поэтому, гуглил смотрел мувики. Писал так, потому что получается то, что нужно на картинке.

На самом деле нужно так, чтоб при наведении на стрелку запускалась ВСЯ анимация, поэтому stop вначале и play в листенере.

Вот картинка того что я делаю:


При наведении мышки на стрелку окно открывается и пока мышка на стрелке окно должно быть открыто, а как мышка ушла с стрелки окно закрылось.

Вот один из вариантов, который содержит только маусовер и маусоут, но анимация не останавливается а проходит полностью)):
http://school-688.ru/okno.swf

[ACE Valery]

На самом деле чтобы вам помочь надо две вещи: ваш код и ваш мувик. Код, как я понимаю, в посте №12.
Что такое там button и buttonMode?

[glazik]

Собственно вот, необходимо, чтобы, как уже писал выше,
1) если мышка на стрелки то окно открывается и остается открытым
2) мышка уходит с стрелки окно закрывается

ВСЕ)

[rocket-ua]

можно сделать примерно вот так (смотрим код в прикрепленном файле)

[glazik]

К сожалению, не могу открыть вашу программу, так как использую flash cs4, если не сложно можно код посмотреть??

[rocket-ua]

var animationIsPlaying:Boolean = false;

stop();

addEventListener(Event.ENTER_FRAME, onEnterFrame);
lstrelka.addEventListener(MouseEvent.MOUSE_OVER, onMouseOver);
lstrelka.addEventListener(MouseEvent.MOUSE_OUT, onMouseOut);

function onMouseOut(e:MouseEvent):void 
{
	playAnimation(11);
}
	
function onMouseOver(e:MouseEvent):void 
{
	playAnimation(1);
}
	
function playAnimation($frame:int):void
{
	if (animationIsPlaying) return;
	
	animationIsPlaying = true;
	gotoAndPlay($frame);
}

function onEnterFrame(e:Event):void 
{
	if (currentFrame == 10 || currentFrame == totalFrames)
	{
		if(currentFrame == totalFrames)
			gotoAndStop(1);
			
		animationIsPlaying = false;
		stop();
	}
}