VBA Упрощение конструкции соответсвий

[mrMad-Cat]

Помогите пожалуйста упростить конструкцию в VBA.

If a="01" Then b = "99" End If
If a="02" Then b = "88" End If
If a="03" Then b = "77" End If...

Я так понимаю что это можно сделать как-то масивами но как не знаю.
Думал что-то такого типа но это не работает:

If a=("01";"02";"03") Then b = ("99";"88";"77") End If

[slan]

b = 110 - 11*a

[Казанский]

Если VBA Excel, то можно использовать функции листа ПРОСМОТР, ВПР, ПОИСКПОЗ и т.д.

a = "02"
b = Application.Lookup(a, Array("01", "02", "03"), Array("99", "88", "77")) 'ПРОСМОТР

[mrMad-Cat]

slan я не это имел ввиду. Вы слишком прям опосмотрели на это дело, но спаисбо за внимание. Смысл в том чо я не случайно взял цифры в скобки. Числа я в примере выбрал случайные, но вы обнаружили в них логику
Меня интересуют текстовые значения и математической формулой тут не обойтись:

If a="01" Then b = "январь" End If
If a="02" Then b = "февраль" End If
If a="03" Then b = "март" End If...

Казанский это Outlook. Увы.

[Казанский]

Вам название месяца надо получить по его номеру, или это опять совпадение?

a = "02"
b = LCase(Format(a & "/1/12", "MMMM"))

Или так

mon = Split("январь февраль март") 'допишите сами
a = "02"
b = mon(a - 1)

[Hugo121]

Sub tt()
    Dim arr, a$, b$
    arr = Split("январь февраль март")
    a = InputBox("Enter a :)")
    b = arr(--a - 1)
    MsgBox b
End Sub

Sub ttt()
    Dim a$, b$
    a = InputBox("Enter a :)")
    b = Split("январь февраль март")(--a - 1)
    MsgBox b
End Sub

Упс, чуть подправил - в первой версии лишний пробел закрался
И бинарное отрицание вообще-то лишнее, ну пусть остаётся...

А вариант Казанского зависим от локали
У меня всё время январь рисовал.
А вот так работает (не не по-русски):

b = LCase(Format("01/" & a & "/12", "MMMM"))

[kuklp]

в аутглюке тоже есть MonthName Function
b=monthname(a)

[mrMad-Cat]

Казанский, Да, это не совпадение, меня действительно интересуют месяца, но вопрос я задавал всетаки более общий так как интересно знать более универсальное решение.

Вариант kuklp подкупает своей гениальной простотой, только есть пробелма с форматом дат в системе. На украинской системе название месяца будет украинское, на английской - английское и т.п. Нужно русское. Можно возможно усложнить что-то в форматах.

Hugo121, спасибо, сейчас попробую осмыслить ваш вариант...

[Hugo121]

Ещё такой универсальный вариант:

Sub tt()
    Dim oDict, a, b, i&, x

    Set oDict = CreateObject("scripting.dictionary")
    
    'исходные пары данных, можно массивы задать иначе или брать из файла/листа
    a = Split("aa bb cc")
    b = Split("январь февраль март")
    
    'наполняем словарь
    For i = 0 To UBound(a)
        oDict.Item(a(i)) = b(i)
    Next
    
    'пользуемся (ввести aa или bb или cc)
    x = InputBox("Enter a :)")
    MsgBox oDict.Item(x)
    
End Sub

Пар может быть сколько угодно, хоть миллион
Если словарь получается большим, то его есть смысл сделать публичным и заполнить один раз (при открытии файла или при первом вызове), а дальше только использовать (если конечно он нужен больше одного раза за сеанс )
Тогда и массивы нужны только один раз, при заполнении словаря - т.е. эту процедуру есть смысл вынести отдельно.

[mrMad-Cat]

Ну что ж, я использовал вариант Hugo121:

b = Split("январь февраль март апрель май июнь июль август сентябрь октябрь ноябрь декабрь")(--a - 1)

Для моего случая эт осамый рабочий вариант. Хотя до сих пор не могу понять суть этой функции и почему нужно двойное отрицание и еще и отнимание еденицы.

Чего-то мне казалось что универсальный вариант будет намного проще. Хотя если присмотреться он не такой уж и сложный ведь сводится до 6 строчек:

Set oDict = CreateObject("scripting.dictionary")
a = Split("aa bb cc")
b = Split("январь февраль март")
For i = 0 To UBound(a)
oDict.Item(a(i)) = b(i)
Next

Hugo121, kuklp, Казанский, slan, спасибо за участие и идеи.