Поиск и копирование совпадений на нескольких листах

[NeDobryj]

Добрый день.

Как произвести копирование нескольких ячеек (наименование, кофицент, количество) из листа "Temp" на лист "Смета" только если значение ячейки "Temp".C#(наименование) найдено на листе "Прайс-лист".A:A (наименование)

Интересует пример макросом VBA, впр и индекс\поискпоз - не подходят...

• Temp - Лист с временными данными.
• Смета - лист где должны проводится расчеты
• Прайс лист - База номенклатуры по которой будет проводится расчет.

Если можно пример с комментариями, что бы разобраться в коде.

[Aleksandr H.]

Sub Macros()
    Dim sh As Worksheet, sh2 As Worksheet, sh3 As Worksheet
    Dim rng As Range, i As Long, j As Long, r As Long, sh2r As Long
    Set sh = Sheets("Temp")
    Set sh2 = Sheets("Прайс-Лист")
    Set sh3 = Sheets("Смета")
    ' строк в прайсе
    sh2r = sh2.Cells(sh2.Rows.Count, 1).End(xlUp).Row
    With sh
    ' перебираем елементы С на темпе
        For i = 2 To .Cells(.Rows.Count, 3).End(xlUp).Row
            ' сравниваем со списком листа Прайс-Лист
            For j = 1 To sh2r
                 ' найдено совпадение
                If sh2.Cells(j, "A") = .Cells(i, "C") Then
                ' последняя строка Сметы
                    r = sh3.Cells(sh3.Rows.Count, 1).End(xlUp).Row + 1
                    ' перенос значений на смету
                    .Range(.Cells(i, "C"), .Cells(i, "E")).Copy _
                            sh3.Cells(r, "A")
                    ' перенос цены на смету
                    sh3.Cells(r, "D") = sh2.Cells(j, "B")
                    ' выход из цикла
                    Exit For
                End If
            Next j
        Next
    End With
    Set sh = Nothing
    Set sh2 = Nothing
    Set sh3 = Nothing
End Sub

[NeDobryj]

Сообщение от Aleksandr H.

Sub Macros()
    Dim sh As Worksheet, sh2 As Worksheet, sh3 As Worksheet
    Dim rng As Range, i As Long, j As Long, r As Long, sh2r As Long
    Set sh = Sheets("Temp")
    Set sh2 = Sheets("Прайс-Лист")
    Set sh3 = Sheets("Смета")
    ' строк в прайсе
    sh2r = sh2.Cells(sh2.Rows.Count, 1).End(xlUp).Row
    With sh
    ' перебираем елементы С на темпе
        For i = 2 To .Cells(.Rows.Count, 3).End(xlUp).Row
            ' сравниваем со списком листа Прайс-Лист
            For j = 1 To sh2r
                 ' найдено совпадение
                If sh2.Cells(j, "A") = .Cells(i, "C") Then
                ' последняя строка Сметы
                    r = sh3.Cells(sh3.Rows.Count, 1).End(xlUp).Row + 1
                    ' перенос значений на смету
                    .Range(.Cells(i, "C"), .Cells(i, "E")).Copy _
                            sh3.Cells(r, "A")
                    ' перенос цены на смету
                    sh3.Cells(r, "D") = sh2.Cells(j, "B")
                    ' выход из цикла
                    Exit For
                End If
            Next j
        Next
    End With
    Set sh = Nothing
    Set sh2 = Nothing
    Set sh3 = Nothing
End Sub

Спасибо огромное, то что нужно!

[NeDobryj]

Как как добавить проверку по симвовам, к примеру если первые 200 символов совпадают?

[Aleksandr H.]

Сообщение от NeDobryj

первые 200 символов совпадают?

http://www.homeandlearn.org/left_and...functions.html

[NeDobryj]

Код отличный, выполняет то что нужно... вопрос в следующем, если мне нужно значение которое не совпало, добавить в прайс лист, по условию:

                If .Cells(i, "C").Offset(0, 1) <> "" Then
                    q = sh2.Cells(sh2.Rows.Count, 1).End(xlUp).Row + 1
                    .Cells(i, "C").Copy _
                        sh2.Cells(q, "A")
                    Exit For
                End If

Как правильно встроить этот код в макрос, else, не подходит, макрос дублирует значение...
Понимаю что это нужно сделать после перебора по совпадению..

[Aleksandr H.]

введите логическую переменную, например, которая принимает true если найдено совпадение, иначе false. после цикла for проверить и если она false - копировать