как правильно завершить цикл?

[Bape}l{ka]

привет всем еще раз!

надо: чтобы все цифры в таблице сдвинулись к левому краю, т.е. чтобы между ними не было пустых ячеек
есть код, но не совсем правильно работает - сдвигается первая цифра в строке, а последующие остаются на местах Т_Т

думаю все из-за Exit For, но ничего альтернативного в голову не приходит. подскажите, пожалуйста, как поправить

Sub SdvigVlevo()
    Dim x As Integer
    
    Call VBABrand.Subs_.DefinitionSelectionRowCol
    
    For Roww = FirstRow To MaxRow
        For Each iCell In Range(Cells(Roww, FirstCol), Cells(Roww, MaxCol))
            If Not IsEmpty(iCell) Then
                For x = 0 To (iCell.Columns.Count - FirstCol + 1)
                    If IsEmpty(Cells(Roww, FirstCol + x)) Then
                        Cells(Roww, FirstCol + x) = iCell.Value
                        iCell = ""
                        Exit For
                    End If
                Next x
            End If
        Next iCell
    Next Roww
    
End Sub

думала сделать через Do Until, но тоже что-то не то выходит

пример: пример сдвига.rar

[kuklp]

Почему без этих многочисленных циклов в цикле не удалить все пустые в диапазоне со сдвигом влево?

Sub SdvigVlevo()
    Call VBABrand.Subs_.DefinitionSelectionRowCol
    Range(Cells(FirstRow, FirstCol), Cells(MaxRow, MaxCol)).SpecialCells(4).Delete Shift:=xlToLeft
End Sub

[Казанский]

может так?

activesheet.cells.specialcells(xlcelltypeblanks).delete Shift:=xlToLeft

[Bape}l{ka]

удалять нельзя, т.к. я применяю это не для всех данных на листе, а только для части, а остальное должно остаться на своих местах

по вашим способам сдвигается по всей строке

но вы подали идею - может как-то сделать СДВИГ?? но у меня сдвигать именно значения не получается.. в прошлый раз я вырезала-вставляла. но в данном случае при cut-paste тоже нужен будет цикл и остается та же проблема Т_Т

люди, хеелп!

[IgorGO]

Sub SdvigVlevo()
  Call VBABrand.Subs_.DefinitionSelectionRowCol
  for r = firstrow to maxrow
    c = range(cells(r,firstcol), cells(r,maxcol)).SpecialCells(4).count
    if c > 0 then range(r,maxcol+1).resize(1, c).Insert Shift:=xlToRight
  next
  Range(Cells(FirstRow, FirstCol), Cells(MaxRow, MaxCol)).SpecialCells(4).Delete Shift:=xlToLeft
End Sub

подойдет так?

чтобы удалить чего-нибудь ненужное, надо сначала добавить чего-нибудь ненужное
(с) КотМатроскин

[nilem]

или (без удаления ячеек)

Sub SdvigVlevo()
Dim x, i&, j&, k&
Dim FirstRow&, MaxRow&, FirstCol&, MaxCol&
Application.ScreenUpdating = False

Call VBABrand.Subs_.DefinitionSelectionRowCol
x = Range(Cells(FirstRow, FirstCol), Cells(MaxRow, MaxCol)).Value
For i = 1 To UBound(x, 1)
    k = 1
    For j = 1 To UBound(x, 2)
        If Not IsEmpty(x(i, j)) Then
            x(i, k) = x(i, j): If k < j Then x(i, j) = Empty
            k = k + 1
        End If
    Next j
Next i
Range(Cells(FirstRow, FirstCol), Cells(MaxRow, MaxCol)).Value = x

Application.ScreenUpdating = True
End Sub

[Bape}l{ka]

на вот этой строке выдает ошибку, что object or with block not set

c = Range(Cells(r, FirstCol), Cells(r, MaxCol)).SpecialCells(4).Count

а если так, то tipe mismatch на count Т_Т

Set c = Application.Range(Cells(r, FirstCol), Cells(r, MaxCol)).SpecialCells(4).Count

ладна.. я еще поэкспериментирую Т_Т
вот пример:
пример сдвига.rar

[Bape}l{ka]

nilem, а как вы присваиваете значение диапазону??

x = Range(Cells(FirstRow, FirstCol), Cells(MaxRow, MaxCol)).Value

Range(Cells(FirstRow, FirstCol), Cells(MaxRow, MaxCol)) - это ведь не одна ячейка. или я чего-то не знаю?

[IgorGO]

извините:

  Dim r As Integer, c As Integer
  Call Subs_.DefinitionSelectionRowCol 'ActiveWorkbook.ActiveSheet.
  For r = FirstRow To MaxRow
    c = Range(Cells(r, FirstCol), Cells(r, MaxCol)).SpecialCells(4).Cells.Count
    If c > 0 Then Cells(r, MaxCol + 1).Resize(1, c).Insert Shift:=xlToRight
  ...

[Hugo121]

x = Range(Cells(FirstRow, FirstCol), Cells(MaxRow, MaxCol)).Value

- это значения диапазона берутся в массив.
Далее массив обрабатывается, и "присваиваете значение диапазону" вот здесь:

Range(Cells(FirstRow, FirstCol), Cells(MaxRow, MaxCol)).Value = x