Копирование-вставка диапазона ячеек между двумя книгами

[strannick]

Добрый день, уважаемые форумчане!
Помогите со следующей проблемой. Есть такой код:

Sub myMacro()
Dim sh As Worksheet
Dim iLastRow As Long
    Set sh = Sheets("База заказов")
    iLastRow = sh.Cells(Rows.Count, 6).End(xlUp).row
Application.OnTime Now() + TimeSerial(0, 15, 0), "myMacro"
Debug.Print Time
Application.ScreenUpdating = False
    Dim myPath As String, myName As String, f As String
    myPath = "D:\Статистика заказов\VSE ZAKAZI\" 'Путь к папке с файлами
    myName = Dir(myPath & "*.xlsx")
    Do While myName <> ""
        If f = "" Then f = myName Else If FileDateTime(myPath & myName) > FileDateTime(myPath & f) Then f = myName
        myName = Dir
    Loop
    
Workbooks.Open Filename:=myPath & f
With Workbooks
Sheets("Заказы").Select
    'автофильтр
    i = Cells(Rows.Count, 1).End(xlUp).row
   
    Range("A1:R" & i).AutoFilter Field:=6, Criteria1:="=БЕЗНАЛ"
    Range("A2:R2").Select
    Range(Selection, Selection.End(xlDown)).Select
    Selection.Copy
    Application.CutCopyMode = True ' не очищаем буфер обмена
ActiveWorkbook.Close SaveChanges = False
End With

    sh.Range(iLastRow + 1, 6).Select
    ActiveSheet.Paste

    
Application.ScreenUpdating = True
    
End Sub

Макрос срабатывает каждые 15 мин, ищет в папке "D:\Статистика заказов\VSE ZAKAZI\" самый свежий файл (по дате-времени сохранения), открывает его, отфильтровывает строки со значением БЕЗНАЛ в столбце F, копирует все ячейки с A по R, и не очищая буфер обмена, закрывает этот файл без сохранения. Потом скопированный диапазон ячеек, который должен быть в буфере обмена, вставляет в следующую свободную ячейку столбца F на листе "База заказов".
Проблема возникает в двух моментах:
1. Скопированный диапазон то есть в буфере обмена, то нет.
2. Но даже если он там есть не работает вставка. Подсвечивается строка

sh.Range(iLastRow + 1, 6).Select

.
Что не так?
Заранее спасибо!

[kuklp]

А зачем Вы так спешите закрывать файл? Вставьте данные, потом закрывайте. И проще:

        i = Cells(Rows.Count, 1).End(xlUp).Row
        Range("A1:R" & i).AutoFilter Field:=6, Criteria1:="=БЕЗНАЛ"
        Range("A2:R2", Range("A2:R2").End(xlDown)).SpecialCells(12).Copy _
        sh.Range(iLastRow + 1, 6)
        ActiveWorkbook.Close SaveChanges = False
    End With

Даже так(зачем Вам там была With?):

    Loop
    With Workbooks.Open(myPath & f).Sheets("Заказы")
        i = .Cells(Rows.Count, 1).End(xlUp).Row
        .Range("A1:R" & i).AutoFilter Field:=6, Criteria1:="=БЕЗНАЛ"
        .Range("A2:R" & i).SpecialCells(12).Copy sh.Range(iLastRow + 1, 6)
        .Parent.Close 0
    End With
    Application.ScreenUpdating = True
End Sub

А это подсвечивалось:

sh.Range(iLastRow + 1, 6).Select

потому, что вы пытались выделить ячейку на неактивном листе. Сначала надо выделять лист, а потом уже ячейку на нем.
А чтоб сразу перейти, можно:

application.goto sh.Range(iLastRow + 1, 6)

[strannick]

Сработала такая конструкция:

    Loop
    With Workbooks.Open(myPath & f).Sheets("Заказы")
        i = .Cells(Rows.Count, 1).End(xlUp).Row
        .Range("A1:R" & i).AutoFilter Field:=6, Criteria1:="=БЕЗНАЛ"
        .Range("A2:R" & i).SpecialCells(12).Copy sh.Cells(iLastRow + 1, 6)
        .Parent.Close 0
    End With
    Application.ScreenUpdating = True
End Sub

Только в строке:

 .Range("A2:R" & i).SpecialCells(12).Copy sh.Cells(iLastRow + 1, 6)

Range заменил на Cells во второй части (то бишь где говорится куда вставлять). При Range выдавало ошибку. Почему - не знаю.
А так все в порядке. При ручном запуске срабатывает. Проверяю при запуске по таймеру. Огромное спасибо!!!