Событие на изменения в создаваемом листе

[fun_kok]

Есть лист с кнопкой(Лист1), при нажатии на нее формируется новый лист(Лист2) с данными. Как сделать обработчик события на изменение созданного листа(Лист2)??? И можно ли вообще это сделать в VBA????

[Hugo121]

Есть событие изменения листа книги

Private Sub Workbook_SheetChange(ByVal Sh As Object, ByVal Target As Range)

End Sub

Вот его и используйте.

[Казанский]

Еще можно в модуле ЭтаКнига написать

Dim WithEvents mySh As Worksheet

Private Sub Workbook_NewSheet(ByVal Sh As Object)
  Set mySh = Sh     'связать mySh с создаваемым листом
End Sub

'пример обработчика события вновь создаваемого листа

Private Sub mySh_SelectionChange(ByVal Target As Range)
  MsgBox Target.Address(external:=True)
End Sub

Можно переменную с обработкой событий WithEvents определить в модуле класса, под каждый новый лист создавать экземпляр класса и управлять ими как угодно.

[fun_kok]

Можно немного поподробней (только начинал изучать VBA).Как будет выглядеть обработчик, если нужно
Лист3!A1:D1 = Лист2!A1:D1, т.е. на созданном листе(Лист2), при изменении ячеек в диапазоне A1:D1 изменить содержимое ячеек на листе(Лист3) хотя бы тот же диапазон. Куда этот обработчик записывать, в модуль??? в книгу??? в Лист2 и Лист3 записать не получится, т.к. они создаются после запуска программы.

[Hugo121]

Private Sub Workbook_SheetChange() находится в книге.
Если имена создаваемых листов заранее известны - прописывайте сразу в коде обработку имени изменяемого листа и соотв. реакцию.

[Казанский]

Сообщение от fun_kok

Как будет выглядеть обработчик, если нужно Лист3!A1:D1 = Лист2!A1:D1

Для этого обработчик не нужен, достаточно вставить формулу в ячейки Лист3.
Если у Вас кнопка на Лист1 типа ActiveX, можете все написать в модуле Лист1, рядом с ее кодом:

Dim WithEvents sh2 As Worksheet, sh3 As Worksheet

Private Sub CommandButton1_Click()
  If sh2 Is Nothing Then
    Set sh2 = Worksheets.Add(after:=Sheets(Sheets.Count))
    Set sh3 = Worksheets.Add(after:=Sheets(Sheets.Count))
    sh3.Range("A1:D1").FormulaArray = Replace("=IF(~!A1:D1="""","""",~!A1:D1)", "~", sh2.Name)
  Else
    MsgBox "Листы уже созданы!", vbExclamation
  End If
End Sub

Private Sub sh2_SelectionChange(ByVal Target As Range)
  MsgBox Target.Address(external:=True), vbInformation, "Событие созданного листа"
End Sub

Заметьте, что в этом примере sh2 объявлено "с событиями", а sh3 - нет. Поэтому в выпадающем списке объектов с событиями (панель над окном кода) есть CommandButton1, sh2 и Worksheet, а sh3 нет.
Эта панель позволяет создавать заготовки обработчиков событий в два клика, что очень удобно.