Ошибка при выполнении макроса

[rlev]

Не могу понять, где закралась ошибка. На текущем листе выполняется, а вон на другом - не хочет. Помогите разобраться, пожалуйста.

[alyon_ka]

в файле 3 макроса какой из них смотреть? и на каком листе он работает нормально, а на каком - не хочет? на всех трех листах разные шаблоны...

[The_Prist]

Как минимум ошибка в Модуль14. Исправьте макрос так:

Sub Макрос3()
'
' Макрос3 Макрос
'

'
    Sheets("акт").PrintOut Copies:=2
    Title = "                Печать акта !"
    Msg = " Вы уверены, что хотите напечатать акт? "
    Btns = vbYesNo + vbCritical + vbDefaultButton2  ' кнопки и свойства
    Result = MsgBox(Msg, Btns, Title)
    If Result = vbYes Then MyString = "Да"

End Sub

[WordVest]

Ваш макрос действительно выдает ошибку в Модуле14. Вы использовали блок With … End With.
У вас 1 действие в этом блоке «.PrintOut Copies:=2», то есть Вы выводите на печать две копии данного листа, но после этого Вы запрашиваете пользователя о том хочет он вывести этот лис на печать или нет.
Текст макроса должен выглядеть так:
MsgBox "Вывести лист «акт» на печать?", vbYesNo
If msg=7 Then
Exit Sub
Else
Workseets ("акт").PrintOut Copies:=2
End If
Данный текст VBA запрашивает у пользователя хочет ли он распечатать данный лист, если нет то не выполняет далее никаких действий, если да то напрямую используя принтер по умолчанию, распечатывает лист «акт» в двух экземплярах

[The_Prist]

Ну если уж исправлять и причесывать, то так:

Sub Макрос3()
If MsgBox(" Вы уверены, что хотите напечатать акт? ", vbYesNo + vbCritical + vbDefaultButton2, "                Печать акта !") = vbNo Then Exit Sub
Sheets("акт").PrintOut Copies:=2
End Sub

[rlev]

Сообщение от alyon_ka

в файле 3 макроса какой из них смотреть? и на каком листе он работает нормально, а на каком - не хочет? на всех трех листах разные шаблоны...

К сожалению, во всех 3 макросах были проблемы. По "печать актов" уже подсказали, спасибо. Моя невнимательность. А вот в двух других макросах ошибки есть и они однотипные. При запуские и одного, и второго макроса на листе "счет" все выполняется, а вот на листе "акт" практически в одном и том же месте вываливается ошибка. И что с ними делать - не знаю.

[The_Prist]

Сообщение от rlev

на листе "акт" практически в одном и том же месте вываливается ошибка

Ну вот нельзя написать, что за ошибка, на какой строке? Или все должны теперь запустить макрос и искать?

[The_Prist]

Догадываюсь где ошибка. Нельзя выделять диапазон на неактивном листе.
Вот коды поправленных макросов:
из Module13

Sub Макрос2()
    ActiveSheet.Unprotect
    Dim LastRow As Long
    LastRow = Cells(Rows.Count, 11).End(xlUp).Row
    Cells(LastRow - 1, 1).Select
    Title = "                Удаление строки !"
    Msg = " Вы уверены в удаление строки? "
    Btns = vbYesNo + vbCritical + vbDefaultButton2  ' кнопки и свойства
    Result = MsgBox(Msg, Btns, Title)
    If Result = vbYes Then
        MyString = "Да"
        Selection.EntireRow.Delete Shift:=xlUp
        ActiveSheet.Protect DrawingObjects:=False, Contents:=True, Scenarios:=False
        With Sheets("акт")
            .Unprotect
            LastRow = .Cells(Rows.Count, 9).End(xlUp).Row
            .Cells(LastRow - 1, 1).EntireRow.Delete Shift:=xlUp
            .Protect DrawingObjects:=False, Contents:=True, Scenarios:=False
        End With
    Else
        MyString = "Нет"
        Exit Sub
    End If
End Sub

Из Module10

Sub Макрос1()
    ActiveSheet.Unprotect
    Dim LastRow As Long, iCol As Integer
    LastRow = Cells(Rows.Count, IIf(ActiveSheet.Name = "счет", 11, 9)).End(xlUp).Row
    Cells(LastRow, 1).Select
    Selection.EntireRow.Insert
    Range(Cells(LastRow - 1, 1), Cells(LastRow - 1, 12)).Select
    Selection.AutoFill Destination:=Range(Cells(LastRow - 1, 1), Cells(LastRow, 12)), Type:=xlFillDefault
    Cells(LastRow + 1, 12).Select
    ActiveCell.FormulaR1C1 = "=SUM(R[-10]C:R[-1]C[1])"
    With Sheets("акт")
        .Unprotect
        LastRow = .Cells(Rows.Count, 9).End(xlUp).Row
        .Rows(LastRow).EntireRow.Insert
        .Range(.Cells(LastRow - 1, 1), .Cells(LastRow - 1, 9)).AutoFill Destination:=.Range(.Cells(LastRow - 1, 1), .Cells(LastRow, 9)), Type:=xlFillDefault
        .Cells(LastRow + 1, 9).FormulaR1C1 = "=SUM(R[-10]C:R[-1]C[1])"
        .Protect
    End With
    Cells(LastRow, 2).Select
    ActiveSheet.Protect DrawingObjects:=False, Contents:=True, Scenarios:=False
End Sub

[rlev]

Спасибо большое.