Быстро создать панель инструментов

[OgE®_M@G]

Здравствуйте уважаемые форумчане. У меня такой вопрос. Как быстро создать панель инструментов, закрепить ее за конкретным файлом excel, чтобы при открытие открывалась только она.
Я понял что есть два способа:
I
1. Создать панель несколько панелей инструментов
2. Сохранить файл excel11.xlb по умолчанию путь C:\Documents and Settings\User\Application Data\Microsoft\Excel\
3. Прописать в модуле Эта Книга макрос на открытие панели и закрытие всех остальных и все.
II
1. Прописать все команды макросом http://excelvba.ru/tools/CommandBar (EducatedFool (Игорь)), спасибо за помощь.
2. Затем париться с настройкой. Прикреплением панели и т.д. (Сразу вопрос EducatedFool (Игорь) почему панель не выходит закрепленной на панели инструментов?)
И собственно вопрос можно ли сделать несколько файлов excel11.xlb? и подгружать их соответственно?
Если нет то посоветуйте что выбрать (какой способ)? А то я никак не могу определиться? Заранее спасибо.

[doober]

В 2007 можно без проблем сделать пользовательскую вкладку на свой файл

[Skif-F]

Не знаю, что за сложности в настройке панели.
Можно сделать так, чтобы каждая книга при открытии ставила свою панель (меню), а при закрытии убирала.
Попробуйте вариант, что использую я:

Option Explicit             'Все переменные должны быть объявлены'

Private Const MenuName = "Преобразование сметы"   'Наименование меню'
Private Const ThisName = "Преобразование сметы 8.2.xla"

Private Sub Workbook_Open()  'При открытии книги'
    Application.ScreenUpdating = False
    KontekstMenu "Cell"   'Подключаем контекстное меню к ячейке'
    AddMenu                 'Добавляем меню'
    Application.ScreenUpdating = True
End Sub

Private Sub Workbook_BeforeClose(Cancel As Boolean)
    On Error Resume Next
    Application.CommandBars("Worksheet Menu Bar").Controls(MenuName).Delete 'Убираем меню с панели'
    Application.CommandBars("Cell").Controls(MenuName).Delete 'Убираем контекстное меню ячейки'
    On Error GoTo 0
End Sub

Private Sub AddMenu()   'Формируем меню на панели инструментов'
    AddButton MenuName, "Преобразовать смету", "BaseModule.Макрос1", 37
    AddButton MenuName, "Выделить форму", "BaseModule.ВыделитьФорму", 44
    AddButton MenuName, "Сравнить области и выделить цветом различные ячейки", "OtherModule.CompareColumn", 237
    AddButton MenuName, "Заполнить ячейки ценами", "OtherModule.FillCellsByPrice", 132
    AddButton MenuName, "Сформировать колонтитул для коммерческого предложения", "OtherModule.DownFooter", 237
    AddButton MenuName, "Сформировать ссылки в сводной таблице", "OtherModule.ReferFromSummary", 43
    AddButton MenuName, "Удалить меню", "КнигаПреобразования.Uninstall", 536
End Sub

Private Sub KontekstMenu(Menu As String)   'Формируем контекстное меню'
    AddButton MenuName, "Преобразовать смету", "BaseModule.Макрос1", 37, Menu
    AddButton MenuName, "Выделить форму", "BaseModule.ВыделитьФорму", 44, Menu
    AddButton MenuName, "Сравнить области и выделить цветом различные ячейки", "OtherModule.CompareColumn", 237, Menu
    AddButton MenuName, "Заполнить ячейки ценами", "OtherModule.FillCellsByPrice", 132, Menu
    AddButton MenuName, "Сформировать ссылки в сводной таблице", "OtherModule.ReferFromSummary", 43, Menu
End Sub
Sub Uninstall(Optional silent = False)
    Dim ad As AddIn
    If Not silent Then
        If MsgBox("Вы действительно желаете удалить меню надстройки?", vbYesNo) = vbNo Then Exit Sub
    End If
    
    On Error Resume Next
    Application.CommandBars("Worksheet Menu Bar").Controls(MenuName).Delete
    Application.CommandBars("Cell").Controls(MenuName).Delete
    Application.AddIns(Left(ThisName, Len(ThisName) - 4)).Installed = False
    On Error GoTo 0
End Sub

Private Sub AddButton(Menu As String, _
                      submenu As String, _
                      macro As String, _
                      FaceId As Integer, _
                      Optional CBars As String = "Worksheet Menu Bar", _
                      Optional descr As String = "")
    Dim mnu As CommandBarControl, Button As CommandBarControl
    
    On Error Resume Next
    Set mnu = Application.CommandBars(CBars).Controls(Menu)
    If IsNull(mnu) Or Err.Number <> 0 Then
        Set mnu = Application.CommandBars(CBars).Controls.Add(Type:=msoControlPopup, before:=1)
        mnu.Caption = "&" & Menu
        mnu.Visible = True
    End If
    Set Button = Application.CommandBars(CBars).Controls(Menu).Controls(submenu)
    If IsNull(Button) Or Err.Number <> 0 Then
        Set Button = Application.CommandBars(CBars).Controls(Menu).Controls.Add(Type:=msoControlButton, ID:=2950)
        With Button
            .DescriptionText = descr
            .TooltipText = descr
            .Caption = "&" & submenu
            .Style = 3
            .OnAction = macro
            .FaceId = FaceId
        End With
    End If
End Sub

[OgE®_M@G]

Спасибо за быстрый отклик. Если можно Skif-F поясните что означают цифры 37,44, и т.д. Прошу сильно не пинать, но с панелями и их построением сталкиваюсь в первый раз.

[Skif-F]

В Office встроено несколько тысяч картинок, которыми маркируются все кнопки на панелях инструментов, так вот эти числа - это номера иконок.
Установи надстройку Panel_FaceID и посмотри какие номера каким картинкам соответствуют

[OgE®_M@G]

И еще вопрос как поместить на панель стандартные команды типа удалить строку или сохранить. Спасибо большое.

[Skif-F]

Сообщение от OgE®_M@G

И еще вопрос как поместить на панель стандартные команды типа удалить строку или сохранить. Спасибо большое.

только реализуя их макросами

[OgE®_M@G]

вот блин загвоздка. Писать на все команды макросы очень долго, лучше использовать готовые команды, только вот как?

[Skif-F]

C++ и WinAPI Вам в руки :-)

[OgE®_M@G]

Спасибо за поддержку буду искать еще способы. И обязательно отпишусь. Может кому нить потом пригодиться.