Ошибка в программе, ассемблер

[Nafanja20]

Уважаемые программисты, скажите пожалуйста что исправить, чтобы программа правильно работала
Определить симметричный ли массив, то есть ровни ли между собой равноудаленные от концов элементы массива и подать ответ «1», если так, или «0» если нет
А программа выводит просто числа

INCLUDE LIBMACRO.INC
PROGRAM PR_10_1

.DATA
yes db 1
no db 0
n equ 25
mas db 1,2,3,4,5,3,7,8,9,10,11,12,13,12,11 ,10,9,8,7,6,5,4,3,2,1

start;
assume ds:@data, es:@data
mov ax,@data

mov cx,12
mov si,n
mov di,0
dec si

m1:
mov al,mas[si]
wword mas[si]
wword mas[di]
cmp al,mas [di]
jne m2
inc di
dec si
loop m1
wword yes
jmp ex
m2:
wword no
ex:
return
END PR_10_1

[airyashov]

изменить цикл так

m1:
mov al,mas[si]
cmp al,mas [di]
jne m2
inc di
dec si
loop m1

[Mikl___]

Nafanja20
а я бы сделал так

.286
.model tiny
.code	
org 100h
start:  mov ax,3;стираем с экрана
	int 10h
	mov si,offset mas
	mov bx,len-2
a0:     lodsb;получить очередной элемент массива
	cmp al,[si+bx];проверить симметричность
	jne a1;если не равны -- сообщить об этом
	sub bx,2
	jns a0;массив закончился?
	mov bx,1; ответ «1»
	jmp a2
a1:	mov bx,0; ответ «0»
a2:	shl bx,1
	mov dx,indx[bx]
	mov ah,9;выводим надпись на экран
	int 21h
	mov ah,0;пока не нажмут любую клавишу
	int 16h
exit:	ret;конец программы
mas db 1,2,3,4,5,3,7,8,9,10,11,12,13,12,11,10,9,8,7,6,5,4,3,2,1
len = $-mas;длина массива
string1 db 'Массив симметричный$'
string2 db 'Массив несимметричный$'
indx dw string2,string1 
end start

[Nafanja20]

Спасибо Вам большое!
А что значит
shl bx,1

[Mikl___]

Сообщение от Nafanja20

А что значит shl bx,1

умножить содержимое BX на 2, еще можно так add bx,bx
на весы не забудь нажать

[Nafanja20]

indx dw string2,string1
значит что string1 и string 2 имеют индексы 0 и 1?

[Mikl___]

indx dw адрес string2,адрес string1; массив адресов
indx[0]=адрес string2
indx[2]=адрес string1

[Nafanja20]

Простите пожалуйста за навязчивость, но я не понимаю как объяснить эту строку
mov bx,len-2
Для чего мы вычитаем 2?

[Mikl___]

mov bx,len-2
Для чего мы вычитаем 2?

Нумерация элементов массива идет не с 1, а с 0 поэтому номер последнего элемента n-1, кроме того после команды lodsb произойдет увеличение содержимого si на 1 поэтому bx=len-2