Экспорт файлов одинакового расширения

[Малявка]

Всем привет. есть такой вопрос. в папке есть файлы одинакового текстового расширения. их все нужно экспортировать на один (!!!) экселевский лист. т.е. выгрузились данные, последняя строка 151. начиная с 152-ой должен выгружаться след файл и т.д.

[pashulka]

Вы можете использовать этот макрос (как базис) для решения поставленной задачи.

Private Sub Test()

iPath$ = "C:\Мои документы\"
If Dir(iPath$, vbDirectory) = "" Then
   MsgBox "Укажите существующую папку", vbCritical, ""
   Exit Sub
End If

With Application
     .ScreenUpdating = False
     .DisplayAlerts = False
     .Calculation = xlManual
     Dim iWorksheet As Worksheet
     Set iWorksheet = .Workbooks.Add(xlWBATWorksheet).Worksheets(1)
     iRowIndex& = 1:  iFileName$ = Dir(iPath$ & "*.xls")
     Do Until iFileName$ = ""
        With .Workbooks.Open _
             (Filename:=iPath$ & iFileName$, UpdateLinks:=True)
             'Рабочая книга не должна быть защищена паролем
             With .Worksheets(1).UsedRange
                  'Рабочая книга должна содержать, минимум, один рабочий лист
                  .Copy Destination:= _
                  iWorksheet.Range("A1").Item(iRowIndex&)
                  iRowIndex& = iRowIndex& + .Rows.Count
                  'неплохо бы проверить количество строк, ибо оно, небесконечно
             End With
             .Close saveChanges:=True
        End With
        iFileName$ = Dir
     Loop
     .Calculation = xlAutomatic
     .DisplayAlerts = True
     .ScreenUpdating = True
End With

End Sub