Работа с массивами

[Maxx]

Всем Доброго дня!

Есть на листе непрерывный набор данных типа Long в диапазоне A1:C300.

Можно ли эти данные поместить в 2-ух мерный массив статический (Dim My_Array(299, 2) As Long)?

[SAS888]

Можно:

MyArray = [A1:C300].Value

Необходимо учесть, что при этом размерности массива начинаются с единицы.

[Maxx]

ОГО, так просто! Спасибо!

[Maxx]

SAS888, а если вместо А1 и С300 будут переменные с адресами ячеек, то так будет правильно?

Dim MyArray(1, 300) As Long
MyArray = (a, b).Value

[SAS888]

Нет. Вместо "A1" и "C300" можно использовать ссылки на ячейки. например:

MyArray = Range(Cells(i, j), Cells(x, y)).Value

или так:

Set x = Range(Cells(i, j), Cells(x, y))
MyArray = x.Value

ЗАМЕЧАНИЯ:
1. Диапазон ячеек должен быть непрерывный (иначе - ошибка).
2. Диапазон ячеек должен содержать не менее 2-х ячеек (иначе - ошибка).
2. Не смотря на то, что, свойство Value в VBA Excel используется по умолчанию, в данном случае его необходимо явно указывать явно (см. пример).

[Maxx]

Понял, спасибо!
Буду творить дальше

[Maxx]

SAS888, я вот тут сочинил следующее, пусть немного объёмно, но это для того, чтобы самому понять, как это будет работать:

Sub Массив()

a = Range("A1").Address
arow = Range("A1").Row
acol = Range("A1").Column

b = Cells(Cells(Rows.Count, "F").End(xlUp).Row, "F").Address
brow = Cells(Cells(Rows.Count, "F").End(xlUp).Row, "F").Row
bcol = Cells(Cells(Rows.Count, "F").End(xlUp).Row, "F").Column

ro = brow - arow + 1
col = bcol - acol + 1

Set x = Range(a, b)
MyArray = x.Value

Dim SummArray(1 To 300) As Long

For i = 1 To ro

summ = 0

For j = 1 To col
summ = summ + MyArray(i, j)
Next j

SummArray(i) = summ

Next i

Set y = Range(Cells(arow, 8), Cells(brow, 8))
y.Value = SummArray(i)

End Sub

В итоге выдает ошибку "Script out of range"
В чем проблема?

И как записать:

Dim SummArray(1 To 300) As Long

через переменные,
т.е.:

Dim SummArray(1 To ro) As Long

[SAS888]

Необходимо определить динамический массив, а затем, когда станет известна требуемая размерность, определить ее, используя ReDim.
Для примера, посмотрите, как можно решить Вашу задачу из поста №7:

Sub Массив_2()
    Dim i As Long, j As Long, s As Double, arr(), SummArray()
    arr = Range([A1], Cells(Rows.Count, "F").End(xlUp)).Value
    ReDim SummArray(1 To UBound(arr, 1))
    For i = 1 To UBound(arr, 1)
        For j = 1 To UBound(arr, 2): s = s + arr(i, j): Next
        SummArray(i) = s: s = 0
    Next
    Range([H1], Cells(UBound(SummArray), 8)).Value = Application.Transpose(SummArray)
End Sub

[doober]

После цикла i равно не 300 а на единицу больше


Замените SummArray(i) на SummArray(i - 1)

Set y = Range(Cells(arow, 8), Cells(brow, 8))
y.Value = SummArray(i - 1)

[SAS888]

1. Замена

Set y = Range(Cells(arow, 8), Cells(brow, 8))
y.Value = SummArray(i)

на

Set y = Range(Cells(arow, 8), Cells(brow, 8))
y.Value = SummArray(i - 1)

избавит от ошибки в коде. А полученный массив SummArray все равно из строки потребуется транспонировать в столбец.
2. Пример того, как задать размерность результирующего массива см. выше.
3. Могу еще предложить код без внутреннего цикла:

Sub Массив_3()
    Dim i As Long, j As Long, arr(), SummArray()
    arr = Range([A1], Cells(Rows.Count, "F").End(xlUp)).Value
    ReDim SummArray(1 To UBound(arr, 1))
    For i = 1 To UBound(arr, 1)
        SummArray(i) = Application.Sum(Application.Index(arr, i, 0))
    Next
    Range([H1], Cells(UBound(SummArray), 8)).Value = Application.Transpose(SummArray)
End Sub