Создание пользователя рабочей группы

[Eseniya]

Добрый день! Срочно нужна помощь в решении задачи.
Дана таблица в Excel ( поля: имя пользователя, № зачетки, пароль, ФИО, рабочая группа и папка этого пользователя)
Нужно создать пользователей с помощью макроса, на диске C папку этого пользователя, чтобы был к ней общий доступ.

Подскажите как это можно сделать, хотя бы алгоритм выполнения действий.
Заранее спасибо.

[EducatedFool]

Этот код создаст в системе пользователя Вася Пупкин (с паролем Сложный ПАРОЛЬ),
после чего будет создана папка c:\Вася Пупкин с общим доступом:

Sub ПримерИспользования()
    СозданиеПользователяВСистеме "Вася Пупкин", "Сложный ПАРОЛЬ"
End Sub


Sub СозданиеПользователяВСистеме(ByVal Логин As String, ByVal Пароль As String)
    ' http://support.microsoft.com/kb/251394
    Commnd = "net user " & Chr(34) & Логин & Chr(34) & " " & Chr(34) & Пароль & Chr(34) & " /add"
    Shell "cmd.exe /c " & Commnd

    ' net share "Папка пользователя Вася Пупкин"="c:\Вася Пупкин"
    ПутьКПапкеПользователя = "c:\" & Логин
    On Error Resume Next: MkDir ПутьКПапкеПользователя
    Commnd = "net share " & Chr(34) & "Папка пользователя " & Логин & Chr(34) _
             & "=" & Chr(34) & ПутьКПапкеПользователя & Chr(34)
    Shell "cmd.exe /c " & Commnd
End Sub

[Eseniya]

Спасибо, то, что Вы, написали очень помогло. А как сделать так, чтобы пользователь брался из таблицы, из конкретной ячейки и создавался?

[Teslenko_EA]

Здравствуйте Eseniya.
Если задача выполняется из Excel, Вы не думали о возможности корректировки команды?
Commnd = "net user " & Chr(34) & Sheets(1).[a1] & Chr(34) & " " & Chr(34) & Sheets(1).[b1] & Chr(34) & " /add"

Евгений.

[EducatedFool]

А как сделать так, чтобы пользователь брался из таблицы, из конкретной ячейки и создавался?

А так не пробовали?

Sub test()
    Dim cell As Range
    ' перебираем все заполненные ячейки в столбце А
    For Each cell In Range([A1], Range("A" & Rows.Count).End(xlUp)).Cells
        ' имя пользователя берем из столбца А, пароль - из столбца С
        СозданиеПользователяВСистеме cell, cell.Next.Next
    Next cell
End Sub

Ну или так, если Вам непонятно, как организован цикл:

Sub test()
    ' имя пользователя берем из столбца А, пароль - из столбца С
    СозданиеПользователяВСистеме [a1], [c1]
    СозданиеПользователяВСистеме [a2], [c2]
    ' ....
    СозданиеПользователяВСистеме [a10], [c10]
End Sub

[Eseniya]

Большое спасибо! Все поняла, все работает. Тему можно закрывать.