автоматическое пересохранение

[Окоча Юра]

Привет всем!! когда я пересохраняю документ, мне необходимо в имя файла каждый раз вводить сегодняшнюю дату и еще несколько ключевых слов из документа. Можно ли, чтобы при пересохранении , эти ключевые слова и сегодняшняя дата попадали в строку имени файла автоматически? Спасибо.

[viter.alex]

Вот так это делается. Помести процедуру в шаблон и пользуйся. Она будет вызываться при каждом сохранении файла. Также ее можно поместить в модуль ThisDocument самого докумета, если ты просто сохраняешь его копии.

Sub FileSave()
  Dim KeyWords$
  KeyWords = "ключевые слова"
  With Application.Dialogs(wdDialogFileSaveAs)
    .Name = Format(Date, "dd.MM.yyyy") & " " & KeyWords
    .Show
  End With
End Sub

Ключевые слова из документа нужно сделать закладками, чтобы к ним можно было обратиться и взять из них текст.
Например, так

KeyWords = ThisDocument.Bookmarks("Имя_закладки").Range.Text

Если процедуру поместишь в шаблон, а не в документ, то ThisDocument нужно заменить на ActiveDocument.

[Окоча Юра]

Стыдно признаться, но я даже не знаю куда или через что этот код вставить, как в шаблон так и в документ . Если можно пошагово - "ДЛЯ ЧАЙНИКОВ". Я обычный пользователь, с закладками я разобрался давно, но дальше...сложно. Я прикрепил файл "555". Допустим надо чтобы в строке пересохранения было такое название: експертиза (слово по умолчанию)_(чтобы здесь я мог набирать любой текст)_(сюда вставить надо закладку НомерЕкспертизи)_(а сдесь закладка ДатаНаписання)". Заранее спасибо...

[viter.alex]

Эх, Юра, Юра. Если бы не славный город Житомир, и ваше вкуснейшее мороженое «Империя»…

Значит по порядку.

1. Открыли документ
2. Жмем Alt+F11, чтобы добраться до редактора VBA.
3. В появившемся окне слева видим нечто такое:
   
4. С учетом пожеланий трудящихся макрос выглядит так:
   

   Sub FileSave()
     On Error GoTo ErrorHandler
     With Application.Dialogs(wdDialogFileSaveAs)
       .Name = "експертиза_" & ThisDocument.Bookmarks("НомерЕкспертизи").Range.Text & "_" & _
         ThisDocument.Bookmarks("ДатаНаписання").Range.Text
       .Show
     End With
   ErrorHandler:
     If Err.Number <> 0 Then _
       MsgBox "Произошла ошибка при подготовке к сохранению. Описание ошибки: " & vbCr & _
         Err.Description, vbOKOnly + vbCritical, "Документ не сохранен."
   End Sub

5. Если макрос поместить в ThisDocument, который расположен в нашем документе «555», то этот макрос будет работать только для этого документа.
6. Но, если мы раскроем папку Microsoft Word Objects, то увидим, что там тоже есть модуль ThisDocument. Так вот, если поместить макрос туда, а в самом макросе заменить ThisDocument на ActiveDocument, то макрос будет работать для всех документов.
7. В приложенном файле я уже все сделал. Макрос находится в документе и работает только для документа.

[Окоча Юра]

Спасибо большое!!!!

[Окоча Юра]

Я все сделал - макрос запустился, все сработало. Обычно я пересохраняю файл в начале, а потом во время работы периодически сохраняюсь. Но после того как я пересохранился с помощью макроса и нажав через 10 минут Shift+F12(сохранение файла) у меня снова макрос запустился макрос , всесто обычного сохранения, как этого избежать?

[viter.alex]

В общем-то этого вопроса я ждал. Самый простой метод — это дописать «As» к названию макроса. Тогда он будет срабатывать при команде «Сохранить как…»
А можно организовать проверку на соответствие разным условиям: имени файла некоему шаблону, даты последнего сохранения и текущей дате и пр. Но первый метод на-а-амного проще.

[Окоча Юра]

С меня мороженое. Спасибо.

[Окоча Юра]

Привет. Помоги добить этот макрос, что добавить чтобы при пересохранении по умолчанию открывалась определенная мною папка, в которую я хотел бы сохранить документ?

[viter.alex]

Вот так. Вместо «C:\» пропиши полный свой путь. При указании пути в имени файла Word сам переходит в ту директорию и оставляет в поле имени только само имя. Сам этого не знал, но решил попробовать. Получилось. Бум знать.

Sub FileSaveAs()
  Dim sPath$
  sPath = "C:\"
  On Error GoTo ErrorHandler
  With Application.Dialogs(wdDialogFileSaveAs)
    .Name = sPath & "експертиза_" & ThisDocument.Bookmarks("НомерЕкспертизи").Range.Text & "_" & _
      ThisDocument.Bookmarks("ДатаНаписання").Range.Text
    .Show
  End With
ErrorHandler:
  If Err.Number <> 0 Then _
    MsgBox "Произошла ошибка при подготовке к сохранению. Описание ошибки: " & vbCr & _
      Err.Description, vbOKOnly + vbCritical, "Документ не сохранен."
End Sub