копирование данных из закрытой книги в открытую

[mars56]

создал макрос который копирует данные из "закрытой" книги в другую "открытую" книгу, при копировании данные помещаются в буфер из-за этого появляется предупреждение "В буфере обмена находиться большой объем данных...." Подскажите как можно отключить это предупредение, чтобы оно срабатывало как будто нажали Нет. Данные беруться из книги "PO_сводный отчет" и всталяются в книгу "Тест" на лист PO_сводный отчет, при нажатии на кнопку Ввод . Оба файла лежат в корне с:\База

[EducatedFool]

Можно попробовать так:
(копировать напрямую, а не через буфер обмена)

Sub ввод()
    With Workbooks.Open("c:\база\PO_сводный отчет.xls")
        .Worksheets(1).Columns("A:I").Copy ThisWorkbook.Sheets("PO_сводный отчет").Range("A1")
        .Close True
    End With
    Sheets("база").Activate
End Sub

Ну или так:

Sub ввод()
    Workbooks.Open Filename:="c:\база\PO_сводный отчет.xls"
    Columns("A:I").Copy

    Workbooks("тест.xls").Sheets("PO_сводный отчет").Range("A1").PasteSpecial

    Application.DisplayAlerts = False    ' временно отключаем вывод предупреждений
    Workbooks("PO_сводный отчет.xls").Close
    Application.DisplayAlerts = True ' включаем обратно

    Sheets("база").Activate
End Sub

[mars56]

спасибо!!!

[mars56]

а как скопировать все тоже самое только если книга "PO_сводный отчет" в формате cvs? После переноса данных в книгу "Тест" пытался на листе PO_сводный отчет выделить столбец А затем Данные-Текс по столбцам... результат не корректный (не которые поля сбиваются "причина не выплаты, дата", а надо так чтоб было как после сохранения csv в xls)

[Maxx]

Вставьте этот код:

Private Sub vvod()
    Application.ScreenUpdating = False
    FullFileName = ThisWorkbook.Path & "\PO_сводный отчет.csv"
    NewName = Left(FullFileName, Len(FullFileName) - 3) & "txt"
    Name FullFileName As NewName
    Workbooks.OpenText Filename:=NewName, StartRow:=1, DataType:=xlDelimited, Semicolon:=True
    With ActiveWorkbook
        .Worksheets(1).Columns("A:I").Copy ThisWorkbook.Sheets("PO_сводный отчет").Range("A1")
        .Close True
    End With
    Name NewName As FullFileName
    Sheets("база").Activate
    Application.ScreenUpdating = True
End Sub

[mars56]

спасибо!!!