Рассылка!

[Chemik]

Добрый день! Хотел уточнить , возможно сделать эмэил рассылку с помощью Access 2007...Как должно быть в идеале , есть таблица в которой 5.тыс контактов которые разбиты на идентификаторы. Допустим мне нужно по идентификаторам отсортировать 500контактов и отправить им всем одно и то же сообщение...Возможно ли это сделать непосредственно из Access , если возможно , то как ?

[Chemik]

Кто-то может ответить вообще это возможно или нет ?

[Teslenko_EA]

Здравствуйте Chemik.
"..возможно сделать эмэил рассылку с помощью Access..?" - хотя СУБД (система управления базами данных) MS Access не является почтовой программой
и не "умеет" работать с почтой, задачу можно выполнить подключив к проекту библиотеку соответствующего приложения (MS Outlook)
и выполнив подобный код:

Sub sendingToAddress()
Dim cn As New ADODB.Connection, rs As New ADODB.Recordset, s$
Const sQ = "select eAdress from table where ..." 'запрос возвращающий адреса получателей
Const sSubj = "Тема сообщения ..."
Const sBody = "Тело сообщения ..."
Set cn = CurrentProject.Connection

rs.Open sQ, cn, adOpenStatic, adLockReadOnly
If Not rs.EOF Then
    s = rs.GetString("; ") 'получение списка адресов
    sendMail s, sSubj, sBody 'отправка адресатам сообщения
End If
If Not rs.State = 0 Then rs.Close
Set rs = Nothing
If Not cn.State = 0 Then cn.Close
Set cn = Nothing
End Sub
Function sendMail(sTo$, sSybject$, sBody$)
Dim oApp As Object, oItem As Object, bRun As Boolean
On Error Resume Next
Set oApp = GetObject(, "Outlook.Application")
If Not Err.Number = 0 Then
    bRun = True: Err.Clear
    Set oApp = CreateObject("Outlook.Application")
End If
Set oItem = oApp.CreateItem(0)
With oItem
    .to = sTo: .Subject = sSybject: .Body = sBody
    '.Display'отображение при необходимости Outlook
    .Send 'отправка
End With
'If bRun Then oApp.Application.Quit 'закрывать Outlook если открывался
End Function

Евгений.

[Chemik]

Спасибо большое Тестировать буду через недельку , потом отпишусь!)

[gluk_fm]

Не знаю как в 2007, но в 2003 у меня там возникла проблема, что при каждой отправке необходимо подтверждение отправки сообщения. Я долго бился над данной проблемой, но так ничего и не нашёл - поэтому пошёл другим путём и нашёл приблизительно следующее:

Sub CDO()


Set objMsg = CreateObject("CDO.Message")
Set Config = CreateObject("CDO.Configuration")
Set Config = objMsg.Configuration
objMsg.FROM = "от"
objMsg.To = "кому"
objMsg.Subject = "Test sending email from sñriðt"
objMsg.Textbody = "This is a body of E-mail."
Config("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
Config("http://schemas.microsoft.com/cdo/configuration/smtpserver") = "имя серевера"
Config("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
Config("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = 1
Config("http://schemas.microsoft.com/cdo/configuration/sendusername") = "путь к вашей папке"
Config("http://schemas.microsoft.com/cdo/configuration/sendpassword") = "пароль для входа на компьютер"
Config.Fields.Update
objMsg.Send
End Sub

Параметры кому отправлять и какое письмо можно засунуть в рекордсет и работает быстрее чем через аутлук.
И будет Вам счастье.....