Работа с массивом (assembler)

[Mikl___]

sirex
так у тебя программа не компилируется?

[sirex]

да, компилирует

[Stilet]

sirex

Текст ошибки в студию.

[sirex]

;поиск min в массиве по базе со смещением
.model tiny
.code
org 100h
main:
	mov di,1
	xor ax,ax
	xor si,si
	mov bx,offset arr
	mov ax,word ptr [bx]		 ;	занесли первый элеменент, на регистр, ax=min
	mov cx,5 			;	так как первый элемент уже обработан количество повторений=n-1
cyc:
	add si,2			 ;	переходим на следующий эелемент
	cmp word ptr [bx+si],ax	 ;сравниваем текущее значение с min, word ptr используется так как нам нужен не 1 байт а 2
	jnl no			 ;если элемент >= min переходим на no
	mov ax,[bx+si]
no:
	loop cyc
	
	mov si,-2
	mov bx,offset arr
	mov cx,6 
cyc2:
	add si,2 			;переходим на следующий эелемент
	cmp word ptr [bx+si],ax	 ;сравниваем текущее значение с min, word ptr используется так как нам нужен не 1 байт а 2
	je yes 			;если элемент >= min переходим на no
	
	loop cyc2
	jmp oi1
yes:
	inc di
	loop cyc2
	
	mov ax,di
;вывод результата
oi1:  
      xor     cx, cx
      mov     bx, 10

oi2:   
      cwd
      div     bx	;Делим число на десять. В остатке получается последняя цифра. Сразу выводить её нельзя, поэтому сохраним её в стэке.
      push    dx
      inc     cx

		; А с частным повторяем то же самое, отделяя от него очередную
		; цифру справа, пока не останется ноль, что значит, что дальше
		; слева только нули.
	test    ax, ax
      jnz     oi2

		; Теперь приступим к выводу.
	mov     ah, 02h
oi3:   
	pop     dx
		; Извлекаем очередную цифру, переводим её в символ и выводим.
      add     dl, 30h
      int     21h
		; Повторим ровно столько раз, сколько цифр насчитали.
      loop    oi3
        
	int 20h
	ret

	arr dw 1,2,3,4,5,6

end main

без stack выводит аппаратную ошибку, а если убрать ret, то вовсе ничего не выводит

[Mikl___]

sirex
1) сдается мне что ты не обратил внимание на эти строки
.model tiny
.code
org 100h что говорит о том что должен собираться COM файл а не EXE
кстати, какими ключами ты пользуешься чтобы произвести компиляцию и линковку
2) если вспомнить твое задание "Дан массив из 6 элементов. Подсчитать сколько раз в нем встречается минимальное по величине число" и поместить в "arr dw 1,2,1,4,1,6" то программа Sparky выведет число 4 вот переделанный вариант

; masm dos com #
;поиск min в массиве по базе со смещением
.model tiny
.code
org 100h
main:   mov di,0
	xor si,si
	mov ax,[arr] ;занесли первый элеменент, на регистр, ax=min
	mov cx,5 ;так как первый элемент уже обработан количество повторений=n-1
cyc:    add si,2 ;переходим на следующий эелемент
	cmp arr[si],ax ;сравниваем текущее значение с min, word ptr используется так как нам нужен не 1 байт а 2
	jnl no ;если элемент >= min переходим на no
	mov ax,arr[si]
no:     loop cyc	
	mov si,-2
	mov cx,6 
cyc2:   add si,2 ;переходим на следующий эелемент
	cmp arr[si],ax ;сравниваем текущее значение с min, word ptr используется так как нам нужен не 1 байт а 2
	jne no_ ;если элемент >= min переходим на no
	inc di
no_:	loop cyc2
	mov ax,di
;вывод результата
      	mov bx,10
oi2:  	cwd
      	div bx	;Делим число на десять. В остатке получается последняя цифра. Сразу выводить её нельзя, поэтому сохраним её в стэке.
        add dl,30h
      	push dx
      	inc cx
; А с частным повторяем то же самое, отделяя от него очередную
; цифру справа, пока не останется ноль, что значит, что дальше
; слева только нули.
	test ax,ax
      	jnz oi2
; Теперь приступим к выводу.
	mov ah, 02h
oi3:    pop dx
	; Извлекаем очередную цифру, переводим её в символ и выводим.
        int 21h
; Повторим ровно столько раз, сколько цифр насчитали.
      	loop oi3        
	ret
arr dw 1,2,1,10,5,6
end main

[sirex]

а можно если в конце будет
ret
arr dw 1,2,1,10,5,6
.stack
dw 100 dup(?)
end main
или он просто не выведет

[Mikl___]

sirex
я так и знал! О COM-файле сколько раз было повторено? В нем нет ни секции .data ни секции .stack. Там одна единственная секция .code которая содержит и команды и данные, а самые старшие адреса занимаются стеком. Еще раз спрашиваю С какими ключами ты производишь компиляцию и линковку?

[sirex]

/t - Создание файла типа .com по умолчанию .exe

[Mikl___]

sirex
в случае если пишешь на tasm'e
tasm %filename%.asm
tlink /t/x %filename%.obj
если пишешь на masm'e
ml /AT /c %filename%.asm
link /T %filename%.obj,,,,,
%filename% имя твоего asm-файла

[sirex]

огромное спасибо, заработала программа=))