Мониторинг текстового файла

[zander]

Const ИмяФайла = "C:\Documents and Settings\Игорь\Рабочий стол\Текстовый документ.txt"
Dim РазмерФайла As Long
Const ВременнойИнтервалМеждуПроверками = 2 ' в секундах

Скажите А перед const необходимо поставить Public или Private?

[EducatedFool]

Если макросы, использующие эти константы и переменную, будут находиться в другом модуле, то используйте такой вариант:

Public Const ИмяФайла = "C:\Текстовый документ.txt"
Public РазмерФайла As Long
Public Const ВременнойИнтервалМеждуПроверками = 2

Если же весь код будет расположен в одном модуле - то можно оставить всё как есть.

[zander]

Отлично, работает как надо... (немного переделал что бы на лист выводилось общего файла Excel) Но вот как теперь получить возможность выскочить из бесконечного цикла мониторинга, что бы исполнить макрос обработки когда обнаружится новая строка? А потом по кнопке (ну или событию) опять запустить мониторинг?

[EducatedFool]

Выйти из цикла, и запустить его вновь - не проблема.

А по какому событию это будет происходить - решать уже Вам (это может быть что угодно: по истечении 12 часов работы, после 350 проверок, при нажатии кнопки на листе или на панели инструментов, при выполнении какого-либо условия, при наличии в файле более 1000 строк, и т.д. и т.п.)

Как скажете - так и сделаем.

Но зачем что-то изобретать?
Есть же макрос ОбработкаФайла, который как раз запускается при обнаружении в текстовом файле новых строк.
В этот макрос и допишите обработку.
Или просто вызывайте нужный макрос обработки строк из макроса ОбработкаФайла

Выходить из бесконечного цикла для этого вовсе необязательно...

[zander]

Вот запускаем мы (напрмер кнопкой) макрос СлежениеЗаФайлом, появилась новая строчка, отработал макрос Обработкафайла и параллельно с ним мой собственный макрос, который реагирует на изменении в текстовом файле. Но пока не появится результат отработки от моего собственного макроса, обрабатывать текстовый не надо, иначе мой собственный макрос (при появлении очередной новой строчки) начнет дергать удаленный софт до получения результата от предыдущей обработки. Поэтому хотелось бы иметь возможность останавливать мониторинг (ну и возобновлять) как кнопкой так и без нее.

[EducatedFool]

В этом случае можно сделать так:

Public Const ИмяФайла = "C:\Documents and Settings\Игорь\Рабочий стол\Текстовый документ.txt"
Public РазмерФайла As Long, ПоискИзмененийВременноОтключён As Boolean
Public Const ВременнойИнтервалМеждуПроверками = 2

Sub СлежениеЗаФайлом()
    Do While True    ' бесконечный цикл
        If Not ПоискИзмененийВременноОтключён Then
            НовыйРазмерФайла = CreateObject("scripting.filesystemobject").GetFile(ИмяФайла).Size
            If НовыйРазмерФайла > РазмерФайла Then ОбработкаФайла: РазмерФайла = НовыйРазмерФайла
        End If
        t = Timer: While t + ВременнойИнтервалМеждуПроверками > Timer: DoEvents: Wend ' пауза
    Loop
End Sub

Sub ОбработкаФайла()
    Application.ScreenUpdating = False
    Workbooks.OpenText Filename:=ИмяФайла, DataType:=xlDelimited, Comma:=True
    ActiveWorkbook.Worksheets(1).Cells.Copy ThisWorkbook.Worksheets(1).[a1]
    ActiveWorkbook.Close False
    Application.ScreenUpdating = True

    ПоискИзмененийВременноОтключён = True
    ' здесь запускается Ваш макрос
    ' пока он работает, изменения в текстовом файле не отслеживаются
    ПоискИзмененийВременноОтключён = False
End Sub

[zander]

А кнопочкой как можно прекратить исполнение?

[EducatedFool]

