Можно упростить этот макрос?

[valerij]

Сообщение от Hugo121

"и потом по выбору месяца" - вот я и поймал
По выбору месяца, а не месяцев!

Ну правильно, выбирается один месяц из 12.
Hugo121
Ну вы же мне сделали вып. список с месяцами.!!!
Сорри - Step_UA сделал, перепутал.

[Hugo121]

Потому это отчёт за месяц, а не за год.
Начал что-то делать, к вечеру может покажу свой вариант.
Хотя это можно и формулами делать, если список машин известен заранее.

[valerij]

Сообщение от Hugo121

Потому это отчёт за месяц, а не за год.
Начал что-то делать, к вечеру может покажу свой вариант.
Хотя это можно и формулами делать, если список машин известен заранее.

Спросил, данные за месяц, только таблица(лист Отчёт) должна обнулится тогда, когда я внесу дату текущего месяца, не по системной дате!!
Это может быть и не первым числом месяца.
Вот как в марте, начнут вводить данные только 04.03.2014

[Hugo121]

Вот такой вариант.
Но сперва передвинуть в сторону строку сумм - например под ячейку с выбором месяца или правее.
Эти суммы в принципе можно добавить вниз кодом, но лень. Если такой вариант возмёте - тогда можно и эти суммы дописать.

код в модуль листа ОТЧЁТ:

Private Sub Worksheet_Change(ByVal Target As Range)

    If Target.Address(0, 0) <> "F1" Then Exit Sub
    tt Target.Value

End Sub

код в стандартный модуль:

Option Explicit

Sub tt(m$)
    Dim b(), d(), i(), aa(), ad(), af(), x&, ma, mes&, il&
    Dim dI As Object, dAA As Object, dAD As Object, dAF As Object, k

    Set dI = CreateObject("scripting.dictionary"): dI.comparemode = 1
    Set dAA = CreateObject("scripting.dictionary"): dAA.comparemode = 1
    Set dAD = CreateObject("scripting.dictionary"): dAD.comparemode = 1
    Set dAF = CreateObject("scripting.dictionary"): dAF.comparemode = 1

    ma = Split("Месяц,Январь,Февраль,Март,Апрель,Май,Июнь,Июль,Август,Сентябрь,Октябрь,Ноябрь,Декабрь", ",")
    For x = 1 To 12
        If m = ma(x) Then mes = x: Exit For
    Next

    With Sheets("Расход горючего")
        il = .Range("b" & .Rows.Count).End(xlUp).Row
        b = .Range(.Range("b4"), .Range("b" & il)).Value
        d = .Range(.Range("d4"), .Range("d" & il)).Value
        i = .Range(.Range("i4"), .Range("i" & il)).Value
        aa = .Range(.Range("aa4"), .Range("aa" & il)).Value
        ad = .Range(.Range("ad4"), .Range("ad" & il)).Value
        af = .Range(.Range("af4"), .Range("af" & il)).Value
    End With

    For x = 1 To UBound(b)
        If Month(d(x, 1)) = mes Then
            dI.Item(b(x, 1)) = dI.Item(b(x, 1)) + i(x, 1)
            dAA.Item(b(x, 1)) = dAA.Item(b(x, 1)) + aa(x, 1)
            dAD.Item(b(x, 1)) = dAD.Item(b(x, 1)) + ad(x, 1)
            dAF.Item(b(x, 1)) = dAF.Item(b(x, 1)) + af(x, 1)
        End If
    Next

    x = 0
    If dI.Count > 0 Then
        ReDim out(1 To dI.Count, 1 To 5)
        For Each k In dI
            x = x + 1: out(x, 1) = k
            out(x, 2) = dI.Item(k): out(x, 3) = dAA.Item(k)
            out(x, 4) = dAD.Item(k): out(x, 5) = dAF.Item(k)
        Next
    End If

    With Sheets("Отчёт")
        .[a2].Resize(.UsedRange.Rows.Count, 5).ClearContents
        If x > 0 Then .[a2].Resize(x, 5) = out
    End With

End Sub

Эта возня с месяцами для универсальности - у меня Эксель английский...

[valerij]

Сообщение от Hugo121

Эта возня с месяцами для универсальности - у меня Эксель английский...

Hugo121
Я пока не дома, буду ближе к вечеру, забыл добавить, что выбор месяца в листе Отчёт - [F1], уже не нужен, если только без него нельзя обойтись.
Но пусть будет, убрать всегда успеется. )

[Hugo121]

Ну в принципе без него можно обойтись. Но где-то нужно указать, за какой месяц Вам нужен отчёт

[valerij]

Сообщение от Hugo121

Ну в принципе без него можно обойтись. Но где-то нужно указать, за какой месяц Вам нужен отчёт

Hugo121
Вставил макрос, СУПЕР!!!!!!!!!
Есть мелочи, ввели данные - март месяц, перешли в лист Отчёт и каждый раз приходится активировать месяц, что бы скорректировать данные.
Ведь необязательно ждать конца месяца.
Сам попробую поменять, потом отпишусь.

[Hugo121]

Можно этот макрос дополнительно запускать при переходе на лист.

[valerij]

Сообщение от Hugo121

Можно этот макрос дополнительно запускать при переходе на лист.

А где он удаляет строку([A20]) Итог в листе Отчёт?

Нашёл, так

.[a2].Resize(.UsedRange.Rows.Count - 2, 5).ClearContents

[Hugo121]

Этот итог я сам туда перетащил, чтоб он не затирался, я об этом говорил.
Если такой вариант отчёта годится, то можно или итог держать постоянно под шапкой (что просто и надёжно, код чуть скорректировать), или нужно дописывать код, чтоб он этот итог генерил под таблицей (координаты известны). Это нужно дописать кому-то...