использование в макросе другой книги

[Роня]

Я не понимаю.... Помогите, пожалуйста!
У меня Excel 2003
Написала простейшую программу(для проверки, что удалось ли обратиться к нужному файлу)

Dim f As String, f1 As String, shtname As String
f = ThisWorkbook.Name
f1 = "C:\ФФФ.xls"


Workbooks(f).Worksheets("Лист1").Ra nge("M4").Value = Workbooks(f).Name ' это работает
Workbooks(f).Worksheets("Лист1").Ra nge("M4").Value = Workbooks(f1).Name ' а это нет
Пишет, что Workbooks(f1).Name = <Subscript out of range>

Что делать???

[pashulka]

iFullName$ = "C:\ФФФ.xls"
iFileName$ = Dir(iFileName$)
'Предположим, что скрытые и т.д. файлы нас не интересуют
 
If iFileName$ <> "" Then
   ThisWorkbook.Worksheets(1).Range("M4").Value = _
   Workbooks(iFileName$).Worksheets(1).Range("M4").Value
   'В данном примере предполагается, что :
   '- рабочая книга открыта. если это не так --
   'возникнет ошибка, для предотвращения которой, можно
   'просто проверить не открыта ли нужная рабочая книга.
   '- текущая и указанная рабочая книга содержат, как минимум, по одному рабочему листу.
   '- ячейка [M4] и первый рабочий лист (в текущей книге) не защищены.
Else
   MsgBox "Указанная книга изволит отсутствовать", , ""
End If

[Роня]

Спасибо огромнейшее, Pashulka!
Все работает (после того, как вписала iFileName$ = Dir(iFileName$))
У меня возникли еще вопросы...
А можно ли обращаться в текущей книге к закрытой рабочей книге? (вообще-то, передо мной стоит именно такая задача)
И еще вот:

For Each cell In ThisWorkbook.Worksheets(1).Range("d ata")
cell.Value = Workbooks(iFileName$).Worksheets1). Range(cell).Value
Next cell

Насколько это выражение дико, потому что оно не работает.
Имя "data" я присвоила области данных листа 1.

[Роня]

По поводу второго вопроса:
celladdress = ThisWorkbook.Worksheets(1).Range("d ata").Address
ThisWorkbook.Worksheets(1).Range("d ata").Value = Workbooks(iFileName$).Worksheets(1) .Range(celladdress).Value
Это работает!

Но вопрос по поводу работы с закрытой книгой остается.
Ответьте, пожалуйста.

[pashulka]

Если рабочая книга с именем iFileName открыта, а "data" это или именованный диапазон см.яч. или формула, которая возвращает ссылку на диапазон смежных ячеек, то количество обращений можно немного сократить, например

With ThisWorkbook.Worksheets(1).Range("data")
      .Value = Workbooks(iFileName$).Worksheets(1).Range(.Address).Value
End With

Что касается обращения к закрытой книге, то Workbooks представляет собой семейство открытых книг в данном приложении, поэтому, если Вы хотите обратиться к нужной(закрытой) книге, используя Workbooks, то её необходимо продварительно открыть :Workbooks.Open FileName:=iFullName

iFullName$ = "C:\ФФФ.xls"
 
If Dir(iFullName$, vbReadOnly + vbArchive + vbHidden) <> "" Then
   'Предположим, что скрытые и т.п. файлы нас всё-таки интересуют
   'ибо мы не будем вносить изменения и пытаться сохранить файл
   'имеющий, например, атрибут только для чтения
   With Application
        .ScreenUpdating = False
        '...
        'и т.д. по необходимости
        With .Workbooks.Open(FileName:=iFullName$, UpdateLinks:=0) '+ Password:=""
             'Здесь идёт обработка данных этой рабочей книги
             .Close saveChanges:=False
        End With
        '...
        .ScreenUpdating = True
   End With
Else
   MsgBox "Указанная книга изволит отсутствовать", , ""
End If

Если же открытие/закрытие рабочей книги нежелательно, то есть несколько способов получения нужных данных (без использования метода Open) и наиболее простой, это использование внешних ссылок с последующей заменой этих формул на значения, которые они возвращают.

Предположим, что файл "C:\ФФФ.xls" существует, содержит лист с именем "Рейтинг 2007", а диапазон "A1:A10" содержит некие данные

With ThisWorkbook.Worksheets(1).Range("B10:B19")
     .Formula = "='C:\[ФФФ.xls]Продажи 2007'!A1"
     'При необходимости формулу можно разбить на составляющие
     'имя рабочей книги, листа, адрес диапазона
     .Value = .Value
End With

[Роня]

Pashulka, от всей души благодарю Вас за помощь.
Буду реализовывать 3-й вариант.
Если что, ждите еще вопросов...

[Роня]

Ох, Pashulka, не совсем все просто у меня...
Сначала я вставляю в ячейку path1 путь к рабочему файлу (iFullName$)

Dim Isect As Range
Set Isect = Application.Intersect(Range("path1" ), ActiveCell)
If Isect Is Nothing Then
'MsgBox "Ranges do not intersect"
Else
ActiveCell.Value = Application.GetOpenFilename("Excel Files (*.xls),*.xls")
Cancel = True
End If

Потом:
iFullName$ = Range("path1").Value

И, наконец, мне надо использовать этот путь при реализации обращения к рабочему файлу, не открывая его:

With ThisWorkbook.Worksheets(1).Range("B 10:B19")
.Formula = "='C:\[ФФФ.xls]Продажи 2007'!A1"
'При необходимости формулу можно разбить на составляющие
'имя рабочей книги, листа, адрес диапазона
.Value = .Value
End With

Реально ли это?

[Роня]

Просто в Delphi, насколько я помню, можно было сделать что-то типа:
With ThisWorkbook.Worksheets(1).Range("B 10:B19")
.Formula = "='",iFullName$,"Продажи 2007'!A1"

[pashulka]

Предположим, что Вы используете следующее событие рабочего листа ...

Private Sub Worksheet_BeforeRightClick(ByVal Target As Excel.Range, Cancel As Boolean)
    If Intersect(Me.Range("Path1"), Target) Is Nothing Then
       MsgBox "Ranges do not intersect", vbCritical, ""
    Else
       Cancel = True
       'Возможно мы можем обойтись без изменения значения
       'именованной ячейки, а возможно и без самой ячейки,
       'впрочем, это сугубо добровольное и личное дело
       iFullName = Application.GetOpenFilename( _
       FileFilter:="Excel Files (*.xls),*.xls", Title:="Выберите нужный файл")
       If iFullName <> False Then
          iFileName = Dir(iFullName, vbReadOnly + vbHidden + vbArchive)
          iFullName = Application.Substitute(iFullName, iFileName, "[" & iFileName & "]")
          'iFullName = Replace(iFullName, iFileName, "[" & iFileName & "]") 'XL2000
          iSheetName = "Продажи 2007"
          'Лист должен существовать, иначе Excel выведет
          'стандартное диалоговое окно Выбор листа
          With Me.Range("B10:B19")
               'Указанный диапазон + рабочий лист не должен быть защищён
 
               'Если Вы используете событие листа, книги Worksheet_Change()
               'то перед изменением значений имеет смысл блокировать
               'выполнение этого события, т.е.
               'Application.EnableEvents = False
 
               .Formula = "='" & iFullName & iSheetName & "'!A1"
               .Value = .Value
 
               'Application.EnableEvents = True
               'а затем обязательно вернуть всё на круги своя
          End With
       End If
    End If
End Sub

[Роня]

Гениально!!!
Паша,спасибо!!!