Форматирование текста в Word 2007

[Graouilli]

Доброго дня господа.
Горю по срокам, времени на изучение синтаксиса VBA почти нету, поэтому прошу по возможности помочь написать следующий макрос:
1. Меняющий фон страницы на определенный цвет (в таблице с цветами он третий в первом ряду, обозначен как «светло-коричневый, фон 2»).
2. В первом абзаце шрифт сделать «Times New Roman», 24 кегля, белого цвета и выделенным полужирным. Так весь абзац нужно залить темно-красным цветом.
3. Во втором абзаце шрифт сделать «Times New Roman», 12 кегля, черного цвета и выделить курсивом. Весь абзац нужно залить цветом, в таблице обозначенным «светло-коричневый, фон 2, более темный оттенок 10%».
4. В третьем абзаце шрифт сделать «Times New Roman», 12 кегля, черного цвета и выделить полужирным.
5. 4 абзац сделать подобно третьему.
6. Далее и до конца, в каждый абзаце шрифт сделать «Times New Roman», 12 кегля и черного цвета. Кроме того, если абзац будет начинаться с определенного слово, то это слово необходимо сделать полужирным.

извиняйте, если путано объяснил и заранее спасибо за помощь))
необязательно отвечать на все сразу, с удовольствием приму помощь на каждый пункт по отдельности

[forumWord]

Вид - Макросы - Запись макроса... - Окей.
Делайте действия от 1 до 6.
Вид - Макросы - Остановить запись.
Alt + F11 - NewMacros - справа читаем код.

Sub Макрос1()
'1. Фон страницы
    ActiveWindow.View.DisplayBackgrounds = True
    ActiveDocument.Background.Fill.ForeColor.ObjectThemeColor = wdThemeColorBackground2
    ActiveDocument.Background.Fill.ForeColor.TintAndShade = -0.1
    ActiveDocument.Background.Fill.Solid
'6. Далее и до конца, в каждый абзаце шрифт сделать «Times New Roman», 12 кегля и черного цвета.
    With ActiveDocument.Range.Font
        .Name = "Times New Roman"
        .Size = 12
        .Color = -587137038
    End With
'2. В первом абзаце шрифт сделать «Times New Roman»,
    '24 кегля, белого цвета и выделенным полужирным. Так весь абзац нужно залить темно-красным цветом.
    With ActiveDocument.Paragraphs(1).Range.Font
        .Size = 24
        .Color = -603914241
        .Bold = True
    End With
    ActiveDocument.Paragraphs(1).Range.HighlightColorIndex = wdDarkRed
'3. Во втором абзаце шрифт сделать «Times New Roman», 12 кегля, черного цвета и выделить курсивом.
'    Весь абзац нужно залить цветом, в таблице обозначенным «светло-коричневый, фон 2, более темный оттенок 10%».
    With ActiveDocument.Paragraphs(2).Range.Font
        .Italic = True
    End With
    ActiveDocument.Paragraphs(2).Shading.BackgroundPatternColor = -570366209
'4. В третьем абзаце шрифт сделать «Times New Roman», 12 кегля, черного цвета и выделить полужирным.
    With ActiveDocument.Paragraphs(3).Range.Font
        .Bold = True
    End With
'5. 4 абзац сделать подобно третьему.
    ActiveDocument.Paragraphs(4).Format = ActiveDocument.Paragraphs(3).Format
    With ActiveDocument.Paragraphs(4).Range.Font
        .Bold = True
    End With
End Sub

Sub Макрос2()
'6. Кроме того, если абзац будет начинаться с определенного слово, то это слово необходимо сделать полужирным.
Dim Искомоеслово As String
Искомоеслово = InputBox("Введите слово, которое нужно сделать жирным")
If Искомоеслово = "" Then Exit Sub
With ActiveDocument.Range.Find
    .Text = "^p" & Искомоеслово
    .Format = True
    .Font.Italic = False
    .Replacement.Font.Bold = True
    .Execute Replace:=wdReplaceAll
End With
End Sub