всплывающая подсказка

[ГОСЕАН]

как сделать всплывающую подсказку проявляющая через определенный промежуток времени. Эту реализацию видел в W7 возле языковой панели. Хотел сделать как бы напоминалку, если запрос непустой...при нажатии на напоминалки запускается приложение с таблицей от запроса Query.

[ГОСЕАН]

БД SQL Server2000. а подсказку необходимо реализовать на рабочих станциях

[ГОСЕАН]

Сообщение от ГОСЕАН

БД SQL Server2000. а подсказку необходимо реализовать на рабочих станциях

никто не подскажет?

[raxp]

...в какой среде разрабатываете приложение? Cделайте форму, определите размеры экрана и с поправкой на размеры формы сделайте "выезд" формы с сообщением ...если речь все-таки о баллон-хинте, то winapi.

[*PB*]

Сообщение от ГОСЕАН

как сделать всплывающую подсказку проявляющая через определенный промежуток времени. Эту реализацию видел в W7 возле языковой панели.

Типа этого?


Код.

  #NIN_BALLOONSHOW=$402 
  #NIN_BALLOONHIDE=$403 
  #NIN_BALLOONTIMEOUT =$404 
  #NIN_BALLOONUSERCLICK=$405 
  #NOTIFYICON_VERSION = $3 
  #NOTIFYICONDATA_V1_SIZE = 88 
  #NOTIFYICONDATA_V2_SIZE = 488 
  #NOTIFYICONDATA_V3_SIZE = 504 
  
 

Structure NOTIFYICONDATA_95
  cbSize.l
  hwnd.l 
  uID.l 
  uFlags.l 
  uCallbackMessage.l 
  hIcon.l 
  szTip.b[64] 
EndStructure 
Structure NOTIFYICONDATA_2K Extends NOTIFYICONDATA_95
  szTipEx.b[64] 
  dwState.l
  dwStateMask.l 
  szInfo.b[256] 
  StructureUnion 
  uTimeout.l 
  uVersion.l 
  EndStructureUnion 
  szInfoTitle.b[64]
  dwInfoFlags.l
EndStructure 
 Structure NOTIFYICONDATA_XP Extends NOTIFYICONDATA_2K
   guid.GUID
 EndStructure 



Procedure HideSysTrayIcon(Tray, WindowID, state.l)
  
  Protected nid.NOTIFYICONDATA_XP
  
  If OSVersion() >= #PB_OS_Windows_2000
    
    nid\cbSize      = #NOTIFYICONDATA_V2_SIZE
    nid\uID         = Tray
    nid\hwnd        = WindowID
    nid\uFlags      = #NIF_STATE
    nid\dwStateMask = #NIS_HIDDEN
    
    If state
      nid\dwState = #NIS_HIDDEN
    EndIf
    
    ProcedureReturn Shell_NotifyIcon_(#NIM_MODIFY, @nid) 
    
  EndIf
  
EndProcedure


Procedure SysTrayIconBalloon(Tray, WindowID, Title.s, Message.s, TimeOut.l, TypeIcon) 
; Tray     - идентификатор значка в трее
; WindowID - Системный идентификатор окна
; Title    - текст в заголовке баллона
; Message  - текст в баллоне
; TimeOut  - Время (в миллисекундах) отображения баллона
; TypeIcon - тип значка #NIIF_NONE #NIIF_INFO #NIIF_WARNING #NIIF_ERROR #NIIF_USER
  
  Protected nid.NOTIFYICONDATA_XP
  
  If OSVersion() >= #PB_OS_Windows_XP
    nid\cbSize = #NOTIFYICONDATA_V3_SIZE
  ElseIf OSVersion() >= #PB_OS_Windows_2000
    nid\cbSize = #NOTIFYICONDATA_V2_SIZE
  Else
    ProcedureReturn #False
  EndIf
  
  nid\uVersion = #NOTIFYICON_VERSION
  Shell_NotifyIcon_(#NIM_SETVERSION, @nid)
  nid\uCallbackMessage=#PB_Event_SysTray
  nid\uID         = Tray
  nid\hwnd        = WindowID
  nid\dwInfoFlags = TypeIcon;#NIIF_INFO
  nid\uFlags      = #NIF_INFO
  nid\uTimeout    = timeOut
  
  nid\dwState = #NIS_SHAREDICON
  
  PokeS(@nid\szInfo, message, 256) 
  PokeS(@nid\szInfoTitle, title, 64)
  
  ProcedureReturn Shell_NotifyIcon_(#NIM_MODIFY, @nid) 
  
EndProcedure

SysDir.s=Space(255)
GetSystemDirectory_(@SysDir,255)

If OpenWindow(0, 0, 0, 200, 100, "PureBasic - SysTray Example", #PB_Window_SystemMenu|#PB_Window_ScreenCentered)
 CreateGadgetList(WindowID(0))

  ;AddSysTrayIcon(2, WindowID(0), LoadImage(1, "C:\Program Files\PureBasic\Examples\Sources\Data\CdPlayer.ico"))
  AddSysTrayIcon(2, WindowID(0), ExtractIcon_(0,SysDir+"\SetupAPI.dll",2))
  SysTrayIconToolTip(2, "Icon 2")
  ButtonGadget(1,10,10,170,24,"Отобразить баллон")
  ButtonGadget(2,10,50,170,24,"Спрятать баллон") : DisableGadget(2,1)
  
  count=0
  Repeat
    Event = WaitWindowEvent()
    Gadget=EventGadget()
    If  Event = 12502 ; События балона
     Select EventlParam() 
       
        Case #NIN_BALLOONSHOW 
          Debug "Отображён баллон" 
          DisableGadget(2,0)
        Case #NIN_BALLOONTIMEOUT 
          Debug "Закончилось время отображения либо баллон закрыт щёлчком по крестику" ; The 'X' doesn't seem to be available in W2K?! 
          DisableGadget(2,1)
        Case #NIN_BALLOONUSERCLICK 
          Debug "Клик по баллону"
          DisableGadget(2,1) 
          
        Case #NIN_BALLOONHIDE 
          Debug "Баллон спрятан" 
          DisableGadget(2,1)
          
      EndSelect 
    EndIf
       
       
       
    If Event = #PB_Event_SysTray
     x=EventType()
      If x = #PB_EventType_LeftDoubleClick
        MessageRequester("SysTray", "Left DoubleClick on SysTrayIcon "+Str(EventGadget()),0)
      EndIf
    EndIf
    
    If Event = #PB_Event_Gadget
       If Gadget=1
        SysTrayIconBalloon(2, WindowID(0), "1234", "90", 10000, count )
         count+1
         If count>4
          count=0
         EndIf
       ElseIf Gadget=2
        HideSysTrayIcon(2, WindowID(0), 1)
        HideSysTrayIcon(2, WindowID(0), 0)
       EndIf
      EndIf
    
  Until Event = #PB_Event_CloseWindow
  
EndIf

Скомпилированная прога во вложении.