Организация ввода с клавиатуры

[Argogo]

Сообщение от flu3xz

я только в эмуляторе пишу

Если ваш эмулятор пропускает указанные тут ошибки без ругани, как в нём можно получить хоть какой-то верный результат?

Вообще было-бы неплохо, если бы вы написали задание полностью. А то я что-то плохо соображаю, что должен делать ваш код.

[Argogo]

Сообщение от flu3xz

это ваша.

не, программа ваша, я просто убрал явные опечатки.

[flu3xz]

Данная программа заполняет массив С (bx регистр), элементами массивов А(al) и Б(ah) по возрастанию, не используя методы сортировки (якобы).
Находит мин.эл. из А и Б, и заносим его в С, как первый эл., затем inc si, di
и так пока массив С не будет равен размеру А и Б. Но т.к. ds инициализирую не правильно не идет ввод с клавиатуры.

[Argogo]

Сообщение от flu3xz

Но т.к. ds инициализирую не правильно

После того, как определились с моделью памяти - всё с инициализацией DS стало нормально.

Сообщение от flu3xz

не идет ввод с клавиатуры.

Его вообще в вашей программе нет. Как он может идти или не идти?

Сообщение от flu3xz

Данная программа заполняет массив С (bx регистр), элементами массивов А(al) и Б(ah) по возрастанию, не используя методы сортировки (якобы).

Мне кажется, что можно не использовать какой-нибудь конкретный метод сортировки, но в любом случае, если надо "заполнить массив по возрастанию", то сортировать придётся.


Я правильно понял, что из двух массивов надо сделать один, отсортированный по возрастанию?

[Serge_Bliznykov]

Сообщение от Argogo

Мне кажется, что можно не использовать какой-нибудь конкретный метод сортировки, но в любом случае, если надо "заполнить массив по возрастанию", то сортировать придётся.

не совсем.
см. Сортировка слиянием

т.е. формально это, конечно, сортировка. но, по сути, мы берём два упорядоченных массива ("упорядоченных" - обязательное условие!) и записываем в результирующий массив подходящий (меньший или больший - в зависимости от необходимости порядка в результате) элемент, в том массиве, откуда забрали подходящий элемент, увеличиваем индекс. Если один из массивов закончился, то оставшиеся элементы второго массива переписываем в результирующий.
Это, по сути, и есть сортировка.
Но, когда у нас кончились входные массивы, результирующий уже отсортирован, его дополнительно сортировать не нужно.

[flu3xz]

Данная программа заполняет массив С (bx регистр), элементами массивов А(al) и Б(ah) по возрастанию, не используя методы сортировки (якобы).
Находит мин.эл. из А и Б, и заносим его в С, как первый эл., затем inc si, di
и так пока массив С не будет равен размеру А и Б. Но программа из tasm, в эмуляторе все работает,но дата сегмент не

Сообщение от Argogo

Я правильно понял, что из двух массивов надо сделать один, отсортированный по возрастанию?

да, именно так

[flu3xz]

Сообщение от Argogo

Сообщение от flu3xz
не идет ввод с клавиатуры.
Его вообще в вашей программе нет. Как он может идти или не идти?

я не могу его организовать, т.к. ds не инициализирован. команды xchg просто пропускает, флаги бунтуют.

.model	small 
data segment
massA	db	4,2,8,6,10
sizeA = $-massA
massB	db	9,3,5,7,1
sizeB = $-massB
massC	db	(sizeA+sizeB)dup (0)
data ends
stack segment
    db 1024 dup(?) 
    stack ends  
code segment
    assume cs:code, ds:data, ss:stack
begin: 
     mov ax,@data
     mov ds,ax 
           lea si,massA
           lea di,massB
           lea bx,massC
           mov dx,sizeA
           mov cx,sizeB
l1:   
    mov al,[si]
    mov ah,[di]
    cmp al,ah
    jle l2
    xchg    dx,cx
    xchg    si,di
    xchg    ah,al
l2:   mov [bx],al
        inc bx
        inc si
        loop    l1
        mov cx,dx
        mov si,di
l3:  
              mov al,[si]        
              mov [bx],al
              inc bx
              inc si
              loop    l3
    
   mov ax,4C00h
        int 21h 
code ends        
        end begin

[Argogo]

flu3xz, с учётом того, что написал Serge_Bliznykov:

.MODEL SMALL
.STACK  200h

.DATA
    array1  db  1,3,5,7,9
    len1=$-array1
    array2  db  2,3,4,5,6,34,90
    len2=$-array2
    array3  db  len1+len2 dup(0)

.CODE
start:
    mov ax, @data
    mov ds, ax

    mov si, offset array1
    mov di, offset array2
    mov bx, offset array3
    mov cx, len1
    mov dx, len2

@@loop:
    test    cx, cx
    jz      @@save_2nd
    test    dx, dx
    jz      @@save_1st
    ;
    ; (len1)cx>0, (len2)dx>0
    ;
    mov al, [si]
    mov ah, [di]
    cmp al, ah
    jb  @@byte_1st
    ja  @@byte_2nd
    ;
    ; all
    mov [bx], ax
    inc bx
    inc bx
    inc si
    inc di
    dec cx
    dec dx
    jmp @@loop
@@byte_1st:
    mov [bx], al
    inc bx
    inc si
    dec cx
    jmp @@loop
@@byte_2nd:
    mov [bx], ah
    inc bx
    inc di
    dec dx
    jmp @@loop
@@save_2nd:
    ; cx=0
    ; dx unknown
    test    dx, dx
    jz  @@exit
@@save_2nd_1:
    mov al, [di]
    mov [bx], al
    inc di
    inc bx
    dec dx
    jnz @@save_2nd_1
    jmp @@exit
@@save_1st:
    ; cx>0
    ; dx=0
    mov al, [si]
    mov [bx], al
    inc si
    inc bx
    dec cx
    jnz @@save_1st
@@exit:
    
    mov ax, 4c00h
    int 21h    

    end start

тот код, что у вас, намного компактнее + он для чисел со знаком, но мой нагляднее и он для чисел без знака. EMO8086 не жалуется.

[flu3xz]

красиво, но у меня числа со знаками) так мой последний ds нормально принимает? мне все спокойствия флаги не дают.

[Argogo]

Сообщение от flu3xz

но у меня числа со знаками)

меняешь

jb  @@byte_1st
ja  @@byte_2nd

на

jl  @@byte_1st
jg  @@byte_2nd

и, я надеюсь, всё.