Запарка со сравнением текста

[BRcr]

Здравствуйте, подскажите маленько, кому не лень.
Сами мы не местные и синтаксис VB знаем крайне хреново...
Так вот. В теле функции объявляю массив(или это строка ) следующего вида:

var = "*[()[]{}]*"

Затем пытаюсь сравнить его со строчкой формата string посредством функции like и ничего не выходит - строчка обрабатывается так, будто бы в ней нет скобок. Пятая точка мне подсказывает, что я неправильно объявляю строчку шаблона, содержащую скобки и что проблема именно в самих скобках, т.к. с другими символами это работает.
Сразу скажу - способ объявления где-то подглядел и на самом деле понятия не имею, как в VB объявляются массивы, а в справке этого найти не смог. В этой идиотской справке вообще фиг чего найдешь в час ночи.

[doober]

Время больше часу ночи
Стив Каммингс
VBA для чайников


Объявление массивов
Как и обычные переменные, массивы должны быть объявленными. При этом объявление
массива по форме отличается от объявления переменной только в одной дополнительной де-
тали. Вот несколько примеров:
' Объявление одномерного массива данных типа Date:
Dim datTimeOfImpact (cdatMaxObservations) As Date
' Объязление массива типа Currency без объявления размера:
Public curPriceQuotes () As Currency
1 Объязление четырехмерного массива типа I n t e g e r :
Dim intArrayOflntegers (34, 13, 29, 4) As Integer
Как видите, разница объявлений для обычных переменных и массивов заключается в том,
что в объявлении массива за именем следуют скобки, в которых может не содержаться ниче-
го, а могут содержаться значения, задающие размеры массива по каждому из его измерений.
(Обратите внимание, что в первом из вышеприведенных примеров размер одномерного мас-
сива задается именованной константой.)
Не забудьте при объявлении массива указать тип данных, включив в объявление
массива As Type с подходящим ключевым словом, задающим тип. Если не ука-
зать тип, VBA создаст массив типа V a r i a n t , в результате чего требования ва-
шей программы к памяти возрастут, а ее выполнение замедлится. Массивы дан-
ных типа V a r i a n t допустимы и в некоторых ситуациях могут быть вполне под-
ходящим решением, но всегда, когда это возможно, лучше назначать массивам
конкретный тип данных.

[Aent]

Начнём с того что Like не функция а оператор.
Если бы вы навели на него курсор и нажали F1 то узнали бы что он имеет синтаксис:
логический результат = строка Like шаблон
В шаблоне же символы [?#* являются специальными и при употреблении в группе [... ] должны быть заключены в квадратные скобки. Пара квадратных скобок означает что соответствующее знакоместо будет сопоставляться с любым символом
из находящихся внутри скобок [.,;:] сопоставится с любым из перечисленных в скобках символом.
[!.,;:] - c любым символом отличным от . , ; :
[A-Z] - c любым символом от A до Z
### - c любыми тремя цифрами
* - с любым набором символов
[] - cопоставляется с пустой строкой.
Правая квадратная скобка ] не может присутствовать в качестве одного из символов группы.
Если задача состоит в том что бы узнать присутствует ли в строке какая либо скобка - нужно воспользоваться не like а объектом RegExp (примеры есть на этом форуме) или кодом вроде:

Dim s As String
s = "(a + b) *c[3]"
Debug.Print Instr(s,"[") + Instr(s,"]") > 0 Or  s Like "*[{()}]*"

Можно ограничиться использованием оператора Like

Debug.Print s Like "*[[]*" Or s Like "*]*" Or s Like "*[{()}]*

Конструкция в шаблоне "*[[]*" означает "что угодно" "левая квадратная скобка (в экранирующих квадратных скобках)" "что угодно"
Правая квадратная скобка во втором шаблоне не начинает группу и поэтому не нуждается в экранировании.
Последний шаблон сопоставится с любой строкой содержащей один из символов: "{", "}", "(", ")".
Однако, приведённый выше код не будет самым эффективным.
К сожалению в чистом VB (VBA) нет функции или оператора проверяющего присутствие любого символа из множества.
Но можно написать:

Dim i As Long
Dim s As String
Dim res As Boolean
res  = False
For i = 1 to Len(s)
   res =  Instr("([{}])",Mid$(s,i,1)) > 0
   If res exit For
Next i

Но и этот код не слишком эффективен.
Вместо использования функции Instr в цикле можно воспользоваться оператором Select

Select Case Mid$(s,i,1)
      Case "(",")","{","}","[","]"
            res = True : Exit For
End Select

[BRcr]

2doober: спасибо, конечно, но мимо.

2Aent: нда... слышал я звон, да не понял, где он. Хотя сразу, блин, больно странным показалось такое задание строчки шаблона, все в звездах да скобках. Правильно говорила мине мама: "Не пиши на незнакомом языке по ночам, сынок!". Спасибо вам огромное за не менее огромное количество вариантов! Я бы ерундой не маялся, написал бы все на С++ и ходил довольным, но не для себя - для Народа стараюсь. А народ с excel'ем гораздо лучше дружит, нежели с С++.

Эффективности ради, конечно, стоило бы набросать отдельную функцию на проверку "присутствия любого символа из множества", построенную на Case, но скорость значения не имеет, так что instr будет в самый раз, самый очевидный выход.