Создайте 2 кнопки, и повесьте на них два последних макроса:

Public Const ИмяФайла = "C:\Documents and Settings\Игорь\Рабочий стол\Текстовый документ.txt"
Public РазмерФайла As Long, ПоискИзмененийВременноОтключён As Boolean
Public Const ВременнойИнтервалМеждуПроверками = 2
Public БесконечныйЦиклАктивирован As Boolean

Sub СлежениеЗаФайлом()
    БесконечныйЦиклАктивирован = True
    Do While БесконечныйЦиклАктивирован    ' бесконечный цикл
        If Not ПоискИзмененийВременноОтключён Then
            НовыйРазмерФайла = CreateObject("scripting.filesystemobject").GetFile(ИмяФайла).Size
            If НовыйРазмерФайла > РазмерФайла Then ОбработкаФайла: РазмерФайла = НовыйРазмерФайла
        End If
        t = Timer: While t + ВременнойИнтервалМеждуПроверками > Timer: DoEvents: Wend    ' пауза
    Loop
End Sub

Sub ОбработкаФайла()
    Application.ScreenUpdating = False
    Workbooks.OpenText Filename:=ИмяФайла, DataType:=xlDelimited, Comma:=True
    ActiveWorkbook.Worksheets(1).Cells.Copy ThisWorkbook.Worksheets(1).[a1]
    ActiveWorkbook.Close False
    Application.ScreenUpdating = True

    ПоискИзмененийВременноОтключён = True
    ' здесь запускается Ваш макрос
    ' пока он работает, изменения в текстовом файле не отслеживаются
    ПоискИзмененийВременноОтключён = False
End Sub


Sub ЗапускЦикла()
    If Not БесконечныйЦиклАктивирован Then СлежениеЗаФайлом
End Sub

Sub ОстановЦикла()
    БесконечныйЦиклАктивирован = False
End Sub

[zander]

Не хочет останавливаться Останавливает исполнение только кнопка Reset в окне Visual Basic

[EducatedFool]

Не хочет останавливаться

Согласен, ошибочка вышла...

Так точно работает:

Public Const ИмяФайла = "C:\Documents and Settings\Игорь\Рабочий стол\Текстовый документ.txt"
Public РазмерФайла As Long, ПоискИзмененийВременноОтключён As Boolean
Public Const ВременнойИнтервалМеждуПроверками = 1
Public БесконечныйЦиклАктивирован As Boolean

Sub СлежениеЗаФайлом()
    'Debug.Print БесконечныйЦиклАктивирован
    If Not БесконечныйЦиклАктивирован Then Exit Sub
    If Not ПоискИзмененийВременноОтключён Then
        НовыйРазмерФайла = CreateObject("scripting.filesystemobject").GetFile(ИмяФайла).Size
        If НовыйРазмерФайла > РазмерФайла Then ОбработкаФайла: РазмерФайла = НовыйРазмерФайла
    End If
    If БесконечныйЦиклАктивирован Then Application.OnTime  _
            Now + TimeSerial(0, 0, ВременнойИнтервалМеждуПроверками), "СлежениеЗаФайлом"
End Sub

Sub ОбработкаФайла()
    Application.ScreenUpdating = False
    Workbooks.OpenText Filename:=ИмяФайла, DataType:=xlDelimited, Comma:=True
    ActiveWorkbook.Worksheets(1).Cells.Copy ThisWorkbook.Worksheets(1).[a1]
    ActiveWorkbook.Close False
    Application.ScreenUpdating = True

    ПоискИзмененийВременноОтключён = True
    ' здесь запускается Ваш макрос
    ' пока он работает, изменения в текстовом файле не отслеживаются
    ПоискИзмененийВременноОтключён = False
End Sub

Sub ЗапускЦикла()
    БесконечныйЦиклАктивирован = True
    СлежениеЗаФайлом
End Sub

Sub ОстановЦикла()
    БесконечныйЦиклАктивирован = False
End Sub