Актуализация дат в документе

[alexp21]

Ребят помогите написать макрос, у меня в документе два листа, во втором листе в столбце «L» некоторые даты обновлены, нужно подставить их в первый, идентифицировать можно по уникальному значению номера в столбце «B». Буду Вам очень благодарен за помощь! Спасибо.

[Hugo121]

Есть решение на другом ресурсе. Качество не проверял, но вроде ТС устроило.

[Step_UA]

Public Sub UpdateDate()
  Dim Dic As Object, count&, ID(), D(), i&, tmp$
    With Sheets("Сентябрь копия")
        count = .Cells(Rows.count, 1).End(xlUp).Row
        ID = .[b1].Resize(count).Value
        D = .[l1].Resize(count).Value
    End With
    Set Dic = CreateObject("Scripting.Dictionary")
    Dic.comparemode = 1
    For i = 1 To count
        Dic(Split(ID(i, 1), " ", 2)(0)) = D(i, 1)
    Next
    With Sheets("Сентябрь")
        count = .Cells(Rows.count, 1).End(xlUp).Row
        ID = .[b1].Resize(count).Value
        D = .[l1].Resize(count).Value
        For i = 1 To count
            tmp = Split(ID(i, 1), " ", 2)(0)
            If Dic.exists(tmp) Then D(i, 1) = Dic(tmp)
        Next
        .[l1].Resize(count).Value = D
    End With
End Sub

[alexp21]

Спасибо Вам за помощь! Макрос делает то что нужно, вот только последнюю дату он почему то не изменил (L 25,26,27) если Вам не сложно можете подсказать как это исправить, Спасибо.

[Step_UA]

Возможно я неправильно понял постановку задания, но

Сообщение от alexp21

...идентифицировать можно по уникальному значению номера в столбце «B»

- для строк 25 и 26 номера из столбца B одинаковы
- строка 27 имеет одинаковой номер в B и равные значения в L

[alexp21]

Все верно, в строках 21, 22, 23, 24 столбце "В" номера тоже одинаковы, и Ваш макрос верно проставил для них обновленные значения дат в столбце "L", но в последнем случае почему то этого не сделал.

[Step_UA]

При написании макроса подразумевал что номера в строках не повторяются ...
На листе "Сентябрь" все строки с одинаковыми номерами имеют одинаковую дату? иначе какую из них принимать для сравнения? например в строках 21, 22,23 одна дата, в строке 24 - текст (разделители запятая)
Аналогично с листом "Сентябрь копия"
P.S. может необходимо устанавливать наибольшую дату ...

[alexp21]

Наибольшую, именно, если номера в столбце "B" совпадают, то для всех проставляется наибольшая, Ваш макрос так и сделал в предпоследнем случае, а в последнем почему то не изменил, пробовал ставить другие даты , но это не помогло.

[Step_UA]

Public Sub UpdateDate()
  Dim Dic As Object, count&, ID(), D(), i&, sTmp$, dTmp As Date
    With Sheets("Сентябрь копия")
        count = .Cells(Rows.count, 1).End(xlUp).Row
        ID = .[b1].Resize(count).Value
        D = .[l1].Resize(count).Value
    End With
    Set Dic = CreateObject("Scripting.Dictionary")
    Dic.comparemode = 1
    For i = 1 To count
        sTmp = Split(ID(i, 1), " ", 2)(0)
        dTmp = Replace(D(i, 1), ",", ".")  ' возможно необходима корректировка в зависимости от локализации
        If Dic.exists(sTmp) = False Then GoTo 1
        If Dic(sTmp) < dTmp Then
1:            Dic(sTmp) = dTmp
        End If
    Next
    With Sheets("Сентябрь")
        count = .Cells(Rows.count, 1).End(xlUp).Row
        ID = .[b1].Resize(count).Value
        D = .[l1].Resize(count).Value
        For i = 1 To count
            sTmp = Split(ID(i, 1), " ", 2)(0)
            If Dic.exists(sTmp) Then D(i, 1) = Dic(sTmp)
        Next
        .[l1].Resize(count).Value = D
    End With
End Sub

[alexp21]

Отлично, это то что нужно! Спасибо вам огромное!
И еще если позволите один вопрос - Подскажите пожалуйста, каким образом можно выполнить сортировку, так чтобы даты в столбце «L» шли по возрастанию, но при этом одинаковые ФИО людей в столбце «I» группировались независимо от даты?