вывод чисел на экран

[Пепел Феникса]

Даша, ну а ты как думала?
кстати, а то разве FASM сорец, или я подзабыл уже?

ТС, ну догадайтесь что еще нужно макросы подключить.

[TotKtoNado]

Сообщение от Sparky

я смотрю вам воообще лень думать... это процедура а не готовая программа.

но как и любая другая программа процедура должна работать
а illegal instruction вобще не знаю что это такое
что имееться ввиду запрещенная команда?

[Sparky]

да нет это TASM.
TotKtoNado, не знаю как у вас, но у меня все работает, вот вам прога она ждет сначала ввода числа, а затем его выводит

.model tiny
.code
org 100h
main:
;вывести сообщение о том что необходимо ввсети число
	call input	;вызов процедуры ввода значения
	call output	;вызов процедуры вывода значения
 	ret
 	
;========================================================================
;процедура ввода	
input proc near
	xor ax,ax
	xor dx,dx
	xor bx,bx
	xor di,di
	mov ah,0ah
	mov dx,offset buff ; адрес буфера
	int 21h 
	
;перевести строку
	mov dl,0ah
	mov ah,02h
	int 21h 
	
; обрабатываем содержимое буфера
	mov si,offset buff+2 ;адрес начала строки
start:
	cmp byte ptr[si]," "
	je _prop
	cmp byte ptr [si],"-" ; если первый символ минус
	jnz _poloz	;в противном случае перейти на обработку положительных
	mov di,1  ; устанавливаем флаг
_prop:
	inc si    ; переходим на следующее
	jmp start
_poloz:
	xor ax,ax
	mov bx,10  ; основание системы счисления
_perevod:
	mov cl,[si] ; берем символ из буфера
	cmp cl,0dh  ; проверям равен ли символ переводу строки
	jz _endin	;перейти на конец обработки
	
; если символ не последний, то проверяем его на правильность
	cmp cl,30h  ; если введен неверный символ <0
    	jl _err	
    	cmp cl,39h  ; если введен неверный символ >9
    	ja _err

	sub cl,30h ; делаем из символа число 
	mul bx     ; умножаем на 10
	jc _err
	add ax,cx  ; прибавляем к остальным
	jc _err
	inc si     ; переходим на следующее число

	cmp di,1
	je srav_32768
	cmp ax,32767
	ja _err
	jmp _perevod	; повторяем
srav_32768:
	cmp ax,32768
	ja _err	
	
	jmp _perevod	; повторяем


; если была ошибка, то выводим сообщение об этом и выходим
_err:
	mov dx, offset error
	mov ah,09
	int 21h
	int 20h

; все символы из буфера обработаны число находится в ax
_endin:
	
	cmp di,1 ; если установлен флаг, то
	jnz _endp
	neg ax   ; делаем число отрицательным
	
_endp:	
	ret
endp input

;====================================================================
;процедура вывода
output proc near  
;; Проверяем число на знак.
        test    ax, ax
        jns     @oi1

;; Если оно отрицательное, выведем минус и оставим его модуль.
	  push ax
        mov     ah, 02h
        mov     dl, '-'
        int     21h
        pop ax
        neg ax
        
;; Количество цифр будем держать в CX.
@oi1:  
        xor     cx, cx
        mov     bx, 10
@oi2:   
       ;cwd
       xor dx,dx
       div bx
; Делим число на десять. В остатке получается последняя цифра.
; Сразу выводить её нельзя, поэтому сохраним её в стэке.
        push    dx
        inc     cx
; А с частным повторяем то же самое, отделяя от него очередную
; цифру справа, пока не останется ноль, что значит, что дальше
; слева только нули.
        test    ax, ax
        jnz     @oi2
; Теперь приступим к выводу.
        mov     ah, 02h
@oi3:   pop     dx
; Извлекаем очередную цифру, переводим её в символ и выводим.
        add     dl, 30h
        int     21h
; Повторим ровно столько раз, сколько цифр насчитали.
        loop    @oi3
	ret
endp output

error db "Введено не число$"
buff	db 255,255 dup(?)
end main

Считайте новогодним подарком