выборочное копирование

[Yusch]

Добрый день!
Как скопировать данные из столбцов А,В,Е, если кол-во строк изменяется?

Спасибо

[EducatedFool]

Выделяете целиком столбцы, нажимаете Правка-Копировать - и пофиг, сколько там строк, столбцы с данными будут скопированы целиком.

PS: какой вопрос - такой и ответ.
Если вам лень прикрепить файл с примером (что есть, и что надо) - мне лень подробно описывать десятки возможных вариантов.

[Yusch]

Не хочется тащить лишнее. Пробую так : range("A2:A" & lastrow).select
Предварительно задаю последнюю запись
Lastrow=cells(rows.count,1....и т.д.
Но он ругается.....как правильно задать такое копировпние

[EducatedFool]

Пробую так : range("A2:A" & lastrow).select

Вот теперь хотя бы выяснилось, что вы делаете это макросом.
Ещё несколько постов - и мы поймём, что на самом деле вам требуется)

Попробую угадать:

Range([A2], Range("A" & Rows.Count).End(xlUp)).Select

А вообще, выделять ячейки совсем не требуется, чтобы их скопировать.
Будет пример файла с пояснением, что куда надо скопировать - получите макрос копирования из одной-двух строк кода.

[Yusch]

Все, дошло как правильно) спс что откликнулись

[Yusch]

Научите пож-та копировать в две строки)
Есть "файл1", из него надо скопировать содержимое из определенных столбцов(я их выделила, число строк данного файла менятся) в файл "расчетная таблица". Файл "расчетная таблица_готово"- то что должно получится в результате работы макроса.

Файл "расчетная таблица"- планирую создавать так же макросом.

[EducatedFool]

Проверил - всё работает:

Sub Копирование()
    ' перед запуском макроса должен быть активен исходный файл (Файл1),
    ' а файл-получатель ("Расчетная таблица.xlsx") - тоже открыт

    Dim ra1 As Range, ra2 As Range, ra3 As Range

    ' ra1 - заполненные строки исходного файла
    Set ra1 = Range([A2], Range("A" & Rows.Count).End(xlUp)).EntireRow

    ' ra2 - нужные столбцы исходного файла
    Set ra2 = [a:a,c:c,d:d,g:g,k:k,m:m,q:q]

    ' ra3 - пересечение нужных строк и нужных столбцов - диапазон для копирования
    Set ra3 = Intersect(ra1, ra2)

    ra3.Copy Workbooks("Расчетная таблица.xlsx").Worksheets(1).Range("a3")
End Sub

Можно при желании сократить код:

Sub Копирование2()
    Intersect(Range([A2], Range("A" & Rows.Count).End(xlUp)).EntireRow, [a:a,c:c,d:d,g:g,k:k,m:m,q:q]).Copy _
            Workbooks("Расчетная таблица.xlsx").Worksheets(1).Range("a3")
End Sub

[Yusch]

Спасибо все работает! Я так понимаю при таком решении нельзя вставить сначала столбец С , а потом А

[EducatedFool]

при таком решении нельзя вставить сначала столбец С , а потом А

Можно - но код будет посложнее

[DiemonStar]

Можно - но код будет посложнее

Ну я бы не сказал - всего-то две копии строки: сначала для столбца А, а потом для столбца С (ну и не забыть сместить ячейку назначения).