Пропадает прокрутка после выполнения макроса

[rus33]

Добрый день, подскажите пожалуйста не могу понять в чем загвоздка, после выполнения кода пропадает прокрутка в эксель.

Sub RIHBHA1()

    Application.ScreenUpdating = False
    Application.DisplayAlerts = False
    
Dim strFile As String
Dim wkb1    As Workbook
Dim wkb2    As Workbook
Dim r       As Range
Dim f       As Range
    
Set wkb1 = ActiveWorkbook

    strFile = Application.GetOpenFilename
    If strFile = "False" Then Exit Sub
    Worksheets.Add.Name = "List"
    Workbooks.Open strFile
Set wkb2 = ActiveWorkbook
    wkb2.Worksheets("Summary Outputs").Cells.Copy Destination:=wkb1.Worksheets("List").Cells
    wkb2.Close SaveChanges:=False
    Sheets("List").Activate
Set r = Range("A1:A100")
Set f = r.Find("Hook Load*")
If Not f Is Nothing Then
f.Offset(0, 3).Copy
End If

    Sheets("1").Activate
    Range("H31").Select
    ActiveSheet.Paste
    
    Sheets("List").Activate
    Range("O8").Select
    ActiveCell.FormulaR1C1 = "=IF(((COUNTIF(R[53]C[-13]:R[102]C[-13], ""YES"")=0)*1)=0,""Да"",""Нет"")"
    Range("O8").Select
    Selection.Copy

    Sheets("1").Activate
    Range("R31").Select
    ActiveSheet.Paste
    
    Sheets("List").Select
    Application.CutCopyMode = False
    ActiveWindow.SelectedSheets.Delete
    
    Application.ScreenUpdating = True
    Application.DisplayAlerts = True

End Sub

[EducatedFool]

Прокрутка чего пропадает?
Полоса прокрутки справа на листе исчезает? Или просто не крутится?
Или вы мышкой крутите?

PS: В коде нет ничего такого, что бы могло влиять на прокрутку чего-либо.

[rus33]

После выполнения макроса пропадает scroll мышки, не могу прокрутить вниз лист ексель. Помагает только перезагрузка эксель. Не могу понять в чем дело. Помогите пожалуйста.

[VictorM]

чтобы помочь, нужно выполнить весь Ваш код, а для этого нужно создать книгу со всеми Вашими листами и условиями(формулами). Никто этого делать не будет.
Визуально, как говорилось выше

В коде нет ничего такого, что бы могло влиять на прокрутку чего-либо.

Давайте пример файла, проверим.

[rus33]

В архиве два файла. Идея создать сводную таблицу из разного типа эксель рапортов, т.е нажать кнопку, в появившемся меню выбрать рапорт (образец рапорта прикреплен), и макрос выберет нужные значения и вставит в таблицу. Я не большой знаток макросов, все что сделал это слепил из того что нашел в интернете один кусок кода. Единственная загвозда, код работает и нужные мне значения вставляет в таблицу, но почему то перестает работать прокрутка вниз у мыши. Только перезагрузка ексель возвращает scroll. Пару раз было что и перезагрузка не помогала, со временем само востаналивалось. Подозрения падают на функцию выбора файла, в паре макросов использую немножко другого вида решения вызова диалогово окна выбора файла и там прокрутка не пропадает. Помогите пожалуйста.

[doober]

Зачем вам память так напрягать ,необходимо всего 100 ячеек.
У меня прокрутка не пропадала при выполнении вашего макроса.
Макрос не виноват.
Немного уменьшил количество строк кода

Sub RIHBHA1()
        Dim strFile As String
        Dim f As Range
        Application.ScreenUpdating = False
        Application.DisplayAlerts = False
        strFile = Application.GetOpenFilename
        If strFile = "False" Then Exit Sub
        With Workbooks.Open(strFile)
                Set f = .Worksheets("Summary Outputs").Range("A1:A100").Find("Hook Load*")
                If Not f Is Nothing Then
                        ThisWorkbook.Sheets("1").Range("H31").Value = f.Offset(0, 3).Value
                        ThisWorkbook.Sheets("1").Range("R31").FormulaR1C1 = "=IF(((COUNTIF(R[53]C[-13]:R[102]C[-13], ""YES"")=0)*1)=0,""Да"",""Нет"")"
                End If
                .Close (False)
        End With
        Application.ScreenUpdating = True
        Application.DisplayAlerts = True

End Sub

[rus33]

Спасибо огромное, супер, все заработало.