Задачи на BAT-файлах

[Serge_Bliznykov]

mutabor
наберите

HELP FOR

навскидку, обработка всех *.arj файлов (пример выдран из ARJ2RAR.bat):

...
if exist *.arj goto MaskYeah
echo %1 -- files cannot be found.

echo %1 -- files cannot be found. >>!arj2rar.!!!
goto Exit
:MaskYeah
if exist *. ren *.$e$
ren *.arj *.
for %%f in (*.) do call arj2rar %%f
if exist *.$e$ ren *.$e$ *.
goto Quit
...

ну пример старый, похоже, в команде for раньше не было модификаторов:

%~nI - из переменной %I выделяется только имя файла

[mutabor]

Спасибо за подсказку, нужный скрипт написал. Теперь хотелось бы его немного полирнуть чтобы каждую итерацию команды не выводились на экран, а вместо этого в консоли была такая надпись - Обработка файла 35 из 200, т.е. отображать прогресс. Как такое прикрутить к моему скрипту?

for %%f in (*.ex1) do myprogram %%f /param %%~nf.ex2

[Arigato]

Завести переменную, её инкремировать в цикле и выводить значение на экран.

[mutabor]

Сообщение от Arigato

Завести переменную, её инкремировать в цикле и выводить значение на экран.

Ну это понятно. Хотелось бы на реализацию посмотреть. Ладно, не буду навязываться, фиг с ним, и так сойдет.

[Arigato]

Примерно так:

@echo off
setlocal enabledelayedexpansion

rem Считаем общее количество файлов:
set count=0
for %%f in (*.ex1) do set /a count=!count!+1

rem Начинаем обработку файлов:
set cnt=1
for %%f in (*.ex1) do (
	cls
	echo Obrabotka faila !cnt! is %count%
	myprogram %%f /param %%~nf.ex2
	set /a cnt=!cnt!+1
)

endlocal

[sneksnek2006]

Здравствуйте! Такая проблема. У меня ноут. Дома и на работе сети. Требуется батником их перенастраивать. Я написал следующее:

@echo off
color 0f
title Настройка сети
cls


:lan_edit
@Color 0f
cls
echo --------------------------
echo -- Выбирите сеть --
echo --------------------------
echo - 1 - BIA -
echo - 2 - LANS.by -
echo - 3 - Показать маршруты -
echo - 4 - Выход -
echo --------------------------
set menuprompt=x
set /p menuprompt=Ваш выбор:
if /i %menuprompt%==1 goto lan_edit_1
if /i %menuprompt%==2 goto lan_edit_2
if /i %menuprompt%==3 goto route_print
if /i %menuprompt%==4 goto exit
cls
color 0c
echo -------------------------
echo -- Неправильный выбор! --
echo -------------------------
set temp=x
set /p temp=Нажмите Enter...
if /i %temp%==. echo ok
goto lan_edit


:route_print
@Color 0e
cls
echo Маршруты:
route.exe print
set temp=x
set /p temp=Нажмите Enter...
if /i %temp%==. echo ok
goto :lan_edit


:lan_edit_1
@Color 0f
cls
netsh interface ip set address name=lan source=static addr=10.15.1.163 mask=255.255.255.0 gateway=10.15.1.100 gwmetric=1
netsh interface ip set dns name=lan source=static addr=81.25.32.34
netsh interface ip add dns name=lan addr=81.25.32.9 index=2
set temp=x
set /p temp=Нажмите Enter...
if /i %temp%==. echo ok
goto :lan_edit


:lan_edit_2
@Color 0f
cls
netsh interface ip set address name=lan source=static addr=192.168.2.163 mask=255.255.255.0 gateway=192.168.2.251 gwmetric=1
netsh interface ip set dns name=lan source=static addr=93.125.40.2
netsh interface ip add dns name=lan addr=93.125.41.2 index=2
set temp=x
set /p temp=Нажмите Enter...
if /i %temp%==. echo ok
goto :lan_edit


:exit
@color 01
cls
exit

Но когда доходит до netsh, выполнение останавливается. Но в тоже время если создать отдельно два батника без менюшки, то все работает.
Почему??

[Arigato]

Непонятная конструкция:

set temp=x
set /p temp=Нажмите Enter...
if /i %temp%==. echo ok

Не проще использовать pause?

Что до самого вопроса, то похоже на мистику. Видимо, где-то что-то не то делаете, что именно, сказать сложно, т.к. из примера не видно.

[Spider1]

Доброго времени суток!
подскажите пжлста, как можно при помощи bat файла, просмотреть файл на наличие определенной строки и если этой строки нет тогда добавить ее, иначе закрыть файл?

[Arigato]

Spider1
Решение вашей задачи:

@ echo off
set file=test.txt
set str=Hello, World
for /f "tokens=*" %%i in (%file%) do if "%%i"=="%str%" exit /b
echo %str%>>%file%

[Spider1]

ага то что нужно, спасибо больчое!
оказывается все так просто оказалось, в 4 строчках.