Range("хххххх").Select и обрамление диапазона рамкой

[ShamanK]

парни подскажите пожалуйста.
есть следующие данные

начальная строка номер 4
конечная строка номер "y"

начальный столбец "B"
конечный столбец "W"

необходимо выделить этот диаппазон методом Range("хххххх").Select

подскажите - какой синтаксис записи?

[ShamanK]

сори уже нашел, воспользовался поиском ))

теперь другой вопрос:

выделяемый диаппазон я обрамляю сеткой.

    Range(Cells(2, "B"), Cells(y - 1, "W")).Select

    With Selection.Borders(xlEdgeLeft)
        .LineStyle = xlContinuous
        .Weight = xlMedium
        .ColorIndex = xlAutomatic
    End With
    With Selection.Borders(xlEdgeTop)
        .LineStyle = xlContinuous
        .Weight = xlMedium
        .ColorIndex = xlAutomatic
    End With
    With Selection.Borders(xlEdgeBottom)
        .LineStyle = xlContinuous
        .Weight = xlMedium
        .ColorIndex = xlAutomatic
    End With
    With Selection.Borders(xlEdgeRight)
        .LineStyle = xlContinuous
        .Weight = xlMedium
        .ColorIndex = xlAutomatic
    End With

есть несколько блоков которые необходимо обрамлять, и код получился довольно таки большим... в котором несколько раз повторяется одно и тоже..

вопрос - как можно основную часть кода выделить в отдельную функцию, и в нее передавать только выделяемый ДИАППАЗОН ?

[EducatedFool]

Sub ПримерИспользования()
    y = 6
    SetRangeBorders Range(Cells(2, "B"), Cells(y - 1, "W")), xlContinuous, xlMedium
    SetRangeBorders Range(Cells(y + 2, 6), Cells(y - 1, y + 15)), xlContinuous, xlThick
    SetRangeBorders [g23:k27], xlContinuous, xlThin
End Sub

Sub SetRangeBorders(ByRef ra As Range, ByVal BordersLineStyle As XlLineStyle, ByVal BordersWeight As XlBorderWeight)
    ra.Borders.LineStyle = BordersLineStyle: ra.Borders.Weight = BordersWeight
    ra.Borders(xlDiagonalDown).LineStyle = xlNone: ra.Borders(xlDiagonalUp).LineStyle = xlNone
End Sub

выделяемый диаппазон я обрамляю сеткой

Выделять ячейки совсем не обязательно - это только замедляет макрос.

[ShamanK]

Сообщение от EducatedFool

Sub ПримерИспользования()
    y = 6
    SetRangeBorders Range(Cells(2, "B"), Cells(y - 1, "W")), xlContinuous, xlMedium
    SetRangeBorders Range(Cells(y + 2, 6), Cells(y - 1, y + 15)), xlContinuous, xlThick
    SetRangeBorders [g23:k27], xlContinuous, xlThin
End Sub

Sub SetRangeBorders(ByRef ra As Range, ByVal BordersLineStyle As XlLineStyle, ByVal BordersWeight As XlBorderWeight)
    ra.Borders.LineStyle = BordersLineStyle: ra.Borders.Weight = BordersWeight
    ra.Borders(xlDiagonalDown).LineStyle = xlNone: ra.Borders(xlDiagonalUp).LineStyle = xlNone
End Sub

Выделять ячейки совсем не обязательно - это только замедляет макрос.

большое спасибо, все работает!!!