[DOS] Работа с файлами и каталогами: вывод содержимого каталога на экран

[Zueuk]

Всех приветствую.
Пытаюсь решить задачу: вывести содержимое каталога на экран. Нашел похожий код. Попробовал его подправить под свою задачу.

Вопрос вот в чем: как из структуры DTA вытащить имя файла, которое и можно передать функции 09h для вывода на экран имени файла?

; lsdir2.asm
; выводит список файлов и каталогов
; в текущем каталоге
        .model     tiny
        .code
        org        100h                ; СОМ-файл
start:
        mov        ah,4Eh              ; поиск первого файла
	mov        cx,0110111b         ; устанавливаем аттрибуты, какие файлы искать
        mov        dx,offset filespec  ; маска для поиска в DS:DX

file_open:
        int        21h
        jc         no_more_files       ; если CF = 1 - файлы кончились
 
        mov        dx,80h+1Eh          ; смещение DTA + смещение имени файла
        int        21h                 ; от начала DTA
	;;моё-начало вывод имени файла/папки
	mov ah, 09h
	int 21h
	;;моё-конец
        jc         find_next           ; если файл не открылся - перейти
                                       ; к следующему
        mov        bx,ax               ; идентификатор файла в ВХ
        mov        cx,1                ; считывать один байт
        mov        dx,offset buffer    ; начало буфера - в DX
 
find_next:
        mov        ah,3Eh              ; закрыть предыдущий файл
        int        21h
        mov        ah,4Fh              ; найти следующий файл
        mov        dx,80h              ; смещение DTA от начала PSP
        jmp        short file_open
 
no_more_files:                         ; если файлы кончились,
        ret                            ; выйти из программы
 
filespec      db   "*",0	           ; маска для поиска
        end        start               ; конец программы

[прохожий11]

смотри test.rar
У меня поиск файла в каталогах правда покамест выводит файлы в одном каталоге. Для твоих целей работать будет, можешь лишнее убрать.
Вопрос для других форумчан как правильно написать поиск в подкаталогах. Во вложении scan.rar листинг программы вывода имен всех каталогов на диске.
Из двух программ пытаюсь сделать одну.
код в вложении "тест" исходный. прошу подправить где не верно или написать подробный алгоритм поиска.
П.С. сори если такая тема уже поднималась на форуме.

[Zueuk]

Сообщение от прохожий11

смотри test.rar
У меня поиск файла в каталогах правда покамест выводит файлы в одном каталоге. Для твоих целей работать будет, можешь лишнее убрать.

Спасибо. Посмотрю.

[Zueuk]

Всё оказалось очень просто. Вот нашел готовое решение.

И немного подправил его, получился вывод на новой строке имен файлов и каталогов в текущем каталоге, что и требовалось.

; выводит список файлов и каталогов в текущем каталоге
; Вход:
; AH - 4Eh
; DS:DX - адрес строки поиска
; CX - атрибуты
; Выход:
; AX - код ошибки (в случае если встал CF)
; DTA - результаты
    .model tiny
    .code
    org 100h
start:
    ; по умолчанию DTA находится в PSP, но мы можем задать ей другое расположение
    ; (а можем и работать со старым адресом). вобщем переместим
    mov ah,1ah
    mov dx,offset dta
    int 21h
   
    ; FindFirstFile
    mov ah,4eh
    mov cx,0110111b         ; устанавливаем аттрибуты, какие файлы искать
    mov dx,offset searchPath
    int 21h
    jc quit

print_filename:
    ; имя файла находится по смещению 1Eh в DTA и завершается нулем
    ; теперь выводим имя найденного файла. сразу отмечу, чтобы не тратить время на
    ; красивый вывод делаю так: имя файла - последнее поле в DTA, поэтому ставлю
    ; после DTA символ конца строки DOS "$" и вывожу как строку.
    mov ah,9h
    mov dx,offset dta + 1eh
    int 21h
	
    ; перевод на новую строку
    mov ah,9h
    mov dx,offset crlf
    int 21h
   
    ; FindNextFile
    mov ah,4fh
    mov dx,offset dta
    int 21h
    jnc print_filename    ;если ошибки нет - продолжаем вывод списка файлов, иначе конец программы

quit:
    ;вывод сообщения
    mov ah,9h
    mov dx,offset message
    int 21h
	
    ; задержка
    xor ax,ax
    int 16h
   
    mov ah,4ch
    int 21h

; data    
searchPath  db "*.*",0
dta     db 2ch dup (?)
        db "$"
;crlf db 13,10,'$' ;новая строка
crlf db 0Dh,0Ah,'$' ;аналогично, новая строка
message db 'Press any key...','$'

end start