Сумма значений при условии

[amadeus017]

Доброго времени суток!
Помогите написать макрос, чтобы при совпадении одинаковых значений в строках, суммировал их значение, заполняя соседние столбцы. Т.е. есть таблица со значениями которые повторяются по столбцам - "сумма" (А), "наименование" (В), "свойства" (С). Необходимо, если наименование (В) имеет одинаковое свойство (С), то в соседних столбцах D, E, F, один раз заполнялся значениями (в столбики D - наименование, E - свойства), а столбик F - это сумма всех повторяющих значений. Столбцы D, E, F предварительно очистить.
пример:
исходные данные (A, B, C) | итоговые данные (D, E, F)
---- A ----- B ----- C -------- D ------- E ------ F ------
сумма | наим-ние| сво-во | наим-ние| сво-во | сумма
-------------------------------------------------------------------------
1540.00 | рубашка | серая | рубашка | серая | 3132.00
1523.00 | рубашка | белая | рубашка | белая | 1963.00
452.00 | рубашка | серая | рубашка | черная | 2560.00
440.00 | рубашка | белая |
2560.00 | рубашка | черная |
1140.00 | рубашка | серая |

[IgorGO]

в F3 пишите эту формулу

=СУММПРОИЗВ(($B$3:$B$42=D3)*($C$3:$C$42=E3)*$A$3:$A$42)

потом копируйте ее вниз по столбику.
удачи!

[amadeus017]

К сожалению, это не то что я хотел бы видеть, формула
=СУММПРОИЗВ(($B$3:$B$42=D3)*($C$3:$ C$42=E3)*$A$3:$A$42)
схожа по своему принципу, что и
=СУММЕСЛИМН()
и обе они привязаны к определенным значениям введенным вручную.
Таблица которую я привел в качестве примера, имеют мало переменных, в действительности, переменных более сотни и прописывать значение проблематично (долго), поэтому хотелось бы видеть в идеале макрос а не формулу для просчета.
Вероятно я изначально неполную предоставил информацию, поэтому ожидал другой ответ )))

[IgorGO]

увы, макроса так и нет...
используйте сводную таблицу

[SAS888]

Ну, можно и макросом:

Sub Main()
    Dim i As Integer, s As String, a(), x
    Application.ScreenUpdating = False: Application.DisplayAlerts = False
    Intersect(Rows("3:" & Rows.Count), [D:F]).ClearContents
    a = Range("A3:C" & Cells(Rows.Count, 1).End(xlUp).Row).Value
    Set x = CreateObject("Scripting.Dictionary")
    For i = 1 To UBound(a, 1)
        s = a(i, 2) & "|" & a(i, 3)
        If x.Exists(s) Then x.Item(s) = x.Item(s) + a(i, 1) Else x.Add s, a(i, 1)
    Next
    With [D3].Resize(x.Count)
        .Value = Application.Transpose(x.Keys)
        .TextToColumns Destination:=[D3], DataType:=xlDelimited, Other:=True, OtherChar:="|"
    End With
    [F3].Resize(x.Count).Value = Application.Transpose(x.Items)
    Range("D3:F" & Cells(Rows.Count, 4).End(xlUp).Row).Sort Key1:=Range("D3"), Order1:=xlAscending, Header:=xlNo
End Sub

Пример во вложении.

[amadeus017]

То что нужно!!!
Спасибо огромное!