замена символов в строке(ячейке)

[pooli]

помогите решить задачу
в столбце "B" есть такие значения

06.00:00:00
06.00:10:00
06.00:30:00
06.00:48:00
................

нужен макрос с помощью которого "." меняется на ":" ,а последнее ":" меняется на "."

[EducatedFool]

Пробуем так:

Sub test()
    Dim cell As Range, ra As Range: Application.ScreenUpdating = False
    Set ra = Range([b1], Range("b" & Rows.Count).End(xlUp))
    For Each cell In ra.Cells
        txt = Replace(cell, ".", ":"): pos = InStrRev(txt, ":")
        If pos Then Mid(txt, pos, 1) = "."
        If cell <> txt Then cell.NumberFormat = "@": cell = txt
    Next cell
End Sub

Пример в файле: http://excelvba.ru/XL_Files/Sample__...__19-57-06.zip

[pooli]

Спасибо, сработало!

есть еще вопросик касательно символов.
из excel сохраняю в .txt макросом книгу

Private Sub air()
Dim sname
sname = InputBox("ВВЕДИТЕ ИМЯ", "сохранение")

If sname = "" Then
Exit Sub
Else
ActiveWorkbook.SaveAs Filename:="C:\" & sname + ".txt", FileFormat:=xlText
End If

End Sub

на выходе получаю текстовый файл, но в нем присутствуют лишние пробелы, можно ли как-то тутже из макроса указать сохранение без них?
у меня программа вещания ТВ по другому не поймет.

в архиве
екселевский
исходник-то что сохранилось и файлик как должно быть .

[EducatedFool]

Надо заменить все символы табуляции на пробелы.
Это можно сделать при помощи этих функций: http://excelvba.ru/code/txt

Private Sub air()
    Dim sname: sname = InputBox("ВВЕДИТЕ ИМЯ", "сохранение")
    If sname = "" Then Exit Sub
    sname = "C:\" & sname + ".txt"
    Application.DisplayAlerts = False
    ActiveWorkbook.SaveAs sname, xlText
    ActiveWorkbook.ChangeFileAccess xlReadOnly
    SaveTXTfile sname, Replace(ReadTXTfile(sname), vbTab, " ")
    Application.DisplayAlerts = True
End Sub


Function ReadTXTfile(ByVal filename As String) As String
    On Error Resume Next: Set fso = CreateObject("scripting.filesystemobject")
    Set ts = fso.OpenTextFile(filename, 1, True): ReadTXTfile = ts.ReadAll: ts.Close
    Set ts = Nothing: Set fso = Nothing
End Function

Function SaveTXTfile(ByVal filename As String, ByVal txt As String) As Boolean
    On Error Resume Next: Err.Clear
    Set fso = CreateObject("scripting.filesystemobject")
    Set ts = fso.CreateTextFile(filename, True)
    ts.Write txt: ts.Close
    SaveTXTfile = Err = 0
    Set ts = Nothing: Set fso = Nothing
End Function

PS: Для обработки текстового файла его совсем необязательно открывать в Excel...

[pooli]

Спасибо!
сработало

[vikttur]

Хоть и "нужен макрос", для разнообразия - формула:
=ПОДСТАВИТЬ(ПОДСТАВИТЬ(A1;".";":"); ":";".";3)

[pooli]

Сообщение от vikttur

Хоть и "нужен макрос", для разнообразия - формула:
=ПОДСТАВИТЬ(ПОДСТАВИТЬ(A1;".";":"); ":";".";3)

этот вариант я пробовал.
формулы в моем варианте не катят.