Selection.Copy

[ermura]

Здравсвуйте!!!!
хочу с одного .xls документа cкопировать несколько Range ов и поставить в другой .xls док.

Range("G4") .Select
Selection.Copy
Workbooks.Open Filename:="P:\My Documents\temp.xls"
Range("A1") .Select
Range("A1") .PasteSpecial
Application.ThisWorkbook.Close SaveChanges:=True

Вот такой код тока копирует один Range.
Я хотел еще скопировать Range("L5") таких несколько

И скопированные данных нужно поставить слева на право в другом файле

Заранее благодарен

[EducatedFool]

Sub test()
    Application.ScreenUpdating = False    ' отключаем обновление экрана
    Dim sh As Worksheet: Set sh = ActiveSheet    ' запоминаем активный лист

    ' ПутьКФайлу = ThisWorkbook.Path & "\temp.xls"
    ПутьКФайлу = "P:\My Documents\temp.xls"

    With Workbooks.Open(ПутьКФайлу)    ' открываем нужный файл
        .Worksheets(1).Range("A1") = sh.Range("G4")    ' вставляем данные
        .Worksheets(1).Range("D3") = sh.Range("L5")    ' вставляем данные
        .Worksheets(1).Range("F2") = sh.Range("E18")    ' вставляем данные
        ' ...
        .Close True    ' закрываем открытый файл с сохранением изменений
    End With
End Sub

[ermura]

Спасибо огрмное!!!!
Как сделать так что бы на втором файле temp.xls при каждой выполнении этого макроса он записывал вот так примерно

A B C D
1ee ff vv dd
2
3
4
5

1,2,3.. это каждый раз когда я выполняю макро
Спасибо огромное заранее!!!

[EducatedFool]

Sub test()
    Application.ScreenUpdating = False    ' отключаем обновление экрана
    Dim sh As Worksheet: Set sh = ActiveSheet    ' запоминаем активный лист

    ' ПутьКФайлу = ThisWorkbook.Path & "\temp.xls"
    ПутьКФайлу = "P:\My Documents\temp.xls"

    With Workbooks.Open(ПутьКФайлу)    ' открываем нужный файл
        Dim НоваяСтрока As Range    ' ищем первую незаполненную ячейку в столбце А
        Set НоваяСтрока = .Worksheets(1).Range("A" & .Worksheets(1).Rows.Count).End(xlUp).Offset(1).EntireRow
        НоваяСтрока.Cells(1) = sh.Range("G4")    ' вставляем данные
        НоваяСтрока.Cells(2) = sh.Range("L5")    ' вставляем данные
        НоваяСтрока.Cells(3) = sh.Range("E18")    ' вставляем данные
        ' ...
        .Close True    ' закрываем открытый файл с сохранением изменений
    End With
End Sub

[ermura]

Спасибо Вам большое!!!! Работает замечательно. Желаю удачи Вам.