Нахождение 2 колонок и умножение

[HospodySave]

Здрасте всем программистам.
Нужна помощь в такои задачке с помощью кода:
1)Найти 2 колонки "Номер" "Числа" Они могут находится в диапозоне (а2:er2) во всеи 2 строке вобшем
2)Умножить числа находяшиеся в этих колонках "Номер" "Числа" на 1 или на 2 (любое число).
3)На ваше усмотрение
Если можно добавить к некотороым строкам кода описание ибо я плохо
знаю vba коды.
Columns.rar как выгледит исходный фаил

[vikttur]

А если без VBA?
Числа умножить на единицу - что это даст? Давайте лучше на двойку:

=ИНДЕКС($A$3:$AW$20;СТРОКА(1:1);ПОИСКПОЗ("Номер";$A$2:$AW$2;0))*2

Или копировать двойку, выделить столбец с данными, меню Правка-Спецвставка-Умножить-ОК

[HospodySave]

Круто спасибо.Но мне нужно vba кодом

[HospodySave]

Sub Jopa()
Dim x As Range, y As Range, i As Integer
Application.ScreenUpdating = False: On Error Resume Next
Set x = [B:B].Find("Номер", LookAt:=xlWhole)
If Not x Is Nothing Then
x.

Ну мне кто нить поможет?Выше код как найти Номер а как выделить колонку и умножить на 2 я не в курсе.Хелп люди

[Igor67]

Как вариант

Option Explicit
Option Base 1

Sub test()

Dim rngX As Range, iCel As Range
Dim i As Integer
Dim lLastRow As Long, iColmn As Integer
Dim arrStolbName()
Dim k As Double

'создаем массив с именами столбцов
arrStolbName() = Array("Номер", "Числа")

Application.ScreenUpdating = False ': On Error Resume Next

'начинаем перебор имен и поск их на листе
For i = 1 To UBound(arrStolbName())
'ищем ячейку по строке 2
Set rngX = Rows(2).Find(arrStolbName(i), LookAt:=xlWhole)
If Not rngX Is Nothing Then
'вычисляем номер столбца
iColmn = rngX.Column
'и нижнюю границу данных
lLastRow = Cells(Rows.Count, iColmn).End(xlUp).Row
'задаем диапазон ячеек для обработки
Set rngX = Range(Cells(3, iColmn), Cells(lLastRow, iColmn))
'вводим число для умножения
On Error Resume Next
k = Application.InputBox("Введите число для", "", 1)
If k = 0 Then
MsgBox "Введите число, а то ни чего делать не буду", vbInformation, "НУ?!"
Exit Sub
End If

'перебераем и умножаем все ячейки в диапазоне
For Each iCel In rngX
iCel.Value = iCel.Value * k
Next iCel

End If

Next i

Application.ScreenUpdating = True
End Sub

[HospodySave]

Спасибо Igor67 большое