Не работает пример из Хелпа по VBA

[CaptainNemo]

Всем привет!
Возник каверзный вопрос, заключающийся в следующем…
Нашел классический пример из Хелпа по Visual Basic for Application. Хотел было применить его для своего приложения и сразу дался код писать, но вдруг заметил, что пример-то не работает…
В модуль формы вставил код:

Option Explicit
Private WithEvents mText As TimerState
Private Sub Command1_Click()
Text1.Text = "From Now"
    Text1.Refresh
    Text2.Text = "0"
    Text2.Refresh
Call mText.TimerTask(9.84)
End Sub
Private Sub Form_Load()
    Command1.Caption = "Click to Start Timer"
    Text1.Text = ""
    Text2.Text = ""
    Label1.Caption = "The fastest 100 meter run took this long:"
    Set mText = New TimerState
    End Sub
Private Sub mText_ChangeText()
    Text1.Text = "Until Now"
    Text2.Text = "9.84"
End Sub
Private Sub mText_UpdateTime(ByVal dblJump As Double)
    Text2.Text = Str(Format(dblJump, "0"))
    DoEvents
End Sub

Разумеется, имена всех контролов поменял, как показано в примере: форма – Form1, на форму добавил Label и кнопку с именами Label1 и Command1 соответственно. Ну и два Text1 + Text2.

В модуль класса добавил код следующего содержания:

Option Explicit
Public Event UpdateTime(ByVal dblJump As Double)
Public Event ChangeText()
Public Sub TimerTask(ByVal Duration As Double)
    Dim dblStart As Double
    Dim dblSecond As Double
    Dim dblSoFar As Double
    dblStart = Timer
    dblSoFar = dblStart 
    Do While Timer < dblStart + Duration
        If Timer - dblSoFar >= 1 Then
            dblSoFar = dblSoFar + 1
            RaiseEvent UpdateTime(Timer - dblStart)
        End If
    Loop
    RaiseEvent ChangeText
 End Sub

Однако код не работает. Не могу понять, в чём дело… Метод Refresh не работает для Text-бокса…И т.д. Как быть, подскажите, братья…

[EducatedFool]

Нашел классический пример из Хелпа по Visual Basic for Application.

Не путайте Visual Basic for Application (VBA) и Visual Basic (VB)
Они, конечно, очень похожи, но есть некоторые нюансы, которые следует учитывать.

Во-первых, определить принадлежность кода к VB можно по именам элементов управления: Command1, Text1, Text2
Так называются по умолчанию создаваемые элементы в VB

Если бы код изначально писался под VBA, там с вероятностью 99% были бы другие имена элементов управления: CommandButton1, TextBox1, TextBox2

Теперь конкретно по коду:
1) Метод Refresh для текстбоксов в VBA отсутствует. Убираем строки (по сути, они и не были нужны)

2) При загрузке формы в VB вызывается процедура Form_Load(), а в VBA - UserForm_Initialize. Заменяем название процедуры.

3) Не забываем переименовать класс Class1 (имя по умолчанию) в TimerState

Запускаем, и проверяем:

[Sdrghk]

Сообщение от EducatedFool

Запускаем, и проверяем:

Спасиб, дружище. Все работает!