Просмотр листа с использование пароля

[pashulka]

Всё правильно, именно об этом я и говорил в своём прошлом сообщении (см. постскриптум) Поэтому, Вам желательно скачать 'исправленный' вариант с официального сайта.

[pashulka]

Noor, Вот специально для Вас на бескрайних просторах нашёл два файла SELFCERT.EXE попробуйте использовать их для создания цифровой подписи (только не забудьте предварительно проверить их на наличие вирусов, ибо скачены они были отнюдь не с Microsoft)

[Noor]

Огромное спасибо Вам PASHULKA за программульку

Теперь есь еще один вопросик!
Как запретить нажатие комбинаций клавиш. В справке есть информация относительно OnKey
OnKey Method Example

This example assigns "InsertProc" to the key sequence CTRL+PLUS SIGN and assigns "SpecialPrintProc" to the key sequence SHIFT+CTRL+RIGHT ARROW.

Application.OnKey "^{+}", "InsertProc"
Application.OnKey "+^{RIGHT}", "SpecialPrintProc"
This example returns SHIFT+CTRL+RIGHT ARROW to its normal meaning.

Application.OnKey "+^{RIGHT}"
This example disables the SHIFT+CTRL+RIGHT ARROW key sequence.

Application.OnKey "+^{RIGHT}", ""

но что то я так и не понял принцип ее работы!

И как отследить движение мышки на рабочем листе ?(если такое вобще возможно)

[pashulka]

Метод .OnKey непосредственно предназначен для того, что назначить клавише или сочетанию клавиш свой макрос, например :

Private Sub Auto_Open()
    Application.OnKey Key:="^c", Procedure:="NoCopy" 'CTRL+C
End Sub
 
Private Sub Auto_Close()
    Application.OnKey Key:="^c" 'Reset
End Sub
 
Private Sub NoCopy()
    MsgBox "Не дам копировать всякое безобразие", vbSystemModal, ""
End Sub

Но этот метод можно применить и "блокирования" горячих клавиш, т.е. для того, чтобы после нажатия этих клавиш, не выполнялись стандартные команды. Для этого можно использовать предыдущий код и использовать макрос-пустышку (т.е. макрос не содержащий инструкций) или использовать что-то вроде :

Private Sub Auto_Open()
    Application.OnKey Key:="^c", Procedure:=""
End Sub
 
Private Sub Auto_Close()
    Application.OnKey Key:="^c" 'Reset
End Sub

Пример получения координат мышки см. ниже, а событий листа/книги отслеживающих движение мышки нет, но если бросить на рабочий лист, например, Label (сделав его прозрачным и убрав 'рамку'), то можно использовать соответствующее событие этого элемента управления. Впрочем, этот вариант может подойти только для относительного небольшого диапазона ячеек.

Private Type POINTAPI
    X As Long
    Y As Long
End Type
 
Private Declare Function GetCursorPos Lib "user32.dll" (lpPoint As POINTAPI) As Long
 
Private Sub Worksheet_SelectionChange(ByVal Target As Excel.Range)
   Dim iPoint As POINTAPI
   Dim iCursorPos As Long
   iCursorPos = GetCursorPos(iPoint)
   MsgBox "Координаты мышки : " & vbNewLine & _
   "X:" & iPoint.X & " Y:" & iPoint.Y, , ""
End Sub