Удаление строк, в которых ячейка помечена цветом

[inspect0r]

Здравствуйте.
У меня есть 3 файла excel: "old", "new", "сравнение". В первых 2-х списки с ФИО и доп. данными построчно, выгружаемые из программы раз в месяц. old - прошлый месяц, new - соответственно текущий. В файле "сравнение" записан макрос, он сравнивает old и new по столбцу ФИО на совпадение, если ФИО и там и там, подсвечивает ячейку с ФИО в обоих желтым цветом.
Подскажите, пожалуйста, макрос в файл "сравнение", который бы удалял из "new" строку целиком с подсвеченной ячейкой.
Спасибо.

[Hugo121]

Допишите рекордером фильтрацию по цвету и удаление - получите свой макрос.
Ну или вообще сразу и удаляйте вместо подсвечивания.

[IgorGO]

в Вашем макросе где-то есть что-то такое:

cells(r,c).Interior.color = Желтый

замените на

cells(r,c).entirerow.delete

учитывайте - это совет, а не решение

[inspect0r]

IgorGO
попробовал подставить, не заработало,
вываливается в ошибку "невозможно получить свойство FindNext класса Range"

Sub Main()
Dim i As Long, x As Range, Fst As String
    Application.ScreenUpdating = False
    Workbooks("old.xls").Sheets(1).Activate
    With Workbooks("new.xls").Sheets(1)
        Columns("C").Interior.ColorIndex = xlNone
        .Columns("C").Interior.ColorIndex = xlNone
        For i = 1 To Cells(Rows.Count, "C").End(xlUp).Row
            Set x = .Columns("C").Find(what:=Cells(i, "C"), LookAt:=xlWhole)
            If Not x Is Nothing Then
                Cells(i, "C").Interior.ColorIndex = 6
                Fst = x.Address
                Do
                    .Cells(x.Row, "C").EntireRow.Delete //было так: .Cells(x.Row, "C").Interior.ColorIndex = 6
                    Set x = .Columns("C").FindNext(x)
                Loop While Fst <> x.Address
            End If
        Next
    End With    
End Sub

что нужно еще поправить?

[IgorGO]

Sub Main()
Dim i As Long, x As Range, Fst As String, rgO As Range, rgN As Range
    Application.ScreenUpdating = False
    Workbooks("old.xls").Sheets(1).Activate
    With Workbooks("new.xls").Sheets(1)
        Columns("C").Interior.ColorIndex = xlNone
        .Columns("C").Interior.ColorIndex = xlNone
        For i = 1 To Cells(Rows.Count, "C").End(xlUp).Row
            Set x = .Columns("C").Find(what:=Cells(i, "C"), LookAt:=xlWhole)
            If Not x Is Nothing Then
                If rgO Is Nothing Then Set rgO = Cells(i, "C") Else Set rgO = Application.Union(rgO, Cells(i, 3))
                Fst = x.Address
                Do
                    If rgN Is Nothing Then Set rgN = .Cells(x.Row, "C") Else Set rgN = Application.Union(rgN, .Cells(x.Row, 3))
                    Set x = .Columns("C").FindNext(x)
                Loop While Fst <> x.Address
            End If
        Next
        rgN.EntireRow.Delete
        rgO.EntireRow.Delete
    End With
End Sub

[inspect0r]

Класс! Работает.
Большое Спасибо.

[IgorGO]

который бы удалял из "new" строку целиком с подсвеченной ячейкой

в предложенном мною варианте повторы в old.xls тоже удаляются

и чтобы это не падало по ошибке, когда нет повторов, надо так написать:

if not rgn is nothing then rgN.EntireRow.Delete