Сравнение и слияние файлов

[Lemon Tree]

Спасибо ещё раз ))
по сути,все поля,не только эти 9 всегда одни и те же во всех присылаемых файлах.
Я могу собрать в один файл все файлы,в которых есть только одна услуга и в один все файлы,в которых есть остальные услуги. Т.е., получится всего 2 файла,но больших по объёму. А потом уже сверить их по адресам,суммировать начисления,долг и оплату, и отсутствующую услугу закинуть в основной большой файл

[Hugo121]

Я по этим девяти говорил/спрашивал о том, что они всегда в начале и на этих местах?
Т.е. можно это не проверять/искать и брать эти данные из этих позиций? Интересует правда только адрес, раз LS/SG/SNG не нужны. Ну и соответственно тогда собирать данные можно начинать с 10-го столбца, аналогично выгружать с 10-го.
Если будет 2 файла - тогда нет необходимости в диалоге их выбора, не сложно открыть вручную. Но это уже детали, которые можно поменять позже, это не затрагивает основной алгоритм сборки данных.

[Lemon Tree]

да,эти поля всегда на одном и том же месте
но иногда бывают пропущены квартиры в файлах,допустим, одна УК даёт все квартиры,независимо живут в них или нет, а вторая УК даёт без таких квартир

[Hugo121]

Предварительно так.
Но нужно сперва синхронизировать номер ROOM'а - если в одном списке 0, то и в другом нужен 0. Или портить код, навешивая проверки и преобразования...
Ещё можно позже добавить индикацию строк, куда добавлены значения.
Так же можно подумать, как добавить те квартиры, которых нет в сводном файле - сейчас такие молча игнорируются. Хотя в словаре данные есть.

Код в стандартный модуль сборной книги (файл выложить не могу, это сами или попросите кого-нибудь), активируете книгу, из которой тянете данные, по Alt+F8 выполняете код sborka():

Option Explicit

Sub sborka()
    Dim a(), i&, ii&, tAdr$, t$

    If ActiveWorkbook.Name = ThisWorkbook.Name Then MsgBox "Не та книга активна!", vbCritical: Exit Sub

    With CreateObject("Scripting.Dictionary")
        .comparemode = 1
        a = ActiveSheet.[a1].CurrentRegion.Value
        For i = 2 To UBound(a)
            tAdr = a(i, 1) & "|" & a(i, 2) & "|" & a(i, 3) & "|" & a(i, 4) & "|" & a(i, 5) & "|" & a(i, 6)
            For ii = 10 To UBound(a, 2)
                t = tAdr & "|" & a(1, ii)
                .Item(t) = .Item(t) + a(i, ii)
            Next
        Next

        a = ThisWorkbook.Sheets(1).[a1].CurrentRegion.Value
        For i = 2 To UBound(a)
            tAdr = a(i, 1) & "|" & a(i, 2) & "|" & a(i, 3) & "|" & a(i, 4) & "|" & a(i, 5) & "|" & a(i, 6)
            For ii = 10 To UBound(a, 2)
                t = tAdr & "|" & a(1, ii)
                a(i, ii) = a(i, ii) + .Item(t)
            Next
        Next

        With ThisWorkbook.Sheets(1)
            .Columns(7).NumberFormat = "@"    'это думаю косяк примера, но лишним не будет :)
            .[a1].CurrentRegion.Value = a
        End With
    End With

    MsgBox "Данные собраны!"
End Sub

И смотрите, не запустите 2 раза - соберёт вдвойне! Поэтому в конце MsgBox "Данные собраны!".
Кстати, если где-то есть информация, различающая файлы - можно подумать, как это запоминать, чтоб лишний раз случайно не суммировать.
Хотя конечно это лишние тормоза... И лишняя работа.

[Lemon Tree]

спасибо, как Вы быстро! )) но у меня не получилось, ошибка - не та книга активна, хотя пробовала в обоих файлах

[Hugo121]

Ещё раз:
"Код в стандартный модуль сборной книги, активируете книгу, из которой тянете данные, по Alt+F8 выполняете код sborka()"

И не нужно код класть во все книги - только в одну сборную! А то сами запутаетесь, который выполнять, наделаете брака...

Вообще в коде вместо
"Не та книга активна!"
нужно бы писать
"Активируйте лист, из которого собираете данные!".
Так будет правильнее и понятнее, т.к. возможен вариант, что хоть и будет активна нужная книга, но на ненужном листе - и ничего по факту не соберётся, или выпадет в ошибку.
Можно в код добавить и проверку на такой случай, хотя на практике таких запусков не должно быть

    If ActiveSheet.[a1].Value <> "NUMBER" Then MsgBox "Явно не тот лист активен!", vbCritical: Exit Sub

Но это тоже не даёт полной гарантии...
Можно вообще сперва всю первую строку проверить на наличие характерных полей(после проверки что файл не сводный) - но всё равно тут ответственность юзера. Запускать на нужном листе, и только один раз.

P.S. Кстати я бы делал по такой схеме - есть отдельно сводный файл, и папка для свежих исходных файлов.
Набралось сколько-то исходных - не важно сколько - открыли сводный, запустили код - он перебрал/открыл все файлы в папке (можно её выбирать в диалоге, но на практике незачем), импортировал всё что нашёл, файлы перенёс в другую папку "отработанных" файлов.
Так будет просто, быстро и надёжно - повторно подтянется в том случае, если повторно закинете файлы. Но можно вести лог импортированных файлов и не допускать таких ситуаций, если имена файлов всегда разные.
Это в случае если данные всегда на определённом листе (хотя можно перебрать все листы, пока не найдётся [a1].Value = "NUMBER").
Озадачьте своих ИТ - пусть дорабатывают...

[Lemon Tree]

спасибо ))
ИТ-это я,остальные ещё хуже
на самом деле хотела себе облегчить жизнь,но т.к.,не работала в VBA, то не имею представления,как это сделать. Придётся заняться самообразованием ))

[Hugo121]

Тогда тем более Вам нужно вникнуть и далее усовершенствовать процесс самой - будете чувствовать себя уверенной, что при изменении исходных данных сможете сразу подправить макрос.
Но Вы конечно спрашивайте что непонятно, не бросим

[Lemon Tree]

спасибо в очередной раз буду пробовать

[Hugo121]

Ещё раз повторю - код рабочий, но сперва нужно обеспечить соответствие адресов в примере: там в одном room нет, в другом room №0.
Как там в рабочих файлах - Вам виднее. Как вариант - можно заменой по диапазону убрать все нули (ячейка целиком).
Ну или нагружать код этой обработкой - собирать ключ с проверкой: если поле пустое, то ставим 0, иначе значение поля.