Чтение и преобразование строк. masm32

[Danddz]

Методичек нет, учебников нет, нам в МГУ сказали, вот вам задание, развлекайтесь сами. Это под windows.

[Danddz]

R71MT, можно Вас попросить написать мне этот алгоритм, если вам не тяжело, а то у меня голова вообще уже не соображает от такого количества информации, а до сдачи все меньше времени. Я не хочу Вас напрягать.

[R71MT]

..а чё так поздно спохватился-то, если завтра сдавать???
сейчас набросаю (только на FASM'e), а что получится - допилишь сам

[R71MT]

вот тебе готовый код, только на FASM'e. разбирайся...
(лучше это, чем ничего):

; fasm-code
; хэндлы 'GetStdHandle' по умолчанию = stdOut(7), stdIn(3)
;-----------
; Считать две строки!
; В длиной строке меняем все/строчные на (N mod 10), где N = № буквы,
; а в короткой - после последнего 'a', все на '*'.
;----------------------------------------------------------------
format    PE  Console 4.0
include  'win32ax.inc'
entry     start

section   '.data' data readable writeable

mes1      db   'String(1):  '   ; строки диалога..
mes2      db   'String(2):  '   ;   ...
mes3      db   'Result...:  '   ;     ...
len       dd   $ - mes3         ; длина у всех одинакова
crlf      db   13,10            ; перевод строки!

buff1     db   100 dup(0)       ; буфер для строки(1) max = 100 символов.
buff2     db   100 dup(0)       ; буфер для строки(2)
size1     dd   0                ; реальная длина ввода(1)
size2     dd   0                ; реальная длина ввода(2)
bigStr    dd   0,0              ; dword(0)= размер, dword(1)= адрес
smallStr  dd   0,0              ; ^^^^^

section   '.code' code readable executable
start:
;------ Запрос и вводим строки
        invoke   WriteConsoleA, 7, mes1, [len], 0,0     ; запрос на ввод(1)
        invoke   ReadConsoleA, 3, buff1, 100, size1,0   ; макс.100 в буфер(1)

        invoke   WriteConsoleA, 7, mes2, [len], 0,0     ;
        invoke   ReadConsoleA, 3, buff2, 100, size2,0   ;

;------ Сравниваем размеры введённых строк
; В первых dword'ax big/smallSdtr будут размеры строк, во-вторых - их адреса
        push     buff1 [size1]    ; запомним последовательность в стеке
        push     buff2 [size2]    ; ^^^^
        mov      eax,[size1]      ; сравнить размеры строк
        cmp      eax,[size2]      ;
        jb       @small           ; если первая меньше второй

        pop      [smallStr] [smallStr+4]   ; снимаем в переменные со-стека
        pop      [bigStr]   [bigStr+4]     ;   ...в нужном порядке.
        jmp      @big                      ;

@small: pop      [bigStr]   [bigStr+4]     ;
        pop      [smallStr] [smallStr+4]   ;

;------ Обработка длинной строки (меняем все/строчные на (N mod 10))
@big:   mov      ecx,[bigStr]     ; ECX = длина строки (цикл)
        mov      esi,[bigStr+4]   ; ESI = её адрес для стр.инструкций 'LODSB'
        mov      edi,esi          ; EDI = он-же приёмник для записи 'STOSB'
        xor      ebx,ebx          ; EBX = позиция в строке для 'mod 10'
@cyc1:  lodsb                     ; AL = очередной символ из ESI
        inc      bl               ; считаем позицию...
        cmp      al,'a'           ; фильтр строчных
        jb       @next1           ;    ...
        cmp      al,'z'           ;
        ja       @next1           ; если не в диапазоне
        mov      al,bl            ; иначе: AAM = AL/10 (AH-целое, AL-остаток)
        aam                       ; AL = BL mod 10
@next1: stosb                     ; запись AL в ES:EDI
        loop     @cyc1            ; промотать СХ-раз...

;------ Обработка короткой строки (после последнего 'a', все на '*')
        mov      ecx,[smallStr]   ; ECX = длина короткой строки (цикл)
        dec      cx
        push     ecx              ;   ...(запомнить)
        mov      edi,[smallStr+4] ; EDI = её адрес для 'SCASB'
        add      edi,ecx          ; смещаемся в конец строки
        mov      al,'a'           ; AL = что искать!
        std                       ; ставим обратный шаг (Set-Direction-Flag)
@cyc2:  repne    scasb            ; ПОИСК (с конца строки, справо/налево)....
        cld                       ; опять прямой шаг (Clear-Direction)
        pop      eax              ; иначе: EAX = длинна всей строки
        or       ecx,ecx          ; нашли букву 'a' ???
        jz       @stop            ; нет!

        xchg     ecx,eax          ; иначе: поменять операнды
        sub      ecx,eax          ; вычисляем длинну хвоста
        add      edi,2            ; EDI (позиция) уже установлена на -2, на место её
        mov      al,'*'           ; что записать
        rep      stosb            ; заполняем хвост после 'a', значение AL!!!

;------ Вывод результата из буфера
@stop:  invoke   WriteConsoleA, 7, mes3, [len],   0,0
        invoke   WriteConsoleA, 7, buff1,[size1], 0,0
        invoke   WriteConsoleA, 7, crlf,2,0,0          ; перевод строки
        invoke   WriteConsoleA, 7, mes3, [len],   0,0
        invoke   WriteConsoleA, 7, buff2,[size2], 0,0

        jmp      $                ; (!) для теста! закомментировать
@exit:  invoke  ExitProcess, 0    ; на выход!

;------ Импорт API -----------------------------//
section '.idata' import data readable writeable
library  kernel32,'KERNEL32.DLL',\
         user32,  'USER32.DLL'
         include  'api\kernel32.inc'
         include  'api\user32.inc'

[Danddz]

Спасибо большое, поразвлекаюсь.

[R71MT]

скачай FASM , скопируй его в окно и нажми F9
получишь исполняемый файл ЕХЕ

[Danddz]

Так не интересно, я так ничего не пойму, я просто взял ваш код, как некий шаблон (ну я просто начал понимать более менее, как все работает и как все надо организовывать), сейчас пишу свой код

[Danddz]

Доброго времени суток, если вам интересно, кидаю код, который написал сам.

includelib C:\masm32\lib\masm32.lib
includelib C:\masm32\lib\kernel32.lib
includelib C:\masm32\lib\user32.lib
includelib C:\masm32\lib\msvcrt.lib
includelib C:\masm32\lib\io_proc.lib
include C:\masm32\include\console.inc

N equ 100 ;length of text
.data
i dd 0 ;temp
text db N dup (?) ;text array
.code
start:
mov ebx, -1;
mov eax, 0
mov ecx, -1
outstrln 'Enter the text to the point. Not more than 100 symbols.'
Read: ;
inc ecx;
cmp ecx, N ; check the number of characters
jl Characters
outstrln 'Many characters'
jmp Exit1 ; error
Characters:
inchar text[ecx]
cmp text[ecx], 97 ;checking the letter 'a'
jnz NotA ;
mov ebx, ecx ;
NotA:
cmp text[ecx], 46 ;checking dot
jnz Read
mov i, ebx;
sub i, ecx ;
mov eax, 1
cmp ebx, -1
jz FoundDot
Change:;
mov text[eax+ebx], '*' ; change to '*'
inc eax ;
inc i ;
jnz Change
mov text[ecx], ' '
FoundDot:
cmp ecx, 0 ;checking the length of the text
jnz OutPut
outstrln 'There are no letters in the text.' ;
OutPut:
outstrln offset text[0] ;text output
jmp Exit1
Exit1: ;exit from the program
MsgBox "Task End", 'Click OK to exit.', MB_OK
exit
end start

[Danddz]

правда тут нет ввода двух текстов , задание поменяли, но все основное есть