Автоматическое заполнение данных из другого листа

[usgaz@list.ru]

Есть два листа, в одном размещены данные о договорах (№, дата, контрагент и т.д.) они размещены в строку по каждому договору.
Второй лист - карточка к такому договору и в различные ячейки заполняются данные из предыдущего листа.
Как сделать так, чтобы эти данные заполнялись автоматически и оператору достаточно было только указать номер строки из которой заполнить эти данные?
Спасибо!

[EducatedFool]

Приложите файл с данными (заполните по нескольку строк на каждом листе так, как это должно выглядеть в дальнейшем).

Сообщение от usgaz@list.ru

оператору достаточно было только указать номер строки

Как именно оператор будет указывать номер строки?
двойным щелчком на ячейке в этой строке, или выделением строки с последующим нажатием на какую-либо кнопку, или как-то еще?

[usgaz@list.ru]

ВТОРОЙ ЛИСТ - регистрация
ПЕРВЫЙ ЛИСТ - карточка. Те поля, которые в нем помечены желтым цветом должны заполняться из второго листа.
Приведен пример по второй строке второго листа!


Как оператор будет указывать номер строки - совсем не важно - можно в отдельной ячейке или в каком-нибудь поле...

Заранее благодарен за помощь!

[EducatedFool]

См. вложение.

Для заполнения регистрационной карточки выполните двойной щелчок мышью на странице "Регистрация" в столбце 1 по любой ячейке
(по ячейке с регистрационным номером этой карточки)

Макросы в Excel должны быть включены.

[EducatedFool]

Есть и другой вариант - с формулами.

На листе КАРТОЧКА в зеленую ячейку вводите нужный регистрационный номер, и все поля заполняются.

См. вложение:

[usgaz@list.ru]

Спасибо огромное! Выручили по полной!

[usgaz@list.ru]

Сообщение от EducatedFool

См. вложение.

Для заполнения регистрационной карточки выполните двойной щелчок мышью на странице "Регистрация" в столбце 1 по любой ячейке
(по ячейке с регистрационным номером этой карточки)

Макросы в Excel должны быть включены.

Можешь еще подсказать как отредактировать данный вариант? Названия листов на которые ссылается и проч.

[EducatedFool]

Щелкаем правой кнопкой мыши на ярлычке листа "Регистрация", и выбираем пункт Исходный текст

В открывшемся редакторе VBA видим:

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
    On Error Resume Next
    If Target.Column = 1 And Target.Row > 1 Then
        Select Case MsgBox("Заполнить регистрационную карточку?", vbYesNo + vbQuestion, "Подтвердите действие")
            Case vbYes
                Cancel = True
                Dim sh As Worksheet, c1 As Range: Set sh = ActiveWorkbook.Worksheets("КАРТОЧКА")
                If sh Is Nothing Then Beep 100, 100: MsgBox "Отсутствует лист КАРТОЧКА", vbCritical, "Ошибка": Exit Sub
                Set c1 = Target.EntireRow.Cells(1)

                ' на всякий случай сначала очищаем ячейки (чтобы заведомо избавиться от прежних данных)
                sh.Range("RegNumber").FormulaR1C1 = ""
                sh.Range("ContractNumber").FormulaR1C1 = ""
                sh.Range("ContractDate").FormulaR1C1 = ""
                sh.Range("RegDate").FormulaR1C1 = ""
                sh.Range("Agent").FormulaR1C1 = ""
                sh.Range("ContractType").FormulaR1C1 = ""
                sh.Range("DateExpired").FormulaR1C1 = ""

                ' записываем значения (полям в КАРТОЧКЕ присвоены имена)
                sh.Range("RegNumber").Value = c1.Offset(, 0).Value
                sh.Range("ContractNumber").Value = c1.Offset(, 1).Value
                sh.Range("ContractDate").Value = c1.Offset(, 2).Value
                sh.Range("RegDate").Value = c1.Offset(, 3).Value
                sh.Range("Agent").Value = c1.Offset(, 4).Value
                sh.Range("ContractType").Value = c1.Offset(, 5).Value
                sh.Range("DateExpired").Value = c1.Offset(, 6).Value

                sh.Activate    ' активируем лист КАРТОЧКА
                Beep 800, 50
            Case Else
                Cancel = False
        End Select
    End If
End Sub

В нём строка Set sh = ActiveWorkbook.Worksheets("КАРТОЧКА ") отвечает за определение листа, на котором расположена карточка.
Если надо переименовать лист, замените "КАРТОЧКА" на "Новое название листа"

Лист "Регистрация" можно переименовывать без изменений кода.


Строка If Target.Column = 1 And Target.Row > 1 Then определяет ячейки, двойной щелчок по которым вызывает выполнение кода.

В данном случае Target.Column = 1 означает, что обрабатывается 1-й столбец, а Target.Row > 1 - что номер строки должен быть больше 1 (начиная с 2 и дальше)

[usgaz@list.ru]

Благодарю!!!