Вставка особой нумерации на нечетные страницы с разрывом страницы

[БуреВестник]

Да проверил, вроде работает.
Только вот что я заметил: при использовании Разрыва раздела с нечётной страницы пустая страница является первой страницей соответствующего раздела - это видно на предварительном просмотре в строке состояние. Странно как-то.

[viter.alex]

Я все-таки приложу еще один файл, т.к. внес исправление в код поля, чтобы дробный номер страницы не отображался на последней нечетной странице последнего раздела, теперь код поля выглядит так:

{ IF {=(({ =MOD({ PAGE };2) }<>0)*({PAGE}={=INT({ DOCVARIABLE { QUOTE Sec{ SECTION }PageCount } }) })*({ PAGE }<{ NUMPAGES }) )} = 1 { QUOTE { PAGE }/{ =SUM({ PAGE };1) } } { PAGE } }

[akokin]

Ну, что можно сказать? Александр, спасибо огромное!
Сам бы я не дошурупил однозначно.

[viter.alex]

Тема получила неожиданное продолжение.
Автор вопроса меня справедливо упрекнул в том, что я не ознакомился с ГОСТом ГОСТ18675-79, согласно которому нужно делать нумерацию. Грешен, не ознакомился, но только из-за неправильной оценки сложности задачи.
Оказывается, этот ГОСТ устанавливает правила для «Документации эксплуатационной и ремонтной на авиационную технику и покупные изделия для нее», т.е. все очень серьезно.
Согласно этому ГОСТу каждый раздел имеет свою нумерацию: первый нумеруется с 1, второй со 101, третий с 201 и т.д. Поэтому предложенный мной метод не совсем подходит и нуждается в доработке.
Я его доработал. Теперь в переменные документа, в которых хранятся номера страниц, которыми заканчивается раздел, записываются не реальные номера страниц, а те, которые заданы пользователем для данного раздела. Кроме того, пришлось добавить переменную, в которой хранится количество разделов в документе. Поле почти не изменилось (изменения выделил красным цветом):
{ IF {=(({ =MOD({ PAGE };2) }<>0)*({PAGE}={=INT({ DOCVARIABLE { QUOTE Sec{ SECTION }PageCount } }) })*({ SECTION }<>{ DOCVARIABLE "SectionsCount"}) )} = 1 { QUOTE { PAGE }/{ =SUM({ PAGE };1) } } { PAGE } }
Макрос я лишь слегка дополнил, чтобы добавлял переменную документа с количеством разделов и брал нумерацию страниц, введенную пользователем (выделено красным):

Sub GOSTNumbering()
'Такое название потому, что я считаю глупым следовать стандартам,
'разработанным бог знает когда и не несущим практической пользы
  On Error Resume Next
  Dim oSec As Section 'Переменная для перечисления разделов
  Dim nPagesCountEndSec As Long 'Количество страниц, заполненных текстом, до конца раздела
  Dim ovar As Variable 'Переменная для перечисления переменных документа
  
  For Each oSec In ActiveDocument.Sections
    'Количество страниц до конца раздела
    nPagesCountEndSec = oSec.Range.Information(wdActiveEndAdjustedPageNumber)
    'Добавляем переменную в документ
    ActiveDocument.Variables.Add "Sec" & oSec.Index & "PageCount", nPagesCountEndSec
    If Err.Number = 5903 Then 'Если такая переменная в документе уже есть
      'Обновляем значение переменной
      ActiveDocument.Variables("Sec" & oSec.Index & "PageCount").Value = nPagesCountEndSec
      'Очищаем ошибку
      Err.Clear
    End If
  Next
  'Записываем в переменную количество разделов в документе
  ActiveDocument.Variables.Add "SectionsCount", ActiveDocument.Sections.Count
  If Err.Number = 5903 Then 'Если такая переменная в документе уже есть
    'Обновляем значение переменной
    ActiveDocument.Variables("SectionsCount").Value = ActiveDocument.Sections.Count
    'Очищаем ошибку
    Err.Clear
  End If

  'Обновляем поля в документе
  ActiveDocument.Fields.Update
  'Это для контроля имен переменных и их значений. На
  'функциональность это не влияет.
  For Each ovar In ActiveDocument.Variables
    Debug.Print ovar.Name & vbTab & ovar.Value
  Next
End Sub