Работа с переменными Excel

[tae1980]

При работе с формами я сохраняю значение в переменную ексель командой

    Names("п_Объект_АдресОбласть").Value = InОбласть.Value

Где InОбласть - это комбобокс.
Если "InОбласть.Value" имеет нулевое значение, то переменная "п_Объект_АдресОбласть" уничтожается.
Как сделать так что бы при нулевых значениях переменная Excel сохранялась, и так же имела нулевое значение?

[EducatedFool]

Я обычно записываю данные не в имена, а в пользовательские свойства книги:

'======================= запись и чтение свойств документа, определённых пользователем ======================

Sub SDoc(ByVal VarName As String, ByVal VarValue As Variant)    ' запись в документ (возможна ошибка с типом данных!)
    DDoc VarName
    ActiveWorkbook.CustomDocumentProperties.Add VarName, False, msoPropertyTypeString, CStr(VarValue)
End Sub

Sub SDocB(ByVal VarName As String, ByVal VarValue As Boolean)    ' запись в документ (возможна ошибка с типом данных!)
    DDoc VarName
    ActiveWorkbook.CustomDocumentProperties.Add VarName, False, msoPropertyTypeBoolean, CBool(VarValue)
End Sub

Sub DDoc(ByVal VarName As String)    ' удаление переменной из документа
    If ActiveWorkbook.CustomDocumentProperties.Count > 0 Then
        For Each cdp In ActiveWorkbook.CustomDocumentProperties
            If cdp.Name = VarName Then cdp.Delete
        Next
    End If
End Sub


Function GDoc(ByVal VarName As String) As String    'чтение из документа
    GDoc = ""
    If ActiveWorkbook.CustomDocumentProperties.Count > 0 Then
        For Each cdp In ActiveWorkbook.CustomDocumentProperties
            If cdp.Name = VarName Then GDoc = cdp.Value
        Next
    End If
End Function

Function GDocB(ByVal VarName As String) As Boolean   'чтение из документа
    GDocB = False
    If ActiveWorkbook.CustomDocumentProperties.Count > 0 Then
        For Each cdp In ActiveWorkbook.CustomDocumentProperties
            If cdp.Name = VarName Then GDocB = CBool(cdp.Value)
        Next
    End If
End Function

Sub ПримерИспользования()
    VarName = "ИмяПеременной"
    SDoc VarName, "значение"
End Sub

Sub LoadClientInfo()
    On Error Resume Next
    Me.TextBox__Адрес = GDoc("Адрес")
    Me.TextBox__КонтактноеЛицо = GDoc("КонтактноеЛицо")
    Me.SpinButton_discount = Val(GDoc("discount"))
End Sub

[tae1980]

Сообщение от EducatedFool

Я обычно записываю данные не в имена, а в пользовательские свойства книги:

Не знал о таком... Присмотрюсь подробнее.
А можно ли из самого Excel получить доступ к ним в формулах?
Планируется что эти переменные будут активно использоваться в формулах, форма нужна только для задания их значения.

[EducatedFool]

Планируется что эти переменные будут активно использоваться в формулах, форма нужна только для задания их значения.

Для этого пользовательские свойства книги не подходят.
Придётся использовать Names.

[tae1980]

Сообщение от EducatedFool

Я обычно записываю данные не в имена, а в пользовательские свойства книги:

Очень, очень интересно... Не скромный вопрос: почему процедура называется GDoc?

[tae1980]

Сообщение от EducatedFool

Для этого пользовательские свойства книги не подходят.
Придётся использовать Names.

В таком случае начальный вопрос остается в силе.
Как занести пустое значение в переменную? В ручную это сделать без проблем, а вот из VBA не получается.

[tae1980]

Нашел решение. Вот код:

    If InОбласть.Value = "" Then
        Names.Add "п_Объект_АдресОбласть", "="""""
    Else
        Names("п_Объект_АдресОбласть").Value = InОбласть.Value
    End If 'Область

Конечно это не одна строчка, но работает. :))