[BRcr]

Блин, то ли лыжи не едут, то ли я е####й?!

Почему может не работать вот этот кусок?
(замена Mid на Mid$ ничего не меняет)

 Public Function FilterTName(str As String, s1 As Boolean, s2 As Boolean, s3 As Boolean)
  Dim signs1 As String
  Dim signs2 As String
  Dim signs3 As String
  Dim text As String
  Dim res As Boolean
  
  signs1 = "-_.,;'"
  signs2 = "[](){}"
  signs3 = "№~!@#$%^&+="
  res = False
  text = str
  
  If s1 Then
    For i = 1 To Len(text) Step 1
     res = InStr(signs1, Mid(text, i, 1)) > 0
     If res Then
      text = Left(text, i - 1) & Right(text, Len(text) - i)
      i = i - 1
     End If
    Next i
  End If
  
  FilterTName = text
  
 End Function

PS. Об ошибке excel дает понять надписью #!ЗНАЧ в ячейке.

[SAS888]

Во-первых, ошибка в строке

res = InStr(signs1, Mid(text, i, 1)) > 0

Во-вторых, если я правильно Вас понимаю, то требуется убирать из строки символы по условиям. Если так, то все можно сделать существенно проще:

Public Function FilterTName(str As String, s1 As Boolean, s2 As Boolean, s3 As Boolean)
    Dim signs1 As String, signs2 As String, signs3 As String, text As String, i As Integer
    signs1 = "-_.,;'": signs2 = "[](){}": signs3 = "№~!@#$%^&+=": text = str
    If s1 Then
        For i = 1 To Len(signs1): text = Application.Substitute(text, Mid$(signs1, i, 1), ""): Next
    End If
    FilterTName = text
End Function

Пример применения этой функции см. во вложении.
В-третьих, замена Mid на Mid$ увеличивает быстродействие, т.к. в последнем случае функция работает без неявного преобразования аргумента в тип Variant.

[Aent]

Вот простая функция для замены группы символов на подстроку (в частном случае на пустую)

Public Function MultiChrReplace(s As String, f As String, t As String, Optional Inv as Boolean = False ) As String
    Dim i As Long
    Dim j As Long
    Dim ls As Long
    Dim lt As Long

    MultiChrReplace = s
    ls = Len(s)
    if ls = 0 then 
         Exit Function
    end if
    lt = Len(t)
    j = 1
   
    For i = 1 To ls
        If (InStr(f, Mid$(s, i, 1)) > 0) <> Inv Then 'символ подлежит замене ?
            If lt > 0 Then 'длина замещающей подстроки больше 0 ?
                Mid$(MultiChrReplace, j, lt) = t
                j = j + lt
            End If
        Else ' копируем не подлежащий замене символ в результирующую строку
            Mid$(MultiChrReplace, j, 1) = Mid$(s, i, 1)
            j = j + 1
        End If
    Next i
    MultiChrReplace = Left$(MultiChrReplace, j - 1)
End Function

Пример:

' Удалить из строки s все скобки
s = MultiChrReplace(s, "(){}[]",VbNullString)
' Заменить знаки операций на "&&&"
s = MultiChrReplace(s, "+-*/\^","&&&")

Опциональный параметр Inv служит для инвертирования условия замены
MultiChrReplace("a+b-c*d","+-*","") = "abcd" , но
MultiChrReplace("a+b-c*d","+-*","",True) = "+-*"
MultiChrReplace("a+b-c*d","+-*","_",Inv:=True) = "_+_-_*_"

[Aent]

To BRcr:
Во первых непонятно зачем у функции лишние аргументы s2 и s3 ведь строки signs2 и signs3 вы в коде не используете.
По существу:
Вы идёте в цикле по i по символам входной строки (кстати копировать её совершенно не обязательно) и в теле цикла меняете длину этой строки и переменную цикла
Если вы хотите получить строку s без i-го символа, то используйте код:

s = Left$(s,i-1) & Mid$(s,i+1)

Если нужно заменить в строке символ ch на пустую цепочку (т.е. удалить его), воспользуйтесь стандартной функцией Replace

s = Replace(s,ch,vbNullString)

[SAS888]

To Aent:
1. На сколько я понял, аргументы s2 и s3 содержатся в функции для того, чтобы указывать, какой набор символов (signs1, signs2, signs3, или их комбинацию) требуется заменять. Не случайно в коде есть строка If s1 Then... Естественно, что в функцию требуется добавить If s2 Then... и If s3 Then...
2. Стандартная функция Replace понимает спец. символы. А т.к. в наборе символов для замены они присутствуют, то для того, чтобы не случилось некорректной замены, я предлагаю использовать стандартную функцию рабочего листа Excel Application.Substitute(..., ..., ...)

[Aent]

To SAS888:
1. О задумке автора я догадывался Но в приведённом примере функции
FilterTName s2 и s3 не используются...
2. Стандартная функция VBA Replace НЕ понимает спецсимволов. Что очень жаль. Но вы упорствуете в заблуждении
(http://programmersforum.ru/showpost....74&postcount=2)
По всей видимости, вы путаете функцию replace с методом.