считывание данных из выбранного файла excel

[Ilya_L]

Здравствуйте!
Вот уже третий день не могу сделать чтобы в мою текущую таблицу добавлялись данные из другого файла excel. помогите!

вот мой код

PHP код:

Private Sub CommandButton3_Click()
Dim oXL As Workbooks
Dim Fpath As String
Dim a, b As Integer

Fpath = TextBox7.Text
Set oXL = Workbooks.Open(Fpath)

For a = 2 To 301
   For b = 1 To 6
      Worksheets("Список абитуриентов").Cells(a, b).Value = oXL.Worksheets("Лист1").Cells(a, b).Value
   Next b
Next a

oXL.Close
Set oXL = Nothing

End Sub 


[SAS888]

Решить Вашу задачу можно, во-первых, вовсе не открывая файл-источник. Во-вторых, обойтись вообще без циклов. Например, так:

Private Sub CommandButton3_Click()
    Dim Fpath As String, FName As String: Application.ScreenUpdating = False
    FName = Split(TextBox7, "\")(UBound(Split(TextBox7, "\")))
    Fpath = Replace(TextBox7, FName, "")
    With Sheets("Список абитуриентов")
        With .Range(.Cells(2, 1), .Cells(301, 6))
            .ClearContents
            .FormulaR1C1 = "='" & Fpath & "[" & FName & "]Лист1'!R2C1:R301C6"
            .Value = .Value
        End With
    End With
End Sub

ПРИМЕЧАНИЕ: Имеется ввиду, что в TextBox7 находится полый путь и имя файла с расширением. Например: D:\Temp\Книга1.xls

[Ilya_L]

Спасибо вам большое SAS888...Все отлично работает.

[Ilya_L]

Сообщение от SAS888

Решить Вашу задачу можно, во-первых, вовсе не открывая файл-источник. Во-вторых, обойтись вообще без циклов. Например, так:

Private Sub CommandButton3_Click()
    Dim Fpath As String, FName As String: Application.ScreenUpdating = False
    FName = Split(TextBox7, "\")(UBound(Split(TextBox7, "\")))
    Fpath = Replace(TextBox7, FName, "")
    With Sheets("Список абитуриентов")
        With .Range(.Cells(2, 1), .Cells(301, 6))
            .ClearContents
            .FormulaR1C1 = "='" & Fpath & "[" & FName & "]Лист1'!R2C1:R301C6"
            .Value = .Value
        End With
    End With
End Sub

ПРИМЕЧАНИЕ: Имеется ввиду, что в TextBox7 находится полый путь и имя файла с расширением. Например: D:\Temp\Книга1.xls

Еще один вопрос, как сделать чтобы он не выводил нули(0), оставить ячейки пустыми?

[SAS888]

как сделать чтобы он не выводил нули(0), оставить ячейки пустыми?

Либо в "Сервис" - "Параметры" снять флажок "Отображать нулевые значения", либо в код макроса, после строки

.Value = .Value

добавить строку

.Replace 0, "", xlWhole

[Gulash]

Dim ... FName As String...
FName = Split(TextBox7, "\")(UBound(Split(TextBox7, "\")))

Уважаемый SAS888 объясните плиз недалекому почему не выскакивает ошибка?
Если FName объявлена как строка, а Split Function(Из Help-a "Returns a zero-based, one-dimensional array containing a specified number of substrings.").

[Hugo121]

Интересно, я тоже вначале не понял, пришлось конструкцию собирать:

    TextBox7 = "D:\Temp\Книга1.xls"
    x = Split(TextBox7, "\")'проверка
    y = (UBound(Split(TextBox7, "\")))'проверка
    FName = Split(TextBox7, "\")(UBound(Split(TextBox7, "\")))

Нормально, FName получается arr(2) другими словами.

[Gulash]

Все понял. Большое спасибо Вам добрый человек.