Помогите написать программу для нахождения наибольшего из отрицательных чисел

[R71MT]

...она и так EXE.
Скачай FASM (FlatAssembler), скопируй код Stilet'а и вставь в окно FASM'a...
...так что больше -5 или -1 ?!

[Екатерина57]

спасибо,аха -1 конечно

[Екатерина57]

Мне надо код открыть в Dos Box,как это сделать?

[Stilet]

Он не рассчитан на ДОС. Я писал пример под Виндовс.

[R71MT]

Екатерина57. Вот тебе код на FASM..
- макс.отрицательное число равно слову, т.е. - 32767;
- положительные числа игнорируются;
- проверка осуществляется на "Меньше", т.к. после NEG условие становится "Больше"..

[R71MT]

USE16
ORG 100h
JMP start

mess0  DB  13,10,' FIND MAX NEGATIVE DIGIT (R)'
       DB  13,10,' Example: 1 205 -909 37 -13 -32000 25'
       DB  13,10,' ----------------------------------------------------'
       DB  13,10,' Input digital array ..: $'
mess1  DB  13,10,' Max negative digit ...: -$'
mess2  DB  7,'<--- INPUT ERROR!!!$'
max    DW  0                    ; буфер отрицательного числа (для сравнения)

start:
   MOV   AH,9
   MOV   DX,mess0               ; запрос на ввод чисел..
   INT   21h

   XOR   CX,CX                  ; счётчик отриц.элементов сбрасываем в нуль
inArray:                        ; заполняем массив..
   MOV   AH,1                   ; ввод с эхо средствами DOS
   INT   21h
   CMP   AL,13                  ; это ENTER ?!
   JE    findMax                ; если да - начинаем поиск максимального
   CMP   AL,'-'                 ; это знак минус ?!
   JE    negative               ; да - сохраняем введённое число в стеке
   JMP   inArray                ; читаем следующий символ..

negative:                       ; попался знак минус..
   CALL  SaveNEG                ; переводим символы юзера в число (fn возвращает в DI)
   CMP   DI,32767               ; макс.знаковое слово = 32767 dec
   JA    error                  ; юзер ввёл не больше этого числа ?! Да - ошибка!
   NEG   DI                     ; сделаем из числа - отрицательное.
   PUSH  DI                     ; сохраним его в стеке..
   INC   CX                     ; ^^.. и увеличим счётчик отриц.чисел (для LOOP)
   JMP   inArray                ; читаем следующий символ..

error:                          ; если юзверь ввёл число больше чем 32767..
   MOV   AH,9                   ; покажем сообщение об ошибке
   MOV   DX,mess2
   INT   21h
   JMP   exit                   ; выходим из программы!

findMax:                        ; юзер нажал ENTER. Начинаем поиск наибольшего.
   MOV   AH,9                   ; покажем мессагу
   MOV   DX,mess1
   INT   21h
@1:                             ; в СХ у нас кол-во PUSHей (отриц.чисел)
   POP   AX                     ; снимаем со-стека число..
   CMP   AX,[max]               ; ^^.. и сравниваем его с переменной
   JGE   next                   ; если больше/равно - пропускаем число
   MOV   [max],AX               ; значит меньше. Записываем его в переменную
next:
   LOOP  @1                     ; мотаем цикл CX-раз

   MOV   AX,[max]               ; все числа сравнили! Возьмём наименьшее в АХ
   NEG   AX                     ; команда NEG сделает из него наибольшее..
   MOV   BX,10                  ; выводить на экран будем в 10-тичной СС
   CALL  HEX2ASC                ; покажем число!

exit:
   XOR   AX,AX                  ; ждём клавишу и на выход
   INT   16h
   INT   20h

;нннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннннн
;//==========; Процедура переводит число в символы и выводит их на экран ==========|
;//==========; на входе принимает: АХ = число, BX = система счисления =============| 
HEX2ASC:
   PUSHA                   
   XOR   CX,CX
isDiv:
   XOR   DX,DX
   DIV   BX
   PUSH  DX
   INC   CX
   OR    AX,AX
   JNZ   isDiv
isOut:
   POP   AX
   CMP   AL,9
   JLE   noHex
   ADD   AL,7
noHex:
   ADD   AL,30h
   INT   29h
   LOOP  isOut
   POPA
RET

;//==========; Процедура сохраняет юзерский ввод в DEC ===========================|
SaveNEG:
   XOR   DI,DI             ; в регистре DI будет число
NextNumber:
   MOV   AH,1              ; ввод без эхо...
   INT   21h
   CMP   AL,13             ; это ENTER?
   JE    EnterStop         ; да - выходим!
   CMP   AL,' '
   JE    EnterStop
   AND   AX,0Fh            ; переводим символ в цифру
   XCHG  AX,DI             ; меняем последнее и ранее/введёное число
   MOV   BX,10             ; умножаем ранее введеное число на 10
   XOR   DX,DX             ; взводим флаги нуля и чётности
   MUL   BX                ; делим AX на BX. Результат в АХ
   ADD   DI,AX             ; прибавляем его к DI. Теперь в DI введёное число
   JMP   NextNumber        ; следующий символ..
EnterStop:
RET

[Екатерина57]

Спасибо огромное,я вам очень благодарна

блин,а код подходит только к Fasm,пыталась в Dos Box открыть выдает 55 ошибок??

[Stilet]

Код и поста №16 вроде жеж под ДОС заточен? :confised:
а какие ошибки, и что у тебя за компилятор? Турбоассемблер?

[Екатерина57]

Вот,что выдает
k.jpg

[R71MT]

Екатерина57, ты чем собираеш исходник? Компилятор какой? MASM, TASM, NASM, FASM и т.д.? Вот тебе исполняемый файл.. Запусти под DOS-BOX..