Как загрузить текстовый файл с определенной строки и разделить его на столбцы

[TatarinNV]

Добрый вечер, подскажите пожалуйста, как написать макрос загрузки текстового файла, загрузив его с определенной строки и разделить его на столбцы.
Файл постоянно обновляется.
Файл во вложении.

[SAS888]

Можно использовать любой из вариантов "по вкусу":

Sub ReadTxt()
    Dim f As String: Application.ScreenUpdating = False
    f = ThisWorkbook.Path & "\Замер.txt" 'Путь и имя файла
    Workbooks.OpenText f, Origin:=866, StartRow:=40, DataType:=xlDelimited, _
        TextQualifier:=xlNone, ConsecutiveDelimiter:=True, Space:=True
    [B:E].Copy ThisWorkbook.Sheets(1).[A1]
    ActiveWorkbook.Close False
    ActiveSheet.UsedRange.Value = ActiveSheet.UsedRange.Value
End Sub

Sub ReadTxt2()
    Dim f As String, i As Long, t: Application.ScreenUpdating = False
    f = ThisWorkbook.Path & "\Замер.txt" 'Путь и имя файла
    Set t = CreateObject("Scripting.FileSystemObject").OpenTextFile(f, 1)
    For i = 1 To 39: t.SkipLine: Next 'Пропускаем первые 39 строк
    i = 1
    Do While t.AtEndOfStream <> True
        Cells(i, 1) = Trim(t.ReadLine): i = i + 1
    Loop
    t.Close
    [A:A].TextToColumns [A1], xlDelimited, xlNone, True, Space:=True
    ActiveSheet.UsedRange.Value = ActiveSheet.UsedRange.Value
End Sub

[TatarinNV]

Спасибо, но не получается, ошибка пути файла

[EducatedFool]

ну так укажите правильный путь к своему файлу

вместо
f = ThisWorkbook.Path & "\Замер.txt" 'Путь и имя файла

напишите
f = "Полный путь к вашему текстовому файлу"

[SAS888]

В предлагаемых примерах подразумевается, что текстовый файл находится в той же папке, что и книга с этим макросом.
Если это не так, то либо явно укажите в коде макроса полный требуемый путь к файлу, присвоив его переменной f, например:

f = "C:\Temp\Замер.txt"

, либо используйте диалоговое окно для возможности выбора требуемого текстового файла для открытия. Для этого, строку кода

f = ThisWorkbook.Path & "\Замер.txt"

замените на блок

With Application.FileDialog(msoFileDialogOpen)
    .Filters.Add "Text Files", "*.txt", 1: .Show
    If .SelectedItems.Count = 0 Then Exit Sub Else f = .SelectedItems(1)
End With

[TatarinNV]

Спасибо. Все работает