как узнать номер ячейки в таблице Ворда, где находится курсор?

[Вождь]

Сообщение от Ципихович Эндрю

...знать не последняя ли она...

Это уже другой вопрос
Вариант 1:

If Selection.Cells(1).Next Is Nothing Then MsgBox "Конец таблицы"

Вариант 2:

With Selection.Cells(1).Range
        If .End >= .Tables(1).Range.End - 1 Then MsgBox "Конец таблицы"
End With

[Ципихович Эндрю]

Спасибо!!!!

[Пименов Александр]

Вот файл с формой статистики выделенной ячейки.
Запускаете макрос NumCell.
При клике на правую кнопку мыши в выбранной ячейке таблицы в форме отобразится общий номер ячейки из общего количества ячеек и номера строки и столбца

[Ципихович Эндрю]

спасибо, посмотрю

[Ципихович Эндрю]

посмотрел, всё время одно и то же

[Пименов Александр]

Да все работает откройте Doc37.doc, запустите NumCell и щелкайте правым кликом по таблице

[Ципихович Эндрю]

ну вот код:

Private WithEvents appWD As Word.Application
Public Tbl As Table
Public rngAll As Range

Private Sub appWD_WindowBeforeRightClick(ByVal Sel As Selection, Cancel As Boolean)
    Cancel = True
    On Error Resume Next
    If Sel.Range.Cells.Count = 1 Then
        If Err.Number = 0 Then
            Set Me.Tbl = Sel.Tables(1)
            Set Me.rngAll = ActiveDocument.Range(Me.Tbl.Range.Start, Sel.Range.Cells(1).Range.End)
            With Me
                .lbl_NumCell.Visible = True
                .lbl_NumCell = .rngAll.Cells.Count
                .lblCountCells.Visible = True
                .lblCountCells = .Tbl.Range.Cells.Count
                .lblNumRow.Visible = True
                .lblNumRow = Sel.Range.Cells(1).RowIndex
                .lblNumCol.Visible = True
                .lblNumCol = Sel.Range.Cells(1).ColumnIndex
            End With
        Else
            MsgBox Err.Description, vbCritical
            With Me
                .lbl_NumCell.Visible = False
                .lblCountCells.Visible = False
                .lblNumRow.Visible = False
                .lblNumCol.Visible = False
            End With
        End If
    End If
End Sub

Private Sub UserForm_Initialize()
    Set appWD = ActiveDocument.Application
End Sub

если сделать:

Private Sub UserForm_Initialize()
    Set appWD = ActiveDocument.Application
MsgBox$ Sel.Range.Cells.Count
End Sub

получаю сообщение Объект reguried

[Пименов Александр]

Private Sub UserForm_Initialize()
    Set appWD = ActiveDocument.Application
MsgBox$ Sel.Range.Cells.Count
End Sub

Естественно что у Вас возникает ошибка в выделенной строке кода, т.к. в данном коде не объявлен объект Sel. Если написать код так, то MsgBox будет выводиться нормально, но при условии что выделение находится в таблице, в противном случее опять будет выводится ошибка.

Private Sub UserForm_Initialize()
Dim Sel As Selection
    Set appWD = ActiveDocument.Application
    Set Sel = Selection
MsgBox$ Sel.Range.Cells.Count
End Sub

[Ципихович Эндрю]

не понимаю зачем нужна строка

 Set appWD = ActiveDocument.Application

формы, для понимания вопроса не нужны, делаю проще

'условие если выделенное, курсор находится в таблице, тогда ...
        If Selection.Information(wdWithInTable) = False Then
                MsgBox$ "Курсор поставьте в любом месте внутри таблицы"
    Else
Dim Sel As Selection
Set Sel = Selection
MsgBox$ Sel.Range.Cells.Count
End If

Всё время 1 получаю
??

[Пименов Александр]

Отвечаю по порядку.
Так как в коде мы используем События объекта Application в данном случае
Private Sub appWD_WindowBeforeRightClick(ByVal Sel As Selection, Cancel As Boolean) мы объявили это в начале кода

Private WithEvents appWD As Word.Application

Нам при иницилизации формы необходимо объявить appWD как Application

Set appWD = ActiveDocument.Application

Теперь по строке кода

Sel.Range.Cells.Count

Она выдает результат, как количество выделенных ячеек и соответственно если у Вас курсор стоит в какой-либо из ячеек таблицы и не выделено ни одной ячейки результат будет всегда 1.
Для того чтобы получить реальный номер ячейки надо набрать код

i = ActiveDocument.Range(Sel.Tables(1).Range.Start, Sel.Range.End).Cells.Count

Данная строка считает количество ячеек в диапазоне от начала таблицы до конца выделения, что и является порядковым номером выделенной ячейки в таблице