конвертация

[Romuald]

Всем добрый день!!!
Подскажите, пожалуйста макрос , что бы сделать конвертацию (convert to number) колонок А,Е,О начиная со второй строки
Заранее благодарю
Ромуальд

[vikttur]

Если не обязательно макросом.
Копируете единицу, выделяете диапазоны, меню Правка-Спецвставка-Умножить-ОК.

[Romuald]

Спасибо!!
Но очень надо макрос

[Hugo121]

Попробуйте варианты:

Option Explicit

Sub convert()
Dim rr As Range, rrr As Range
Set rr = Range(Cells(2, 1), Cells(UsedRange.Rows.Count, 1))
Set rrr = rr
Set rr = Range(Cells(2, 5), Cells(UsedRange.Rows.Count, 5))
Set rrr = Union(rr, rrr)
Set rr = Range(Cells(2, 15), Cells(UsedRange.Rows.Count, 15))
Set rrr = Union(rr, rrr)
rrr.NumberFormat = "General" 'может быть нужен формат "0" или "0.00"
rrr.Value = rrr.Value ' можно сделать это, если нужно
End Sub

[Romuald]

Не конвертирует!

[doober]

Макрос отработал правильно,на пять баллов.

[аналитика]

Сообщение от vikttur

Если не обязательно макросом.
Копируете единицу, выделяете диапазоны, меню Правка-Спецвставка-Умножить-ОК.

Sub Макрос()
   Dim lr As Integer
   Dim r As Range

   lr = Cells(Cells.Rows.Count, 1).End(xlUp).Row
   Set r = Union(Range("A2:A" & lr), Range("E2:E" & lr), Range("O2:O" & lr))

   With Cells(lr + 1, 1)
      .Value = 1
      .Copy
      r.PasteSpecial Paste:=xlPasteValues, Operation:=xlMultiply
      .ClearContents
   End With
   
End Sub

[SAS888]

Еще вариант (проверил в 2003 и 2007):

Sub ConvToNumber()
    Dim x As Range, a(), b(), c: b = Array(1, 5, 15)
    For Each c In b
        Set x = Range(Cells(2, c), Cells(Rows.Count, c).End(xlUp))
        a = x.Value: x.NumberFormat = "General": x.Value = a
    Next
End Sub

[Romuald]

Спасибо Огромное!
Отлично!
SAS888!!!!!!
Спасибо огомное!!!