Проверка на наличие в массиве

[istoe]

Уважаемы знатоки, какой самый быстрый способ проверить наличие элемента(например строки) в массиве данных (одномерном)

Заранее благодарен

[Pavel55]

Попробуйте что-нибудь в этом духе

Sub Макрос1()
Dim Arr() As String
    ReDim Arr(2)
    Arr(0) = "мама"
    Arr(1) = "мыла"
    Arr(2) = "раму"
    On Error Resume Next
    If Application.Match("мыла", Arr, 0) = 0 Then
        MsgBox "Слово 'мыла' НЕТ в массиве!", 48, ""
    Else
        MsgBox "Слово 'мыла' есть в массиве!", 64, ""
    End If
    Err.Clear
End Sub

[Teslenko_EA]

Здравствуйте istoe.
возможно есть способ и быстрее, попробуйте оценить

Function inArray(sFind$) As Boolean
Dim s$
    s = Join(sArray(), "|")
    inArray = InStr(s, sFind, 2)
End Function

Евгений.

[EducatedFool]

Один из наиболее быстрых способов: (взято отсюда)

Sub test()
    массив = Array("строка 1", "строка 2", "строка 3", "строка 4", "строка 5", "строка 6")
    ИскомаяПодстрока = "строка 3"
    
    If IsNumeric(Application.Match(ИскомаяПодстрока, массив, 0)) Then
        MsgBox "Есть такая строка в массиве"
    Else
        MsgBox "Подстрока в массиве не найдена"
    End If
End Sub

Ну или так:

Sub test2()
    массив = Array("строка 1", "строка 2", "строка 3", "строка 4", "строка 5", "строка 6")
    ИскомаяПодстрока = "строка 3"
    
    If "%" & Join(массив, "%") & "%" Like "*%" & ИскомаяПодстрока & "%*" Then
        MsgBox "Есть такая строка в массиве"
    Else
        MsgBox "Подстрока в массиве не найдена"
    End If
End Sub

(добавлено)
Опоздал с ответами

[EducatedFool]

Teslenko_EA, на Вашу функцию VBA Excel ругается
К примеру, я не нашёл первого параметра в функции InStr
Странно, если этот код у Вас работает...

Вот в таком виде - работает:

Sub test()
    sArray = Array("строка 1", "строка 2", "строка 3", "строка 4", "строка 5", "строка 6")
    sFind = "строка 3"
    s = Join(sArray, "|")

    If InStr(1, s, sFind, vbTextCompare) Then
        MsgBox "Есть такая строка в массиве"
    Else
        MsgBox "Подстрока в массиве не найдена"
    End If
End Sub

Судя по цифре 2 в строке InStr(s, sFind, 2), этот код взят из Access-а...
А у Excel, судя по всему, немного другой синтаксис функций.

[Teslenko_EA]

Здравствуйте EducatedFool.
да Вы правы только в MS Access допускается использование значения 2 для выполнения сравнения на основании сведений, содержащихся в базе данных и "...Указание аргумента start является обязательным, если указан аргумент compare..." тоже моя ошибка.

[Aent]

Ну или так (для полноты картины )

Option Base 0
Public Sub tst()
    Dim sArray()
    Dim sFind As String
    sArray = Array("строка 1", "строка 2", "строка 3", "строка 4", "строка 5", "строка 6")
    sFind = "строка 33"
    If UBound(Filter(sArray, sFind)) > -1 Then
        Debug.Print "строка присутствует"
    Else
        Debug.Print "строка отсутствует"
    End If
End Sub

[SAS888]

Уважаемый Aent.
Предложенный Вами способ, конечно, рабочий. Но применять его нужно с большой осторожностью. Так, например, если имеется массив значений и строка для поиска в виде

sArray = Array("строка 1", "строка 2", "строка 33", "строка 4", "строка 5", "строка 6")
sFind = "строка 3"

То результат будет ошибочным. К сожалению, в функции Filter нет опции выбора частичного или однозначного совпадения.

[istoe]

Спасибо всем!

Кстати на моём тесте комбинация join-like работает быстрее match в 2 раза.
Но тут конечно надо быть уверенным, что в массиве нет символа разделителя join("%" примере EducatedFool).