Удалить из символьного массива все вхождения цифр и арифметических знаков

[Mr_Nobody]

Доброго времени суток! Помогите, пожалуйста, с заданием

Задание: Задан символьный массив S(n), n≤700. Разработать программу, которая изымает из этого массива все повторные вхождения цифр и арифметических знаков. Вывести результат на консоль.

[R71MT]

Под какую ОС? Где твоё решение? Показывай свой код..

[FPaul]

И, за компанию, название компилятора, каким образом изымать (просто не выводить на экран или сначала преобразовать строку).

[Mr_Nobody]

Сообщение от R71MT

Под какую ОС? Где твоё решение? Показывай свой код..

Исходя из задания, можно предположить что строка объявлена и заранее известно ее длина:

.model small
.stack 100h
.data
arr     dw 'd','f','+','t','1','4','h','`','@','0','*','.','9','k'
l=13

Я так понимаю, что есть два способа решения:
1. Удалить ненужные элементы, сместив оставшиеся
2. Переписать массив, с нужными элементами
...но как это сделать, я не особо представляю)

Сообщение от FPaul

И, за компанию, название компилятора, каким образом изымать (просто не выводить на экран или сначала преобразовать строку).

Комипиляторы: masm32, TASM.
Вывести нужно начальный и конечный результат.

[R71MT]

Сообщение от Mr_Nobody

которая изымает из этого массива все повторные вхождения цифр и арифметических знаков.

Так-как в ASCII-таблице коды цифр идут подряд, то их можно вытащить за один проход. Со-знаками уже такой фокус не пройдёт (в последовательности есть две дырки /см.рис.ниже/), и их нужно искать каждый в отдельности. А это ещё 4 прохода. Итого, изъять всё данные из строки можно за 5 проходов (если искать каждый символ отдельно, то за 2). ИМХО..

[R71MT]

Вот тебе решение на Фасм'е. Под Тасм переделаешь сам..
Массив заполняется случайным образом. Длина массива вычисляется тоже рандомно, в диапазоне 16..699, в следствии чего при каждом запуске программы данные и результат будут разные. Организовано в один проход..

Фильтруется только первая половина (127 символов) ASCII-таблицы, а это все символы, кроме кирилицы и псевдографики. Чтоб не расходовать память, найденные элементы помещается в тот-же массив, перезаписывая его с головы.

;fasm-code /*.COM-file/
;--------------------------
org   100h
push  start
retn

mess0   db  13,10,10,'ARRAY...'
        db  13,10,'------------',13,10,'$'
mess1   db  13,10,10,'FOUND...'
        db  13,10,'------------',13,10,'$'

array   db  700 dup(0)          ; место под массив (и результат)
len     dw  0                   ; переменная с длиной массива

start:
;// получаем длину массива "от фонаря"
        in    ax,40h            ; АХ = рандом
        mov   bx,700            ; делитель
        xor   dx,dx             ;
        div   bx                ;
        cmp   dx,16             ; проверка остатка на минимум
        jb    start             ; повторить, если меньше
        mov   [len],dx          ; длина массива в диапазоне 16..699

;// заполняем массив случайным образом
        mov   di,array          ; приёмник
@@:     xor   cx,cx             ; задержка..
        loop  $                 ; ^^^
        in    ax,40h            ; берём рандом
        imul  ax,9E35h          ; разделить на полином
        and   al,7Fh            ; оставим только первую половину ASCII-кодов
        cmp   al,13             ; уберём возврат каретки,
        je    @b                ; ^^^
        cmp   al,10             ; ..и перевод строки.
        je    @b                ; ^^^
        stosb                   ; сохранить символ в ES:DI !
        dec   dx                ;
        jnz   @b                ; промотать вернюю метку(@@) DX-раз..

;// выводим получившийся массив на экран
        mov   ah,9              ; мессага
        mov   dx,mess0          ;
        int   21h               ;
        mov   cx,[len]          ; СХ = длина массива
        mov   si,array          ; SI = источник
@@:     lodsb                   ;
        int   29h               ;
        loop  @b                ;

        mov   ah,9              ; мессага
        mov   dx,mess1          ;
        int   21h               ;

;// поиск заданных символов в массиве
;// после чтения, источник больше не нужен.
;// найденные будем собирать туда-же (в источник) - начиная с головы.
        mov   cx,[len]          ;
        mov   si,array          ; источник
        mov   di,si             ;    ..он-же приёмник
        xor   dx,dx             ; сбросим счётчик найденных
@@:     lodsb                   ; читаем массив
        mov   bl,al             ; запомним символ в BL (для фильтра чисел)
        cmp   al,'*'            ; фильтр знаков..
        jz    @save             ; сохранить, если равно
        cmp   al,'/'            ;
        jz    @save             ;
        cmp   al,'+'            ;
        jz    @save             ;
        cmp   al,'-'            ;
        jz    @save             ;
        sub   bl,30h            ; проверка на число
        cmp   bl,9              ;
        ja    @next             ; пропустить, если больше
@save:  inc   dx                ; иначе: счётчик +1
        stosb                   ; запись символа в буфер!
@next:  loop  @b                ; промотать СХ-раз..

;// вывод найденных на экран
        mov   cx,dx             ; кол-во найденных
        mov   si,array          ; источник
@@:     lodsb                   ;
        int   29h               ;
        loop  @b                ;

        mov   ah,8              ; выход в DOS по клавише!
        int   21h               ;
        int   20h               ;

[Mr_Nobody]

Немного погуглив, узнал про анонимные метки и что делают отдельные прерывания, также до этого я думал что команды lods и stos что-то, куда-то пересылают, а теперь знаю что, куда и откуда. Как минимум смогу объяснить данную программу.

Очень Вам благодарен! Отдельное спасибо за комментарии.