рев строки tasm

[ChestIotVaga]

помогите исправить код чтоб он правильно работал я делал реверс слов строки. но что то не так

.MODEL SMALL
.STACK 100H
.DATA
    msg DB "Enter a string: $"
    output DB 0AH, "Reversed string: $"
    buffer_size EQU 200 ; размер буфера
    buffer DB buffer_size, ?, buffer_size DUP ('$') ; буфер для хранения строки
.CODE
    MOV AX, @DATA
    MOV DS, AX
    LEA DX, msg
    MOV AH, 9
    INT 21H ; выводим приглашение на ввод строки
    MOV AH, 0AH
    LEA DX, buffer
    INT 21H ; считываем строку в буфер
    XOR BX, BX ; BX - индекс начала слова
    MOV CX, buffer[1] ; CX - длина строки
    DEC CX ; уменьшаем на 1, так как первый байт - длина буфера
    XOR SI, SI ; SI - индекс текущего символа
next_char:
    CMP SI, CX ; если достигли конца строки
    JGE output_result
    MOV AL, buffer[SI + 3] ; берём очередной символ строки из буфера
    CMP AL, ' ' ; если символ - пробел
    JE space_found
    INC SI
    JMP next_char
space_found:
    PUSH CX ; сохраняем текущую длину слова на стеке
    MOV CX, SI ; CX - длина слова
    SUB CX, BX ; вычисляем длину слова
    DEC SI ; SI - индекс последнего символа слова
    ADD SI, 3 ; добавляем 3, так как первые 3 байта - длина буфера и два символа CR,LF
    MOV DI, SI ; DI - индекс места, куда будем записывать реверсированное слово
reverse_word:
    MOV AL, buffer[BX + 3] ; берём символ слова из буфера
    MOV buffer[DI], AL ; записываем символ в реверсированное слово
    INC BX
    DEC DI
    CMP BX, SI ; если прошли все символы слова
    JLE reverse_word
    MOV AL, ' ' ; записываем пробел в реверсированную строку
    MOV buffer[DI], AL
    POP CX ; восстанавливаем длину слова
    MOV BX, SI ; обновляем индекс начала слова
    INC SI ; переходим к следующему символу
    JMP next_char
output_result:
    LEA DX, output
    MOV AH, 9
    INT 21H ; выводим сообщение о реверсированной строке
    LEA DX, buffer
    MOV AH, 9
    INT 21H ; выводим реверсированную строку
    MOV AH, 4CH
    INT 21H ; завершаем программу
END

[macomics]

Тут я ошибки исправил и программа работает. Но на будущее - в полном комплекте TASM5 есть программа отладчик. Она позволит пройти программу шаг за шагом и найти ошибки в логике ее работы.
Выглядит она вот так (см. скриншот)

.MODEL SMALL
.STACK 100H
.DATA
    msg DB "Enter a string: $"
    output DB 0AH, "Reversed string: $"
    buffer_size EQU 200 ; размер буфера
    buffer DB buffer_size, ?, buffer_size DUP ('$') ; буфер для хранения строки
.CODE
START:		; Забыли добавить метку начала программы
    MOV AX, @DATA
    MOV DS, AX
    LEA DX, msg
    MOV AH, 9
    INT 21H ; выводим приглашение на ввод строки
    MOV AH, 0AH
    LEA DX, buffer
    INT 21H ; считываем строку в буфер
    XOR CX, CX
    XOR BX, BX ; BX - индекс начала слова
    MOV CL, buffer[1] ; CX - длина строки
    DEC CX ; уменьшаем на 1, так как первый байт - длина буфера
    XOR SI, SI ; SI - индекс текущего символа

next_char:
    CMP SI, CX ; если достигли конца строки
    JGE output_result
;    MOV AL, buffer[SI + 3] ; берём очередной символ строки из буфера
    MOV AL, buffer[SI + 2] ; берём очередной символ строки из буфера
    CMP AL, ' ' ; если символ - пробел
;    JE space_found
    JNE skip_char
;    INC SI
;    JMP next_char

space_found:
    PUSH CX ; сохраняем текущую длину буфера в стеке, но это можно не сохранять. Она итак доступна через buffer[1]
    MOV CX, SI ; CX - длина слова
    SUB CX, BX ; вычисляем длину слова
    MOV DI, SI ; DI - индекс места, куда будем записывать реверсированное слово
    DEC DI ; SI - индекс последнего символа слова
;    ADD SI, 3 ; добавляем 3, так как первые 3 байта - длина буфера и два символа CR,LF
;    MOV DI, SI ; DI - индекс места, куда будем записывать реверсированное слово

reverse_word:
;    MOV AL, buffer[BX + 3] ; берём символ слова из буфера
    MOV AL, buffer[BX + 2] ; берём символ слова из буфера
    MOV AH, buffer[DI + 2]
    MOV buffer[DI + 2], AL ; записываем символ в реверсированное слово
    MOV buffer[BX + 2], AH
    INC BX
    DEC DI
    CMP BX, DI ; если прошли все символы слова
    JL reverse_word
;   MOV AL, ' ' ; записываем пробел в реверсированную строку
;   MOV buffer[DI], AL
    POP CX ; восстанавливаем длину слова

skip_space:	; Цикл пропуска пробелов (если между словами больше одного)
    CMP SI, CX
    JGE	output_result
    MOV AL, buffer[SI + 2]
    CMP AL, ' '
    JNZ skiped_spaces
    INC SI
    JMP skip_space

skiped_spaces:
    MOV BX, SI ; обновляем индекс начала слова
    JMP next_char

skip_char:
    INC SI ; переходим к следующему символу
    JMP next_char

output_result:
    LEA DX, output
    MOV AH, 9
    INT 21H ; выводим сообщение о реверсированной строке
    LEA DX, buffer[2]
    MOV AH, 9
    INT 21H ; выводим реверсированную строку
    MOV AH, 4CH
    INT 21H ; завершаем программу
END START